Bump to EAPI-2 to force sqlite deps so that tests have a chance of not failing

(Portage version: 2.2_rc28/cvs/Linux x86_64)

2 files changed, 66 insertions, 1 deletions

diff --git a/dev-python/sqlalchemy/ChangeLog b/dev-python/sqlalchemy/ChangeLog
index 54b1cd38efb4..ca928138c5e6 100644
--- a/dev-python/sqlalchemy/ChangeLog
+++ b/dev-python/sqlalchemy/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/sqlalchemy
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/ChangeLog,v 1.25 2009/03/20 13:15:50 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/ChangeLog,v 1.26 2009/04/01 11:45:14 patrick Exp $
+
+*sqlalchemy-0.5.2-r1 (01 Apr 2009)
+
+  01 Apr 2009; Patrick Lauer <patrick@gentoo.org>
+  +sqlalchemy-0.5.2-r1.ebuild:
+  Bump to EAPI-2 to force sqlite deps so that tests have a chance of not
+  failing
 
   20 Mar 2009; Joseph Jezak <josejx@gentoo.org> sqlalchemy-0.4.7_p1.ebuild,
   sqlalchemy-0.5.2.ebuild:
diff --git a/dev-python/sqlalchemy/sqlalchemy-0.5.2-r1.ebuild b/dev-python/sqlalchemy/sqlalchemy-0.5.2-r1.ebuild
new file mode 100644
index 000000000000..eca49431b1ae
--- /dev/null
+++ b/dev-python/sqlalchemy/sqlalchemy-0.5.2-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/sqlalchemy-0.5.2-r1.ebuild,v 1.1 2009/04/01 11:45:14 patrick Exp $
+
+EAPI="2"
+
+NEED_PYTHON=2.4
+
+inherit distutils
+
+MY_P=SQLAlchemy-${PV/_}
+
+DESCRIPTION="Python SQL toolkit and Object Relational Mapper."
+HOMEPAGE="http://www.sqlalchemy.org/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc examples firebird mssql mysql postgres +sqlite test"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+# note: if you use psycopg-1, then you need egenix-mx-base
+RDEPEND="firebird? ( dev-python/kinterbasdb )
+	mssql? ( dev-python/pymssql )
+	mysql? ( dev-python/mysql-python )
+	postgres? (
+		|| (
+			( >=dev-python/psycopg-2 )
+			( <dev-python/psycopg-2 dev-python/egenix-mx-base )
+		)
+	)
+	sqlite? (
+		>=dev-db/sqlite-3.3.13
+		|| ( dev-python/pysqlite >=dev-lang/python-2.5 )
+	)"
+
+DEPEND="dev-python/setuptools
+	test? (
+		>=dev-db/sqlite-3.3.13
+		|| ( dev-python/pysqlite >=dev-lang/python-2.5[sqlite] )
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+src_install() {
+	distutils_src_install
+
+	use doc && dohtml doc/*
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+}
+
+src_test() {
+	PYTHONPATH="./test/" "${python}" test/alltests.py || die "tests failed"
+}