Version bump.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 17A85C72)

2 files changed, 137 insertions, 1 deletions

diff --git a/dev-python/pyside/ChangeLog b/dev-python/pyside/ChangeLog
index 28697bbde6cb..464c0f5754c7 100644
--- a/dev-python/pyside/ChangeLog
+++ b/dev-python/pyside/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pyside
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyside/ChangeLog,v 1.55 2013/10/04 16:17:01 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyside/ChangeLog,v 1.56 2013/11/14 00:46:04 pesa Exp $
+
+*pyside-1.2.1 (14 Nov 2013)
+
+  14 Nov 2013; Davide Pesavento <pesa@gentoo.org> +pyside-1.2.1.ebuild:
+  Version bump.
 
   04 Oct 2013; Mike Frysinger <vapier@gentoo.org> pyside-1.1.2-r1.ebuild:
   Mark arm stable #460234.
diff --git a/dev-python/pyside/pyside-1.2.1.ebuild b/dev-python/pyside/pyside-1.2.1.ebuild
new file mode 100644
index 000000000000..b4a36e2cb3dc
--- /dev/null
+++ b/dev-python/pyside/pyside-1.2.1.ebuild
@@ -0,0 +1,131 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyside/pyside-1.2.1.ebuild,v 1.1 2013/11/14 00:46:04 pesa Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2} )
+
+inherit multilib cmake-utils python-r1 virtualx
+
+MY_P="${PN}-qt4.8+${PV}"
+
+DESCRIPTION="Python bindings for the Qt framework"
+HOMEPAGE="http://qt-project.org/wiki/PySide"
+SRC_URI="http://download.qt-project.org/official_releases/${PN}/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+IUSE="X declarative designer help kde multimedia opengl phonon script scripttools sql svg test webkit xmlpatterns"
+
+REQUIRED_USE="
+	declarative? ( X )
+	designer? ( X )
+	help? ( X )
+	multimedia? ( X )
+	opengl? ( X )
+	phonon? ( X )
+	scripttools? ( X script )
+	sql? ( X )
+	svg? ( X )
+	test? ( X )
+	webkit? ( X )
+"
+
+# Minimal supported version of Qt.
+QT_PV="4.7.0:4"
+
+RDEPEND="
+	>=dev-python/shiboken-${PV}[${PYTHON_USEDEP}]
+	>=dev-qt/qtcore-${QT_PV}
+	X? (
+		>=dev-qt/qtgui-${QT_PV}[accessibility]
+		>=dev-qt/qttest-${QT_PV}
+	)
+	declarative? ( >=dev-qt/qtdeclarative-${QT_PV} )
+	designer? ( || ( dev-qt/designer:4 <dev-qt/qtgui-4.8.5:4 ) )
+	help? ( >=dev-qt/qthelp-${QT_PV} )
+	multimedia? ( >=dev-qt/qtmultimedia-${QT_PV} )
+	opengl? ( >=dev-qt/qtopengl-${QT_PV} )
+	phonon? (
+		kde? ( media-libs/phonon )
+		!kde? ( || ( >=dev-qt/qtphonon-${QT_PV} media-libs/phonon ) )
+	)
+	script? ( >=dev-qt/qtscript-${QT_PV} )
+	sql? ( >=dev-qt/qtsql-${QT_PV} )
+	svg? ( >=dev-qt/qtsvg-${QT_PV}[accessibility] )
+	webkit? ( >=dev-qt/qtwebkit-${QT_PV} )
+	xmlpatterns? ( >=dev-qt/qtxmlpatterns-${QT_PV} )
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtgui-${QT_PV}
+"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( ChangeLog )
+
+src_prepare() {
+	# Fix generated pkgconfig file to require the shiboken
+	# library suffixed with the correct python version.
+	sed -i -e '/^Requires:/ s/shiboken$/&@SHIBOKEN_PYTHON_SUFFIX@/' \
+		libpyside/pyside.pc.in || die
+
+	if use prefix; then
+		cp "${FILESDIR}"/rpath.cmake .
+		sed \
+			-i '1iinclude(rpath.cmake)' \
+			CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_build test TESTS)
+		$(cmake-utils_use_disable X QtGui)
+		$(cmake-utils_use_disable X QtTest)
+		$(cmake-utils_use_disable declarative QtDeclarative)
+		$(cmake-utils_use_disable designer QtDesigner)
+		$(cmake-utils_use_disable designer QtUiTools)
+		$(cmake-utils_use_disable help QtHelp)
+		$(cmake-utils_use_disable multimedia QtMultimedia)
+		$(cmake-utils_use_disable opengl QtOpenGL)
+		$(cmake-utils_use_disable phonon)
+		$(cmake-utils_use_disable script QtScript)
+		$(cmake-utils_use_disable scripttools QtScriptTools)
+		$(cmake-utils_use_disable sql QtSql)
+		$(cmake-utils_use_disable svg QtSvg)
+		$(cmake-utils_use_disable webkit QtWebKit)
+		$(cmake-utils_use_disable xmlpatterns QtXmlPatterns)
+	)
+
+	configuration() {
+		local mycmakeargs=(
+			-DPYTHON_SUFFIX="-${EPYTHON}"
+			"${mycmakeargs[@]}"
+		)
+		cmake-utils_src_configure
+	}
+	python_foreach_impl configuration
+}
+
+src_compile() {
+	python_foreach_impl cmake-utils_src_make
+}
+
+src_test() {
+	local PYTHONDONTWRITEBYTECODE
+	export PYTHONDONTWRITEBYTECODE
+
+	local VIRTUALX_COMMAND="cmake-utils_src_test"
+	python_foreach_impl virtualmake
+}
+
+src_install() {
+	installation() {
+		cmake-utils_src_install
+		mv "${ED}"usr/$(get_libdir)/pkgconfig/${PN}{,-${EPYTHON}}.pc || die
+	}
+	python_foreach_impl installation
+}