Restrict -r0 to <sys-devel/bison-3 and fix building in -r1 wrt #511560 by "zimous"

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

1 files changed, 66 insertions, 0 deletions

diff --git a/dev-util/xxdiff/xxdiff-4.0_beta1_p20110426-r1.ebuild b/dev-util/xxdiff/xxdiff-4.0_beta1_p20110426-r1.ebuild
new file mode 100644
index 000000000000..f54a832cbf66
--- /dev/null
+++ b/dev-util/xxdiff/xxdiff-4.0_beta1_p20110426-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/xxdiff/xxdiff-4.0_beta1_p20110426-r1.ebuild,v 1.1 2014/05/27 12:36:00 ssuominen Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 eutils qt4-r2
+
+DESCRIPTION="A graphical file and directories comparator and merge tool"
+HOMEPAGE="http://furius.ca/xxdiff/"
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="dev-qt/qtgui:4"
+DEPEND="${RDEPEND}
+	virtual/yacc"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-gcc47.patch \
+		"${FILESDIR}"/${P}-bison3.patch
+
+	pushd src >/dev/null
+	sed -i -e '/qPixmapFromMimeSource/d' *.ui || die #365019
+	qt4-r2_src_prepare
+	popd
+
+	distutils-r1_src_prepare
+}
+
+src_configure() {
+	pushd src >/dev/null
+	qt4-r2_src_configure
+	cat Makefile.extra >> Makefile
+	popd
+
+	distutils-r1_src_configure
+}
+
+src_compile() {
+	pushd src >/dev/null
+	qt4-r2_src_compile
+	popd
+
+	distutils-r1_src_compile
+}
+
+src_install() {
+	dobin bin/xxdiff
+
+	distutils-r1_src_install
+
+	dodoc CHANGES README* TODO doc/*.txt src/doc.txt
+
+	dohtml doc/*.{png,html} src/doc.html
+
+	# example tools, use these to build your own ones
+	insinto /usr/share/doc/${PF}
+	doins -r tools
+}