Version bump.

(Portage version: 2.2.0_alpha87/cvs/Linux x86_64)

2 files changed, 71 insertions, 2 deletions

diff --git a/app-misc/task/ChangeLog b/app-misc/task/ChangeLog
index 7b0f8686b55d..3af75134ed93 100644
--- a/app-misc/task/ChangeLog
+++ b/app-misc/task/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/task
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v 1.26 2011/10/17 19:47:11 radhermit Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v 1.27 2012/02/23 04:31:03 radhermit Exp $
+
+*task-2.0.0_beta5 (23 Feb 2012)
+
+  23 Feb 2012; Tim Harder <radhermit@gentoo.org> +task-2.0.0_beta5.ebuild:
+  Version bump.
 
   17 Oct 2011; Tim Harder <radhermit@gentoo.org> -task-1.9.4.ebuild,
   -task-2.0.0_beta3.ebuild, -files/task-2.0.0_beta1-rcdir.patch:
diff --git a/app-misc/task/task-2.0.0_beta5.ebuild b/app-misc/task/task-2.0.0_beta5.ebuild
new file mode 100644
index 000000000000..51aeca5e5f38
--- /dev/null
+++ b/app-misc/task/task-2.0.0_beta5.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/task/task-2.0.0_beta5.ebuild,v 1.1 2012/02/23 04:31:03 radhermit Exp $
+
+EAPI=4
+
+inherit eutils cmake-utils bash-completion-r1
+
+MY_P="${P/_/.}"
+DESCRIPTION="A task management tool with a command-line interface"
+HOMEPAGE="http://taskwarrior.org/projects/show/taskwarrior/"
+SRC_URI="http://taskwarrior.org/download/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="lua vim-syntax zsh-completion"
+
+DEPEND="lua? ( dev-lang/lua )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	# Use the correct directory locations
+	sed -i -e "s:/usr/local/share/doc/task/rc:/usr/share/task/rc:" \
+		doc/man/taskrc.5.in doc/man/task-tutorial.5.in doc/man/task-color.5.in || die
+	sed -i -e "s:/usr/local/bin:/usr/bin:" doc/man/task-faq.5.in scripts/add-ons/* || die
+
+	# Don't automatically install scripts
+	sed -i -e '/scripts/d' CMakeLists.txt || die
+
+	epatch "${FILESDIR}"/${PN}-2.0.0_beta4-rcdir.patch
+	epatch "${FILESDIR}"/${PN}-1.9.4-lua-automagic.patch
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_enable lua LUA)
+		-DTASK_DOCDIR=/usr/share/doc/${PF}
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	newbashcomp scripts/bash/task_completion.sh task
+
+	if use vim-syntax ; then
+		rm scripts/vim/README
+		insinto /usr/share/vim/vimfiles
+		doins -r scripts/vim/*
+	fi
+
+	if use zsh-completion ; then
+		insinto /usr/share/zsh/site-functions
+		doins scripts/zsh/*
+	fi
+
+	exeinto /usr/share/${PN}/scripts
+	doexe scripts/add-ons/*
+}