Adds webapp-config version 1.54

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key A8C8FBCF)

2 files changed, 69 insertions, 1 deletions

diff --git a/app-admin/webapp-config/ChangeLog b/app-admin/webapp-config/ChangeLog
index 52f3edbb9ee0..bb6752cddab3 100644
--- a/app-admin/webapp-config/ChangeLog
+++ b/app-admin/webapp-config/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-admin/webapp-config
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/webapp-config/ChangeLog,v 1.134 2015/06/22 19:24:29 twitch153 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/webapp-config/ChangeLog,v 1.135 2015/07/03 20:29:17 twitch153 Exp $
+
+*webapp-config-1.54 (03 Jul 2015)
+
+  03 Jul 2015; Devan Franchini <twitch153@gentoo.org>
+  +webapp-config-1.54.ebuild:
+  Adds webapp-config version 1.54
 
   22 Jun 2015; Devan Franchini <twitch153@gentoo.org> webapp-config-9999.ebuild:
   Updates to git-r3 eclass
diff --git a/app-admin/webapp-config/webapp-config-1.54.ebuild b/app-admin/webapp-config/webapp-config-1.54.ebuild
new file mode 100644
index 000000000000..d5fb8f0854ac
--- /dev/null
+++ b/app-admin/webapp-config/webapp-config-1.54.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/webapp-config/webapp-config-1.54.ebuild,v 1.1 2015/07/03 20:29:17 twitch153 Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+SRC_URI="http://dev.gentoo.org/~twitch153/${PN}/${P}.tar.bz2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+
+DESCRIPTION="Gentoo's installer for web-based applications"
+HOMEPAGE="http://sourceforge.net/projects/webapp-config/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+portage"
+
+DEPEND="app-text/xmlto
+	sys-apps/gentoo-functions"
+RDEPEND="portage? ( sys-apps/portage[${PYTHON_USEDEP}] )"
+
+python_compile_all() {
+	emake -C doc/
+}
+
+python_install() {
+	# According to this discussion:
+	# http://mail.python.org/pipermail/distutils-sig/2004-February/003713.html
+	# distutils does not provide for specifying two different script install
+	# locations. Since we only install one script here the following should
+	# be ok
+	distutils-r1_python_install --install-scripts="/usr/sbin"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /etc/vhosts
+	doins config/webapp-config
+
+	keepdir /usr/share/webapps
+	keepdir /var/db/webapps
+
+	dodoc AUTHORS
+	doman doc/*.[58]
+	dohtml doc/*.[58].html
+}
+
+python_test() {
+	PYTHONPATH="." "${PYTHON}" WebappConfig/tests/external.py \
+		|| die "Testing failed with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	elog "webapp-config now requires that all -I/-U/-C commands be followed"
+	elog "by the package name and package version of the webapp"
+	elog "eg.) 'webapp-config -d drupal -I drupal 8.0.0_beta10'"
+	elog "See 'man 8 webapp-config' for more information"
+}