Version bump #128394 by toto.

(Portage version: 2.1_pre7-r3)

3 files changed, 139 insertions, 1 deletions

diff --git a/app-emulation/wine/ChangeLog b/app-emulation/wine/ChangeLog
index 34db0438b86a..e99734ec2d23 100644
--- a/app-emulation/wine/ChangeLog
+++ b/app-emulation/wine/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/wine
 # Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/ChangeLog,v 1.135 2006/03/16 00:08:36 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/ChangeLog,v 1.136 2006/04/01 22:32:37 vapier Exp $
+
+*wine-0.9.11 (01 Apr 2006)
+
+  01 Apr 2006; Mike Frysinger <vapier@gentoo.org> +wine-0.9.11.ebuild:
+  Version bump #128394 by toto.
 
 *wine-0.9.10 (16 Mar 2006)
 
diff --git a/app-emulation/wine/files/digest-wine-0.9.11 b/app-emulation/wine/files/digest-wine-0.9.11
new file mode 100644
index 000000000000..af3465a92ff5
--- /dev/null
+++ b/app-emulation/wine/files/digest-wine-0.9.11
@@ -0,0 +1,3 @@
+MD5 b21d359b75f07255bb5cd34384bdc3cf wine-0.9.11.tar.bz2 10671110
+RMD160 e48d33d7f6d39a4ad9e59ed84b1b75608e736194 wine-0.9.11.tar.bz2 10671110
+SHA256 785277343f770004f1cf9d12497e377aa93985bfc17c1b462c4f421a39748e84 wine-0.9.11.tar.bz2 10671110
diff --git a/app-emulation/wine/wine-0.9.11.ebuild b/app-emulation/wine/wine-0.9.11.ebuild
new file mode 100644
index 000000000000..1fc12efd8be1
--- /dev/null
+++ b/app-emulation/wine/wine-0.9.11.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/wine-0.9.11.ebuild,v 1.1 2006/04/01 22:32:37 vapier Exp $
+
+inherit eutils flag-o-matic multilib
+
+DESCRIPTION="free implementation of Windows(tm) on Unix"
+HOMEPAGE="http://www.winehq.com/"
+SRC_URI="mirror://sourceforge/${PN}/wine-${PV}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="-* -amd64 ~x86"
+IUSE="alsa arts cups debug esd gif glut jack jpeg lcms ldap nas ncurses opengl oss scanner truetype xml2 X"
+RESTRICT="test" #72375
+
+RDEPEND=">=media-libs/freetype-2.0.0
+	media-fonts/corefonts
+	ncurses? ( >=sys-libs/ncurses-5.2 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	X? ( || ( ( x11-libs/libXrandr
+				x11-libs/libXi
+				x11-libs/libXmu
+				x11-libs/libXxf86dga
+				x11-libs/libXxf86vm
+			)
+			virtual/x11
+		)
+	)
+	arts? ( kde-base/arts )
+	alsa? ( media-libs/alsa-lib )
+	esd? ( media-sound/esound )
+	nas? ( media-libs/nas )
+	cups? ( net-print/cups )
+	opengl? ( virtual/opengl )
+	gif? ( media-libs/giflib )
+	jpeg? ( media-libs/jpeg )
+	ldap? ( net-nds/openldap )
+	glut? ( virtual/glut )
+	lcms? ( media-libs/lcms )
+	xml2? ( dev-libs/libxml2 dev-libs/libxslt )
+	truetype? ( media-libs/freetype media-gfx/fontforge )
+	scanner? ( media-gfx/sane-backends )
+	amd64? (
+		>=app-emulation/emul-linux-x86-xlibs-2.1
+		>=app-emulation/emul-linux-x86-soundlibs-2.1
+		>=sys-kernel/linux-headers-2.6
+	)"
+DEPEND="${RDEPEND}
+	X? ( || ( ( x11-proto/inputproto
+				x11-proto/xextproto
+				x11-proto/xf86dgaproto
+				x11-proto/xf86vidmodeproto
+			)
+			virtual/x11
+		)
+	)
+	sys-devel/bison
+	sys-devel/flex"
+
+pkg_setup() {
+	use amd64 && has_multilib_profile && export ABI=x86
+}
+
+src_unpack() {
+	unpack wine-${PV}.tar.bz2
+	cd "${S}"
+
+	epatch "${FILESDIR}"/wine-0.9.6-force-ddraw-gamma.patch #119931
+	sed -i '/^UPDATE_DESKTOP_DATABASE/s:=.*:=true:' tools/Makefile.in
+	epatch "${FILESDIR}"/wine-gentoo-no-ssp.patch #66002
+	sed -i '/^MimeType/d' tools/wine.desktop || die #117785
+}
+
+config_cache() {
+	local h ans="no"
+	use $1 && ans="yes"
+	shift
+	for h in "$@" ; do
+		[[ ${h} == *.h ]] \
+			&& h=header_${h} \
+			|| h=lib_${h}
+		export ac_cv_${h//[:\/.]/_}=${ans}
+	done
+}
+
+src_compile() {
+	export LDCONFIG=/bin/true
+	use arts    || export ac_cv_path_ARTSCCONFIG=""
+	use esd     || export ac_cv_path_ESDCONFIG=""
+	use scanner || export ac_cv_path_sane_devel="no"
+	config_cache jack jack/jack.h
+	config_cache cups cups/cups.h
+	config_cache alsa alsa/asoundlib.h sys/asoundlib.h asound:snd_pcm_open
+	config_cache nas audio/audiolib.h audio/soundlib.h
+	config_cache xml2 libxml/parser.h libxslt/pattern.h libxslt/transform.h
+	config_cache ldap ldap.h lber.h
+	config_cache gif gif_lib.h
+	config_cache glut glut:glutMainLoop
+	config_cache jpeg jpeglib.h
+	config_cache oss sys/soundcard.h machine/soundcard.h soundcard.h
+	config_cache lcms lcms.h
+	use x86 && config_cache truetype freetype:FT_Init_FreeType
+
+	strip-flags
+
+	#	$(use_enable amd64 win64)
+	econf \
+		CC=$(tc-getCC) \
+		--sysconfdir=/etc/wine \
+		$(use_with ncurses curses) \
+		$(use_with opengl) \
+		$(use_with X x) \
+		$(use_enable debug trace) \
+		$(use_enable debug) \
+		|| die "configure failed"
+
+	emake -j1 depend || die "depend"
+	emake all || die "all"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die
+	dodoc ANNOUNCE AUTHORS ChangeLog DEVELOPERS-HINTS README
+}
+
+pkg_postinst() {
+	einfo "~/.wine/config is now deprecated.  For configuration either use"
+	einfo "winecfg or regedit HKCU\\Software\\Wine"
+}