Version bump.

(Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 92 insertions, 2 deletions

diff --git a/dev-util/sysdig/ChangeLog b/dev-util/sysdig/ChangeLog
index ba875f3e8cb1..38ce34070a19 100644
--- a/dev-util/sysdig/ChangeLog
+++ b/dev-util/sysdig/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/sysdig
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/sysdig/ChangeLog,v 1.2 2014/11/22 10:36:18 mgorny Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/sysdig/ChangeLog,v 1.3 2015/03/04 09:14:27 mgorny Exp $
+
+*sysdig-0.1.98 (04 Mar 2015)
+
+  04 Mar 2015; Michał Górny <mgorny@gentoo.org> +sysdig-0.1.98.ebuild:
+  Version bump.
 
   22 Nov 2014; Michał Górny <mgorny@gentoo.org> metadata.xml,
   sysdig-0.1.92.ebuild:
diff --git a/dev-util/sysdig/sysdig-0.1.98.ebuild b/dev-util/sysdig/sysdig-0.1.98.ebuild
new file mode 100644
index 000000000000..fcd9a0f0f494
--- /dev/null
+++ b/dev-util/sysdig/sysdig-0.1.98.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/sysdig/sysdig-0.1.98.ebuild,v 1.1 2015/03/04 09:14:27 mgorny Exp $
+
+EAPI=5
+
+inherit linux-mod bash-completion-r1 cmake-utils
+
+DESCRIPTION="A system exploration and troubleshooting tool"
+HOMEPAGE="http://www.sysdig.org/"
+# mirrored from https://github.com/draios/sysdig/archive/${PV}.tar.gz
+SRC_URI="http://dev.gentoo.org/~mgorny/dist/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+modules"
+
+RDEPEND="dev-lang/luajit:2=
+	dev-libs/jsoncpp:0=
+	sys-libs/zlib:0="
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/os-headers"
+
+# needed for the kernel module
+CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS TRACEPOINTS"
+
+pkg_pretend() {
+	use modules && linux-mod_pkg_setup
+}
+
+pkg_setup() {
+	use modules && linux-mod_pkg_setup
+}
+
+src_prepare() {
+	sed -i -e 's:-ggdb::' CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# we will use linux-mod for that
+		-DBUILD_DRIVER=OFF
+		# libscap examples are not installed or really useful
+		-DBUILD_LIBSCAP_EXAMPLES=OFF
+
+		# unbundle the deps
+		-DUSE_BUNDLED_LUAJIT=OFF
+		-DLUAJIT_PREFIX="${EPREFIX}"/usr
+		-DLUAJIT_INCLUDE="${EPREFIX}"/usr/include/luajit-2.0
+		-DUSE_BUNDLED_JSONCPP=OFF
+		-DJSONCPP_PREFIX="${EPREFIX}"/usr
+		-DJSONCPP_INCLUDE="${EPREFIX}"/usr/include/jsoncpp
+		-DUSE_BUNDLED_ZLIB=OFF
+		-DZLIB_PREFIX="${EPREFIX}"/usr
+	)
+
+	cmake-utils_src_configure
+
+	# setup linux-mod ugliness
+	MODULE_NAMES="sysdig-probe(extra:${BUILD_DIR}/driver:)"
+	BUILD_TARGETS="driver"
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	use modules && linux-mod_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use modules && linux-mod_src_install
+
+	# remove sources
+	rm -r "${ED%/}"/usr/src || die
+
+	# move bashcomp to the proper location
+	dobashcomp "${ED%/}"/usr/etc/bash_completion.d/sysdig || die
+	rm -r "${ED%/}"/usr/etc || die
+}