Add 0.6.4.1 from the gnome overlay, needed for gnome-3.2. Notable changes: new eds, libsocialweb, and tracker backends; significant API changes.

(Portage version: 2.2.0_alpha72/cvs/Linux x86_64)

3 files changed, 100 insertions, 1 deletions

diff --git a/dev-libs/folks/ChangeLog b/dev-libs/folks/ChangeLog
index a2dd0c72ef62..b424c17a4980 100644
--- a/dev-libs/folks/ChangeLog
+++ b/dev-libs/folks/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/folks
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/ChangeLog,v 1.16 2011/10/05 16:50:25 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/ChangeLog,v 1.17 2011/11/04 04:07:45 tetromino Exp $
+
+*folks-0.6.4.1 (04 Nov 2011)
+
+  04 Nov 2011; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +folks-0.6.4.1.ebuild, metadata.xml:
+  Add 0.6.4.1 from the gnome overlay, needed for gnome-3.2. Notable changes:
+  new eds, libsocialweb, and tracker backends; significant API changes.
 
   05 Oct 2011; Kacper Kowalik <xarthisius@gentoo.org> folks-0.4.3.ebuild:
   ppc stable wrt #369909
diff --git a/dev-libs/folks/folks-0.6.4.1.ebuild b/dev-libs/folks/folks-0.6.4.1.ebuild
new file mode 100644
index 000000000000..02843bf4e135
--- /dev/null
+++ b/dev-libs/folks/folks-0.6.4.1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/folks-0.6.4.1.ebuild,v 1.1 2011/11/04 04:07:45 tetromino Exp $
+
+EAPI="4"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+DESCRIPTION="libfolks is a library that aggregates people from multiple sources"
+HOMEPAGE="http://telepathy.freedesktop.org/wiki/Folks"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86 ~x86-linux"
+IUSE="eds socialweb test tracker utils vala"
+
+COMMON_DEPEND=">=dev-libs/glib-2.24:2
+	>=net-libs/telepathy-glib-0.13.1
+	dev-libs/dbus-glib
+	<dev-libs/libgee-0.7:0[introspection]
+	dev-libs/libxml2
+	>=gnome-base/gconf-2.31
+	sys-libs/ncurses
+	sys-libs/readline
+
+	eds? ( >=gnome-extra/evolution-data-server-3.1.5 )
+	socialweb? ( >=net-libs/libsocialweb-0.25.15 )
+	tracker? ( >=app-misc/tracker-0.12 )"
+
+# telepathy-mission-control needed at runtime; it is used by the telepathy
+# backend via telepathy-glib's AccountManager binding.
+RDEPEND="${COMMON_DEPEND}
+	net-im/telepathy-mission-control"
+
+# folks socialweb backend requires that libsocialweb be built with USE=vala,
+# even when building folks with --disable-vala.
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/gobject-introspection-0.9.12
+	>=dev-util/intltool-0.35.0
+	>=dev-util/pkgconfig-0.21
+	sys-devel/gettext
+
+	socialweb? ( >=net-libs/libsocialweb-0.25.15[vala] )
+	test? ( sys-apps/dbus )
+	vala? (
+		>=dev-lang/vala-0.13.4:0.14[vapigen]
+		>=net-libs/telepathy-glib-0.13.1[vala]
+		eds? ( >=gnome-extra/evolution-data-server-3.0.1[vala] ) )"
+
+# the inspect tool requires --enable-vala
+REQUIRED_USE="utils? ( vala )"
+
+# XXX: tests appear to use installed version of folks
+RESTRICT="test"
+
+pkg_setup() {
+	DOCS="AUTHORS ChangeLog NEWS README"
+	# Rebuilding docs needs valadoc, which has no release
+	G2CONF="${G2CONF}
+		$(use_enable eds eds-backend)
+		$(use_enable socialweb libsocialweb-backend)
+		$(use_enable tracker tracker-backend)
+		$(use_enable utils inspect-tool)
+		$(use_enable vala)
+		--enable-import-tool
+		--disable-docs
+		--disable-Werror"
+	if use vala; then
+		G2CONF="${G2CONF}
+		VALAC=$(type -p valac-0.14)
+		VAPIGEN=$(type -p vapigen-0.14)"
+	fi
+}
+
+src_test() {
+	# FIXME: several eds backend tests fail
+	sed -e 's/check: .*/check: /' \
+		-i tests/eds/Makefile || die "sed failed"
+	# Don't run make check in po/
+	cd tests
+	dbus-launch emake check
+}
diff --git a/dev-libs/folks/metadata.xml b/dev-libs/folks/metadata.xml
index da6fd63d0085..1a97bdb6332c 100644
--- a/dev-libs/folks/metadata.xml
+++ b/dev-libs/folks/metadata.xml
@@ -2,4 +2,12 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>gnome</herd>
+<use>
+  <flag name="socialweb">Load web service contacts using
+    <pkg>net-libs/libsocialweb</pkg></flag>
+  <flag name="tracker">Load contacts from <pkg>app-misc/tracker</pkg>
+    index</flag>
+  <flag name="utils">Build the folks-inspect utility</flag>
+  <flag name="vala">Regenerate pre-generated C code from Vala source</flag>
+</use>
 </pkgmetadata>