Convert to multilib and stack it for medialibs r11. Improve its deps: cddb is only needed for the binaries and hence not with minimal useflag on. libintl is not needed, only libiconv.

(Portage version: 2.2.0_alpha196/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

2 files changed, 67 insertions, 1 deletions

diff --git a/dev-libs/libcdio/ChangeLog b/dev-libs/libcdio/ChangeLog
index c6a8cc99a9b6..d5dcc7094e81 100644
--- a/dev-libs/libcdio/ChangeLog
+++ b/dev-libs/libcdio/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/libcdio
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libcdio/ChangeLog,v 1.138 2013/03/06 13:47:11 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libcdio/ChangeLog,v 1.139 2013/08/10 22:08:34 aballier Exp $
+
+*libcdio-0.90-r1 (10 Aug 2013)
+
+  10 Aug 2013; Alexis Ballier <aballier@gentoo.org> +libcdio-0.90-r1.ebuild:
+  Convert to multilib and stack it for medialibs r11. Improve its deps: cddb is
+  only needed for the binaries and hence not with minimal useflag on. libintl
+  is not needed, only libiconv.
 
   06 Mar 2013; Samuli Suominen <ssuominen@gentoo.org> libcdio-0.83.ebuild:
   Block dev-libs/libcdio-paranoia wrt #460476 by Ben Kohler
diff --git a/dev-libs/libcdio/libcdio-0.90-r1.ebuild b/dev-libs/libcdio/libcdio-0.90-r1.ebuild
new file mode 100644
index 000000000000..5e70db417190
--- /dev/null
+++ b/dev-libs/libcdio/libcdio-0.90-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libcdio/libcdio-0.90-r1.ebuild,v 1.1 2013/08/10 22:08:34 aballier Exp $
+
+EAPI=5
+inherit eutils multilib-minimal
+
+DESCRIPTION="A library to encapsulate CD-ROM reading and control"
+HOMEPAGE="http://www.gnu.org/software/libcdio/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="cddb +cxx minimal static-libs test"
+
+RDEPEND="
+	!minimal? (
+		>=sys-libs/ncurses-5.7-r7
+		cddb? ( >=media-libs/libcddb-1.3.2 )
+	)
+	virtual/libiconv[${MULTILIB_USEDEP}]
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20130224-r10
+		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}
+	sys-apps/sed
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( dev-lang/perl )"
+DOCS="AUTHORS ChangeLog NEWS README* THANKS TODO"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/cdio/cdio_config.h
+	/usr/include/cdio/version.h
+)
+
+multilib_src_configure() {
+	local util_switch
+	if ! multilib_is_native_abi || use minimal ; then
+		util_switch="--without"
+	else
+		util_switch="--with"
+	fi
+
+	# Tests fail if ECONF_SOURCE is not relative
+	ECONF_SOURCE="../${P}" econf \
+		--disable-maintainer-mode \
+		$(use_enable cxx) \
+		--disable-cpp-progs \
+		--disable-example-progs \
+		$(use_enable static-libs static) \
+		$(use_enable cddb) \
+		--disable-vcd-info \
+		${util_switch}-{cd-drive,cd-info,cdda-player,cd-read,iso-info,iso-read}
+}
+
+multilib_src_install_all() {
+	prune_libtool_files
+}