Version bump. Enable coverage unconditionally since it is now required by the tests. Disable parallel build in src_test() because of tests concurrency.

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)

4 files changed, 203 insertions, 4 deletions

diff --git a/dev-python/nose/ChangeLog b/dev-python/nose/ChangeLog
index efda07795916..3906cd70ac97 100644
--- a/dev-python/nose/ChangeLog
+++ b/dev-python/nose/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for dev-python/nose
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/nose/ChangeLog,v 1.88 2012/12/22 01:51:49 floppym Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/nose/ChangeLog,v 1.89 2013/01/02 12:28:50 mgorny Exp $
+
+*nose-1.2.1 (02 Jan 2013)
+*nose-9999 (02 Jan 2013)
+
+  02 Jan 2013; Michał Górny <mgorny@gentoo.org> +nose-1.2.1.ebuild,
+  +nose-9999.ebuild, nose-1.1.2-r1.ebuild:
+  Version bump. Enable coverage unconditionally since it is now required by the
+  tests. Disable parallel build in src_test() because of tests concurrency.
 
   22 Dec 2012; Mike Gilbert <floppym@gentoo.org> nose-1.1.2-r1.ebuild:
   Add pypy2_0.
diff --git a/dev-python/nose/nose-1.1.2-r1.ebuild b/dev-python/nose/nose-1.1.2-r1.ebuild
index 933e6998034a..60f19a392784 100644
--- a/dev-python/nose/nose-1.1.2-r1.ebuild
+++ b/dev-python/nose/nose-1.1.2-r1.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/nose/nose-1.1.2-r1.ebuild,v 1.3 2012/12/22 01:51:49 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/nose/nose-1.1.2-r1.ebuild,v 1.4 2013/01/02 12:28:50 mgorny Exp $
 
 EAPI=5
 
@@ -48,6 +48,14 @@ python_compile_all() {
 	use doc && emake -C doc html
 }
 
+src_test() {
+	# nosetests use heavy multiprocessing during the tests.
+	# this shall make them less likely to kill your system or timeout.
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+
+	distutils-r1_src_test
+}
+
 python_test() {
 	local targets=( egg_info )
 	[[ ${EPYTHON} == python3.* ]] && targets+=( build_tests )
diff --git a/dev-python/nose/nose-1.2.1.ebuild b/dev-python/nose/nose-1.2.1.ebuild
new file mode 100644
index 000000000000..9e25c6cc1d19
--- /dev/null
+++ b/dev-python/nose/nose-1.2.1.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/nose/nose-1.2.1.ebuild,v 1.1 2013/01/02 12:28:50 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_5,2_6,2_7,3_1,3_2,3_3} pypy{1_8,1_9,2_0} )
+inherit distutils-r1 eutils
+
+DESCRIPTION="A unittest extension offering automatic test suite discovery and easy test authoring"
+HOMEPAGE="http://pypi.python.org/pypi/nose http://readthedocs.org/docs/nose/ https://bitbucket.org/jpellerin/nose"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc examples test"
+
+RDEPEND="dev-python/coverage[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? ( >=dev-python/sphinx-0.6 )
+	test? ( dev-python/twisted )"
+
+DOCS=( AUTHORS )
+
+python_prepare_all() {
+	# Tests need to be converted, and they don't respect BUILD_DIR.
+	use test && DISTUTILS_IN_SOURCE_BUILD=1
+
+	# Disable sphinx.ext.intersphinx, requires network
+	epatch "${FILESDIR}/${PN}-0.11.0-disable_intersphinx.patch"
+	# Disable tests requiring network connection.
+	sed \
+		-e "s/test_resolve/_&/g" \
+		-e "s/test_raises_bad_return/_&/g" \
+		-e "s/test_raises_twisted_error/_&/g" \
+		-i unit_tests/test_twisted.py || die "sed failed"
+	# Disable versioning of nosetests script to avoid collision with
+	# versioning performed by the eclass.
+	sed -e "/'nosetests%s = nose:run_exit' % py_vers_tag,/d" \
+		-i setup.py || die "sed2 failed"
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	local add_targets=()
+
+	if use test; then
+		add_targets+=( egg_info )
+		[[ ${EPYTHON} == python3* ]] && add_targets+=( build_tests )
+	fi
+
+	distutils-r1_python_compile ${add_targets[@]}
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+src_test() {
+	# nosetests use heavy multiprocessing during the tests.
+	# this shall make them less likely to kill your system or timeout.
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	"${PYTHON}" selftest.py || die "Tests fail with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install --install-data "${EPREFIX}/usr/share"
+}
+
+python_install_all() {
+	if use doc; then
+		dohtml -r -A txt doc/.build/html/*
+	fi
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+}
diff --git a/dev-python/nose/nose-9999.ebuild b/dev-python/nose/nose-9999.ebuild
new file mode 100644
index 000000000000..f4105b7db7ca
--- /dev/null
+++ b/dev-python/nose/nose-9999.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/nose/nose-9999.ebuild,v 1.1 2013/01/02 12:28:50 mgorny Exp $
+
+EAPI=5
+
+#if LIVE
+EGIT_REPO_URI="git://github.com/nose-devs/${PN}.git
+	https://github.com/nose-devs/${PN}.git"
+inherit git-2
+#endif
+
+PYTHON_COMPAT=( python{2_5,2_6,2_7,3_1,3_2,3_3} pypy{1_8,1_9,2_0} )
+inherit distutils-r1 eutils
+
+DESCRIPTION="A unittest extension offering automatic test suite discovery and easy test authoring"
+HOMEPAGE="http://pypi.python.org/pypi/nose http://readthedocs.org/docs/nose/ https://bitbucket.org/jpellerin/nose"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc examples test"
+
+RDEPEND="dev-python/coverage[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? ( >=dev-python/sphinx-0.6 )
+	test? ( dev-python/twisted )"
+
+#if LIVE
+SRC_URI=
+KEYWORDS=
+#endif
+
+DOCS=( AUTHORS )
+
+python_prepare_all() {
+	# Tests need to be converted, and they don't respect BUILD_DIR.
+	use test && DISTUTILS_IN_SOURCE_BUILD=1
+
+	# Disable sphinx.ext.intersphinx, requires network
+	epatch "${FILESDIR}/${PN}-0.11.0-disable_intersphinx.patch"
+	# Disable tests requiring network connection.
+	sed \
+		-e "s/test_resolve/_&/g" \
+		-e "s/test_raises_bad_return/_&/g" \
+		-e "s/test_raises_twisted_error/_&/g" \
+		-i unit_tests/test_twisted.py || die "sed failed"
+	# Disable versioning of nosetests script to avoid collision with
+	# versioning performed by the eclass.
+	sed -e "/'nosetests%s = nose:run_exit' % py_vers_tag,/d" \
+		-i setup.py || die "sed2 failed"
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	local add_targets=()
+
+	if use test; then
+		add_targets+=( egg_info )
+		[[ ${EPYTHON} == python3* ]] && add_targets+=( build_tests )
+	fi
+
+	distutils-r1_python_compile ${add_targets[@]}
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+src_test() {
+	# nosetests use heavy multiprocessing during the tests.
+	# this shall make them less likely to kill your system or timeout.
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	"${PYTHON}" selftest.py || die "Tests fail with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install --install-data "${EPREFIX}/usr/share"
+}
+
+python_install_all() {
+	if use doc; then
+		dohtml -r -A txt doc/.build/html/*
+	fi
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+}