Version bump.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

3 files changed, 104 insertions, 4 deletions

diff --git a/media-libs/phonon-gstreamer/ChangeLog b/media-libs/phonon-gstreamer/ChangeLog
index 70a07ff5bcfb..7acf32dddc00 100644
--- a/media-libs/phonon-gstreamer/ChangeLog
+++ b/media-libs/phonon-gstreamer/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/phonon-gstreamer
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-gstreamer/ChangeLog,v 1.46 2013/12/06 13:02:43 johu Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-gstreamer/ChangeLog,v 1.47 2014/06/21 16:20:46 kensington Exp $
+
+*phonon-gstreamer-4.7.2 (21 Jun 2014)
+
+  21 Jun 2014; Michael Palimaka <kensington@gentoo.org>
+  +phonon-gstreamer-4.7.2.ebuild, phonon-gstreamer-9999.ebuild:
+  Version bump.
 
 *phonon-gstreamer-4.7.1 (06 Dec 2013)
 
diff --git a/media-libs/phonon-gstreamer/phonon-gstreamer-4.7.2.ebuild b/media-libs/phonon-gstreamer/phonon-gstreamer-4.7.2.ebuild
new file mode 100644
index 000000000000..f0d8cab1f16d
--- /dev/null
+++ b/media-libs/phonon-gstreamer/phonon-gstreamer-4.7.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-gstreamer/phonon-gstreamer-4.7.2.ebuild,v 1.1 2014/06/21 16:20:46 kensington Exp $
+
+EAPI=5
+
+[[ ${PV} == *9999 ]] && git_eclass="git-r3"
+EGIT_REPO_URI=( "git://anongit.kde.org/${PN}" )
+
+MY_PN="phonon-backend-gstreamer"
+MY_P=${MY_PN}-${PV}
+
+inherit cmake-utils multibuild ${git_eclass}
+
+DESCRIPTION="Phonon GStreamer backend"
+HOMEPAGE="https://projects.kde.org/projects/kdesupport/phonon/phonon-gstreamer"
+[[ ${PV} == *9999 ]] || SRC_URI="mirror://kde/stable/phonon/${MY_PN}/${PV}/src/${MY_P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+if [[ ${PV} == *9999 ]]; then
+	KEYWORDS=""
+else
+	KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~x64-macos"
+fi
+SLOT="0"
+IUSE="alsa debug +network +qt4 qt5"
+REQUIRED_USE="|| ( qt4 qt5 )"
+
+RDEPEND="
+	dev-libs/glib:2
+	media-libs/gstreamer:0.10
+	media-libs/gst-plugins-base:0.10
+	media-plugins/gst-plugins-meta:0.10[alsa?,ogg,vorbis]
+	>=media-libs/phonon-4.7.0[qt4?,qt5?]
+	qt4? (
+		dev-qt/qtcore:4[glib]
+		dev-qt/qtgui:4[glib]
+		dev-qt/qtopengl:4
+	)
+	qt5? (
+		dev-qt/qtcore:5[glib]
+		dev-qt/qtgui:5[glib]
+		dev-qt/qtopengl:5
+		dev-qt/qtwidgets:5
+	)
+	virtual/opengl
+	network? ( media-plugins/gst-plugins-soup:0.10 )
+"
+DEPEND="${RDEPEND}
+	qt4? ( >=dev-util/automoc-0.9.87 )
+	virtual/pkgconfig
+"
+
+[[ ${PV} == 9999 ]] || S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=()
+	if use qt4; then
+		MULTIBUILD_VARIANTS+=(qt4)
+	fi
+	if use qt5; then
+		MULTIBUILD_VARIANTS+=(qt5)
+	fi
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=()
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+			mycmakeargs+=(-DPHONON_BUILD_PHONON4QT5=OFF)
+		fi
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+			mycmakeargs+=(-DPHONON_BUILD_PHONON4QT5=ON)
+		fi
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+}
+
+src_test() {
+	multibuild_foreach_variant cmake-utils_src_test
+}
diff --git a/media-libs/phonon-gstreamer/phonon-gstreamer-9999.ebuild b/media-libs/phonon-gstreamer/phonon-gstreamer-9999.ebuild
index 4a4ba603a450..3f85de4913df 100644
--- a/media-libs/phonon-gstreamer/phonon-gstreamer-9999.ebuild
+++ b/media-libs/phonon-gstreamer/phonon-gstreamer-9999.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-gstreamer/phonon-gstreamer-9999.ebuild,v 1.16 2013/11/11 21:07:10 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-gstreamer/phonon-gstreamer-9999.ebuild,v 1.17 2014/06/21 16:20:46 kensington Exp $
 
 EAPI=5
 
@@ -27,7 +27,9 @@ IUSE="alsa debug +network +qt4 qt5"
 REQUIRED_USE="|| ( qt4 qt5 )"
 
 RDEPEND="
+	dev-libs/glib:2
 	media-libs/gstreamer:0.10
+	media-libs/gst-plugins-base:0.10
 	media-plugins/gst-plugins-meta:0.10[alsa?,ogg,vorbis]
 	>=media-libs/phonon-4.7.0[qt4?,qt5?]
 	qt4? (
@@ -39,6 +41,7 @@ RDEPEND="
 		dev-qt/qtcore:5[glib]
 		dev-qt/qtgui:5[glib]
 		dev-qt/qtopengl:5
+		dev-qt/qtwidgets:5
 	)
 	virtual/opengl
 	network? ( media-plugins/gst-plugins-soup:0.10 )