Added from kde overlay

(Portage version: 2.1.10.4/cvs/Linux x86_64)

2 files changed, 95 insertions, 2 deletions

diff --git a/app-misc/strigi/ChangeLog b/app-misc/strigi/ChangeLog
index 8b2e10452ae9..2da548cefd0b 100644
--- a/app-misc/strigi/ChangeLog
+++ b/app-misc/strigi/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/strigi
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/strigi/ChangeLog,v 1.67 2010/09/27 20:46:53 jer Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/strigi/ChangeLog,v 1.68 2011/07/12 20:26:34 dilfridge Exp $
+
+*strigi-0.7.5 (12 Jul 2011)
+
+  12 Jul 2011; Andreas K. Huettel <dilfridge@gentoo.org> +strigi-0.7.5.ebuild:
+  Added from kde overlay
 
   27 Sep 2010; Jeroen Roovers <jer@gentoo.org> strigi-0.7.1.ebuild,
   strigi-0.7.2.ebuild:
diff --git a/app-misc/strigi/strigi-0.7.5.ebuild b/app-misc/strigi/strigi-0.7.5.ebuild
new file mode 100644
index 000000000000..916b9d5e7454
--- /dev/null
+++ b/app-misc/strigi/strigi-0.7.5.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/strigi/strigi-0.7.5.ebuild,v 1.1 2011/07/12 20:26:34 dilfridge Exp $
+
+EAPI=4
+
+if [[ "${PV}" != "9999" ]]; then
+	SRC_URI="http://www.vandenoever.info/software/${PN}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+else
+	EGIT_REPO_URI="git://anongit.kde.org/strigi"
+	GIT_ECLASS="git-2"
+	EGIT_HAS_SUBMODULES="true"
+	KEYWORDS=""
+fi
+
+inherit cmake-utils ${GIT_ECLASS}
+
+DESCRIPTION="Fast crawling desktop search engine with Qt4 GUI"
+HOMEPAGE="http://strigi.sourceforge.net/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="clucene +dbus debug exif fam ffmpeg hyperestraier inotify log +qt4 test"
+
+COMMONDEPEND="
+	app-arch/bzip2:0
+	dev-libs/libxml2:2
+	sys-libs/zlib:0
+	virtual/libiconv
+	clucene? ( >=dev-cpp/clucene-0.9.21[-debug] )
+	dbus? (
+		sys-apps/dbus
+		qt4? ( x11-libs/qt-dbus:4 )
+	)
+	exif? ( >=media-gfx/exiv2-0.17 )
+	fam? ( virtual/fam )
+	ffmpeg? ( virtual/ffmpeg )
+	hyperestraier? ( app-text/hyperestraier )
+	log? ( >=dev-libs/log4cxx-0.10.0 )
+	qt4? (
+		x11-libs/qt-core:4
+		x11-libs/qt-gui:4
+	)
+"
+DEPEND="${COMMONDEPEND}
+	test? ( dev-util/cppunit )"
+RDEPEND="${COMMONDEPEND}"
+
+src_configure() {
+	# Enabled: POLLING (only reliable way to check for files changed.)
+	# Disabled: xine - recommended upstream to keep it this way
+	mycmakeargs=(
+		-DENABLE_POLLING=ON
+		-DFORCE_DEPS=ON
+		-DENABLE_CPPUNIT=OFF
+		-DENABLE_REGENERATEXSD=OFF
+		$(cmake-utils_use_enable clucene)
+		$(cmake-utils_use_enable dbus)
+		$(cmake-utils_use_enable exif EXIV2)
+		$(cmake-utils_use_enable fam)
+		$(cmake-utils_use_enable ffmpeg)
+		$(cmake-utils_use_enable hyperestraier)
+		$(cmake-utils_use_enable inotify)
+		$(cmake-utils_use_enable log LOG4CXX)
+		$(cmake-utils_use_enable qt4)
+		$(cmake-utils_use_enable test CPPUNIT)
+		$(cmake-utils_disable xine)
+	)
+
+	if use qt4; then
+		mycmakeargs+=(-DENABLE_DBUS=ON)
+	fi
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	if ! use clucene && ! use hyperestraier; then
+		echo
+		elog "Because you didn't enable either of the available backends:"
+		elog "clucene or hyperestraier, strigi may not be functional."
+		elog "If you intend to use standalone strigi indexer (not needed for KDE),"
+		elog "be sure to reinstall app-misc/strigi with either clucene (recommended)"
+		elog "or hyperestraier (unreliable) USE flag enabled."
+		echo
+	fi
+}