Respect LDFLAGS (bug #337615), CC (inherit toolchain-funcs). Use dobin and newman.

(Portage version: 2.2_rc82/cvs/Linux i686)

2 files changed, 77 insertions, 2 deletions

diff --git a/app-misc/oneko/ChangeLog b/app-misc/oneko/ChangeLog
index 053c36d5bca0..b596d3bc1ed4 100644
--- a/app-misc/oneko/ChangeLog
+++ b/app-misc/oneko/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-misc/oneko
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/oneko/ChangeLog,v 1.16 2008/05/12 13:49:24 corsair Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/oneko/ChangeLog,v 1.17 2010/09/17 02:08:38 jer Exp $
+
+*oneko-1.2-r2 (17 Sep 2010)
+
+  17 Sep 2010; Jeroen Roovers <jer@gentoo.org> +oneko-1.2-r2.ebuild:
+  Respect LDFLAGS (bug #337615), CC (inherit toolchain-funcs). Use dobin and
+  newman.
 
   12 May 2008; Markus Rothe <corsair@gentoo.org> oneko-1.2-r1.ebuild:
   Stable on ppc64
diff --git a/app-misc/oneko/oneko-1.2-r2.ebuild b/app-misc/oneko/oneko-1.2-r2.ebuild
new file mode 100644
index 000000000000..b07e633534d5
--- /dev/null
+++ b/app-misc/oneko/oneko-1.2-r2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/oneko/oneko-1.2-r2.ebuild,v 1.1 2010/09/17 02:08:40 jer Exp $
+
+EAPI="2"
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="A cat, dog and others which chase the mouse or windows around the screen"
+HOMEPAGE="http://www.daidouji.com/oneko/"
+SRC_URI="http://www.daidouji.com/oneko/distfiles/${P}.sakura.5.tar.gz
+	mirror://gentoo/${P}-cat.png
+	mirror://gentoo/${P}-dog.png
+	mirror://gentoo/${P}-sakura-nobsd.patch.bz2"
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND="x11-libs/libX11
+	x11-libs/libXext"
+DEPEND="${RDEPEND}
+	x11-misc/gccmakedep
+	x11-misc/imake
+	app-text/rman
+	x11-proto/xextproto"
+
+S="${WORKDIR}/oneko-${PV}.sakura.5"
+
+src_prepare() {
+	epatch "${WORKDIR}/${P}-sakura-nobsd.patch"
+}
+
+src_configure() {
+	xmkmf -a || die "running xmkmf failed!"
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CCOPTIONS="${CFLAGS}" \
+		EXTRA_LDOPTIONS="${LDFLAGS}" \
+		|| die "make failed!"
+}
+
+src_install() {
+	dobin oneko
+	newman oneko._man oneko.1x
+	dodoc README README-NEW README-SUPP
+	newicon "${DISTDIR}/${P}-cat.png" "cat.png"
+	newicon "${DISTDIR}/${P}-dog.png" "dog.png"
+	make_desktop_entry "oneko" "oneko (cat)" "cat" "Game;Amusement"
+	make_desktop_entry "oneko -dog" "oneko (dog)" "dog" "Game;Amusement"
+	make_desktop_entry "killall -TERM oneko" "oneko kill" "" "Game;Amusement"
+}
+
+pkg_postinst() {
+	elog "To kill oneko, type the following in a terminal:"
+	elog ""
+	elog "killall oneko"
+	elog ""
+	elog "If your mouse cursor changes to the default black cross"
+	elog "after running ${PN}, you should emerge x11-apps/xsetroot"
+	elog "and run:"
+	elog ""
+	elog "xsetroot -cursor_name left_ptr"
+	elog ""
+}