Version bump.

Fix process names of directly executed Python scripts (bug #286424).
Fix building on systems without strtok_r() (bug #299152).
Set a+rx permissions on /usr/bin/python-config (bug #299688).
Handle files specific to Mac OS X (bug #310551).
(Portage version: 15840-svn/cvs/Linux x86_64)

1 files changed, 52 insertions, 0 deletions

diff --git a/app-admin/eselect-python/eselect-python-20100321.ebuild b/app-admin/eselect-python/eselect-python-20100321.ebuild
new file mode 100644
index 000000000000..835f27f65c05
--- /dev/null
+++ b/app-admin/eselect-python/eselect-python-20100321.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/eselect-python/eselect-python-20100321.ebuild,v 1.1 2010/03/21 21:59:21 arfrever Exp $
+
+EAPI="1"
+
+inherit toolchain-funcs
+
+DESCRIPTION="Eselect module for management of multiple Python versions"
+HOMEPAGE="http://www.gentoo.org"
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE=""
+
+RDEPEND=">=app-admin/eselect-1.2.3"
+DEPEND="${RDEPEND}
+	sys-devel/autoconf
+	>=sys-devel/gcc-3.4"
+
+pkg_setup() {
+	if [[ $(gcc-major-version) -lt 3 || ($(gcc-major-version) -eq 3 && $(gcc-minor-version) -lt 4) ]]; then
+		die "GCC >=3.4 is required"
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	./autogen.sh || die "autogen.sh failed"
+}
+
+src_install() {
+	keepdir /etc/env.d/python
+	emake DESTDIR="${D}" install || die "emake install failed"
+}
+
+pkg_preinst() {
+	if has_version "<${CATEGORY}/${PN}-20090804" || ! has_version "${CATEGORY}/${PN}"; then
+		run_eselect_python_update="1"
+	fi
+}
+
+pkg_postinst() {
+	if [[ "${run_eselect_python_update}" == "1" ]]; then
+		ebegin "Running \`eselect python update\`"
+		eselect python update --python2 > /dev/null
+		eend "$?"
+	fi
+}