Migrate to distutils-r1.

(Portage version: 2.2.0_alpha151/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)

2 files changed, 70 insertions, 1 deletions

diff --git a/dev-python/sphinx/ChangeLog b/dev-python/sphinx/ChangeLog
index 2af3c3b2a83c..06e5af5412af 100644
--- a/dev-python/sphinx/ChangeLog
+++ b/dev-python/sphinx/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/sphinx
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/ChangeLog,v 1.121 2013/01/04 13:10:28 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/ChangeLog,v 1.122 2013/01/14 00:03:38 mgorny Exp $
+
+*sphinx-1.1.3-r4 (14 Jan 2013)
+
+  14 Jan 2013; Michał Górny <mgorny@gentoo.org> +sphinx-1.1.3-r4.ebuild:
+  Migrate to distutils-r1.
 
   04 Jan 2013; Agostino Sarubbo <ago@gentoo.org> sphinx-1.1.3-r3.ebuild:
   Stable for ppc64, wrt bug #449424
diff --git a/dev-python/sphinx/sphinx-1.1.3-r4.ebuild b/dev-python/sphinx/sphinx-1.1.3-r4.ebuild
new file mode 100644
index 000000000000..599b054cdde6
--- /dev/null
+++ b/dev-python/sphinx/sphinx-1.1.3-r4.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/sphinx-1.1.3-r4.ebuild,v 1.1 2013/01/14 00:03:38 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_5,2_6,2_7,3_1,3_2} pypy1_9 )
+
+inherit distutils-r1
+
+MY_PN="Sphinx"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="http://sphinx.pocoo.org/ http://pypi.python.org/pypi/Sphinx"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc latex test"
+
+RDEPEND=">=dev-python/docutils-0.7[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-1.2[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	latex? (
+		dev-texlive/texlive-latexextra
+		app-text/dvipng
+	)"
+DEPEND="${DEPEND}
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-python3.patch
+)
+
+python_compile() {
+	distutils-r1_python_compile
+
+	if use test; then
+		cp -r -l tests "${BUILD_DIR}"/lib || die
+
+		if [[ ${EPYTHON} == python3* ]]; then
+			2to3 -w --no-diffs "${BUILD_DIR}"/lib/tests || die
+		fi
+	fi
+}
+
+python_compile_all() {
+	use doc && emake -C doc SPHINXBUILD="${PYTHON} -m sphinx.__init__" html
+}
+
+python_test() {
+	nosetests -w "${BUILD_DIR}"/lib/tests || ewarn "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+
+	distutils-r1_python_install_all
+}