Version bump.

Changes since 1.4.26:

* Fix bug where permissions would not be backed up correctly when only
  permissions have changed.
* Support librsync-1.0.0.
* Allow syslog and stdout logging at the same time.
* Better SSL error logging.
* Replace c_rehash with a line of shell script.
* Add soft/hard quota feature.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key F0134531E1DBFAB5)

2 files changed, 112 insertions, 1 deletions

diff --git a/app-backup/burp/ChangeLog b/app-backup/burp/ChangeLog
index 3c1bc9fdf732..e01d2e0fe7b6 100644
--- a/app-backup/burp/ChangeLog
+++ b/app-backup/burp/ChangeLog
@@ -1,6 +1,21 @@
 # ChangeLog for app-backup/burp
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/burp/ChangeLog,v 1.4 2015/04/09 15:19:11 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/burp/ChangeLog,v 1.5 2015/04/09 15:53:36 aidecoe Exp $
+
+*burp-1.4.34 (09 Apr 2015)
+
+  09 Apr 2015; Amadeusz Żołnowski <aidecoe@gentoo.org> +burp-1.4.34.ebuild:
+  Version bump.
+
+  Changes since 1.4.26:
+
+  * Fix bug where permissions would not be backed up correctly when only
+    permissions have changed.
+  * Support librsync-1.0.0.
+  * Allow syslog and stdout logging at the same time.
+  * Better SSL error logging.
+  * Replace c_rehash with a line of shell script.
+  * Add soft/hard quota feature.
 
   09 Apr 2015; Amadeusz Żołnowski <aidecoe@gentoo.org> files/burp.initd:
   Apply improvements to initd script by Marcin Mirosław. Fix bug #533150.
diff --git a/app-backup/burp/burp-1.4.34.ebuild b/app-backup/burp/burp-1.4.34.ebuild
new file mode 100644
index 000000000000..1f78b4088c0f
--- /dev/null
+++ b/app-backup/burp/burp-1.4.34.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-backup/burp/burp-1.4.34.ebuild,v 1.1 2015/04/09 15:53:36 aidecoe Exp $
+
+EAPI=5
+
+inherit autotools eutils user
+
+DESCRIPTION="Network backup and restore client and server for Unix and Windows"
+HOMEPAGE="http://burp.grke.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="acl afs ipv6 nls ssl tcpd xattr"
+
+DEPEND="
+	dev-libs/uthash
+	sys-libs/libcap
+	net-libs/librsync
+	sys-libs/ncurses
+	sys-libs/zlib
+	acl? ( sys-apps/acl )
+	afs? ( net-fs/openafs )
+	nls? ( sys-devel/gettext )
+	ssl? ( dev-libs/openssl:0 )
+	tcpd? ( sys-apps/tcp-wrappers )
+	xattr? ( sys-apps/attr )
+	"
+RDEPEND="${DEPEND}
+	virtual/logger
+	"
+
+DOCS=( CONTRIBUTORS DONATIONS UPGRADING )
+PATCHES=(
+	"${FILESDIR}/${PV}-bedup-conf-path.patch"
+	"${FILESDIR}/${PV}-tinfo.patch"
+	)
+S="${WORKDIR}/burp"
+
+pkg_setup() {
+	enewgroup "${PN}"
+	enewuser "${PN}" -1 "" "" "${PN}"
+}
+
+src_prepare() {
+	epatch "${PATCHES[@]}"
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--sbindir=/usr/sbin
+		--sysconfdir=/etc/burp
+		--enable-largefile
+		$(use_with ssl openssl)
+		$(use_enable acl)
+		$(use_enable afs)
+		$(use_enable ipv6)
+		$(use_enable nls)
+		$(use_enable xattr)
+		$(use_with tcpd tcp-wrappers)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	fowners root:burp /etc/burp /var/spool/burp
+	fperms 0775 /etc/burp /var/spool/burp
+	fowners root:burp /etc/burp/clientconfdir
+	fperms 0750 /etc/burp/clientconfdir
+	fowners root:burp /etc/burp/burp-server.conf
+	fperms 0640 /etc/burp/burp-server.conf
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	dodoc docs/*
+
+	sed -e 's|^# user=graham|user = burp|' \
+		-e 's|^# group=nogroup|group = burp|' \
+		-e 's|^pidfile = .*|lockfile = /run/lock/burp/server.lock|' \
+		-i "${D}"/etc/burp/burp-server.conf || die
+}
+
+pkg_postinst() {
+	if use ssl && [ ! -e /etc/burp/CA/index.txt ]; then
+		elog "At first run burp server will generate DH parameters and SSL"
+		elog "certificates.  You should adjust configuration before."
+		elog "Server configuration is located at"
+		elog ""
+		elog "  /etc/burp/burp-server.conf"
+		elog ""
+	fi
+}