Initial addition. Ebuild written by me. Fixes bug #163934.

(Portage version: 2.1.2.2)

1 files changed, 64 insertions, 0 deletions

diff --git a/dev-java/commons-vfs/commons-vfs-1.0.ebuild b/dev-java/commons-vfs/commons-vfs-1.0.ebuild
new file mode 100644
index 000000000000..ca95999f6c51
--- /dev/null
+++ b/dev-java/commons-vfs/commons-vfs-1.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/commons-vfs/commons-vfs-1.0.ebuild,v 1.1 2007/03/29 15:53:56 betelgeuse Exp $
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-ant-2
+
+DESCRIPTION="a single API for accessing various different file systems"
+HOMEPAGE="http://jakarta.apache.org/commons/vfs/"
+SRC_URI="mirror://apache/jakarta/${PN/-//}/source/${P}-src.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~x86"
+
+COMMON_DEP="
+	dev-java/commons-logging
+	dev-java/commons-net
+	=dev-java/commons-httpclient-3*
+	dev-java/jsch
+	dev-java/commons-collections
+	dev-java/ant-core"
+
+RDEPEND=">=virtual/jre-1.4
+	${COMMON_DEP}"
+DEPEND="
+	!doc? ( >=virtual/jdk-1.4 )
+	doc? ( || ( =virtual/jdk-1.5* =virtual/jdk-1.4* ) )
+	${COMMON_DEP}"
+
+S=${WORKDIR}/${P}-src
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}/1.0-noget.patch"
+	java-ant_rewrite-classpath
+	java-ant_ignore-system-classes
+}
+
+EANT_GENTOO_CLASSPATH="
+	commons-logging
+	commons-net
+	commons-httpclient-3
+	jsch
+	commons-collections
+	ant-core
+"
+
+# The build.xml is generated from maven and can't run the tests properly
+# Use maven test to execute these manually but that means downloading deps from
+# the internet. Also the tests need to login to some ftp servers and samba
+# shares so I doubt they work for everyone.
+#src_test() {
+#	ANT_TASKS="ant-junit" eant test
+#}
+
+src_install() {
+	java-pkg_newjar target/*.jar
+	dodoc *.txt || die
+	use doc && java-pkg_dojavadoc ./dist/docs/api
+	use source && java-pkg_dosrc ./core/src/main/java
+}