Introduce multilib support as needed for x11-libs/gtk+:3.

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 65 insertions, 1 deletions

diff --git a/app-accessibility/at-spi2-core/ChangeLog b/app-accessibility/at-spi2-core/ChangeLog
index 9ef7844b063a..dcdf87c6bd4f 100644
--- a/app-accessibility/at-spi2-core/ChangeLog
+++ b/app-accessibility/at-spi2-core/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-accessibility/at-spi2-core
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-accessibility/at-spi2-core/ChangeLog,v 1.73 2014/10/11 11:28:38 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/at-spi2-core/ChangeLog,v 1.74 2014/11/22 20:01:41 mgorny Exp $
+
+*at-spi2-core-2.12.0-r1 (22 Nov 2014)
+
+  22 Nov 2014; Michał Górny <mgorny@gentoo.org> +at-spi2-core-2.12.0-r1.ebuild:
+  Introduce multilib support as needed for x11-libs/gtk+:3.
 
   11 Oct 2014; Markus Meier <maekke@gentoo.org> at-spi2-core-2.12.0.ebuild:
   arm stable, bug #512012
diff --git a/app-accessibility/at-spi2-core/at-spi2-core-2.12.0-r1.ebuild b/app-accessibility/at-spi2-core/at-spi2-core-2.12.0-r1.ebuild
new file mode 100644
index 000000000000..546eb3279d4f
--- /dev/null
+++ b/app-accessibility/at-spi2-core/at-spi2-core-2.12.0-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/at-spi2-core/at-spi2-core-2.12.0-r1.ebuild,v 1.1 2014/11/22 20:01:41 mgorny Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit eutils gnome2 multilib-minimal
+
+DESCRIPTION="D-Bus accessibility specifications and registration daemon"
+HOMEPAGE="http://live.gnome.org/Accessibility"
+
+LICENSE="LGPL-2+"
+SLOT="2"
+IUSE="+X +introspection"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos"
+
+# x11-libs/libSM is needed until upstream #719808 is solved either
+# making the dep unneeded or fixing their configure
+# Only libX11 is optional right now
+RDEPEND="
+	>=dev-libs/glib-2.36:2[${MULTILIB_USEDEP}]
+	>=sys-apps/dbus-1[${MULTILIB_USEDEP}]
+	x11-libs/libSM[${MULTILIB_USEDEP}]
+	x11-libs/libXi[${MULTILIB_USEDEP}]
+	x11-libs/libXtst[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6 )
+	X? ( x11-libs/libX11[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+"
+
+src_prepare() {
+	# disable teamspaces test since that requires Novell.ICEDesktop.Daemon
+	epatch "${FILESDIR}/${PN}-2.0.2-disable-teamspaces-test.patch"
+
+	gnome2_src_prepare
+}
+
+multilib_src_configure() {
+	# xevie is deprecated/broken since xorg-1.6/1.7
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		--disable-xevie \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable X x11)
+
+	# work-around gtk-doc out-of-source brokedness
+	if multilib_is_native_abi; then
+		ln -s "${S}"/doc/libatspi/html doc/libatspi/html || die
+	fi
+}
+
+multilib_src_compile() { gnome2_src_compile; }
+multilib_src_install() { gnome2_src_install; }