Version bump.

(Portage version: 2.2.0_alpha28/cvs/Linux x86_64)

1 files changed, 60 insertions, 0 deletions

diff --git a/dev-libs/mpfr/mpfr-3.0.1.ebuild b/dev-libs/mpfr/mpfr-3.0.1.ebuild
new file mode 100644
index 000000000000..ddb11b802c18
--- /dev/null
+++ b/dev-libs/mpfr/mpfr-3.0.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/mpfr/mpfr-3.0.1.ebuild,v 1.1 2011/04/05 00:52:17 vapier Exp $
+
+# NOTE: we cannot depend on autotools here starting with gcc-4.3.x
+inherit eutils
+
+MY_PV=${PV/_p*}
+MY_P=${PN}-${MY_PV}
+PLEVEL=${PV/*p}
+DESCRIPTION="library for multiple-precision floating-point computations with exact rounding"
+HOMEPAGE="http://www.mpfr.org/"
+SRC_URI="http://www.mpfr.org/mpfr-current/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE=""
+
+RDEPEND=">=dev-libs/gmp-4.1.4-r2"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	[[ -d ${FILESDIR}/${PV} ]] && epatch "${FILESDIR}"/${PV}/*.patch
+	[[ ${PLEVEL} == ${PV} ]] && return 0
+	for ((i=1; i<=PLEVEL; ++i)) ; do
+		patch=patch$(printf '%02d' ${i})
+		if [[ -f ${FILESDIR}/${MY_PV}/${patch} ]] ; then
+			epatch "${FILESDIR}"/${MY_PV}/${patch}
+		elif [[ -f ${DISTDIR}/${PN}-${MY_PV}_p${i} ]] ; then
+			epatch "${DISTDIR}"/${PN}-${MY_PV}_p${i}
+		else
+			ewarn "${DISTDIR}/${PN}-${MY_PV}_p${i}"
+			die "patch ${i} missing - please report to bugs.gentoo.org"
+		fi
+	done
+	sed -i '/if test/s:==:=:' configure #261016
+	find . -type f -print0 | xargs -0 touch -r configure
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+	rm "${D}"/usr/share/doc/${PN}/*.html || die
+	mv "${D}"/usr/share/doc/{${PN},${PF}} || die
+	dodoc AUTHORS BUGS ChangeLog NEWS README TODO
+	dohtml *.html
+	prepalldocs
+}
+
+pkg_preinst() {
+	preserve_old_lib /usr/$(get_libdir)/libmpfr.so.1
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /usr/$(get_libdir)/libmpfr.so.1
+}