Version bump to 1.5.7.

(Portage version: 2.2.0_alpha4/cvs/Linux x86_64)

2 files changed, 65 insertions, 1 deletions

diff --git a/dev-vcs/gitolite-gentoo/ChangeLog b/dev-vcs/gitolite-gentoo/ChangeLog
index 19972f5cb263..a3564dcb6fa0 100644
--- a/dev-vcs/gitolite-gentoo/ChangeLog
+++ b/dev-vcs/gitolite-gentoo/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-vcs/gitolite-gentoo
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/gitolite-gentoo/ChangeLog,v 1.3 2010/11/06 23:05:05 idl0r Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/gitolite-gentoo/ChangeLog,v 1.4 2010/11/14 09:59:01 idl0r Exp $
+
+*gitolite-gentoo-1.5.7 (14 Nov 2010)
+
+  14 Nov 2010; Christian Ruppert <idl0r@gentoo.org>
+  +gitolite-gentoo-1.5.7.ebuild:
+  Version bump to 1.5.7.
 
   06 Nov 2010; Christian Ruppert <idl0r@gentoo.org>
   gitolite-gentoo-1.5.6-r1.ebuild:
diff --git a/dev-vcs/gitolite-gentoo/gitolite-gentoo-1.5.7.ebuild b/dev-vcs/gitolite-gentoo/gitolite-gentoo-1.5.7.ebuild
new file mode 100644
index 000000000000..52fd13478b22
--- /dev/null
+++ b/dev-vcs/gitolite-gentoo/gitolite-gentoo-1.5.7.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/gitolite-gentoo/gitolite-gentoo-1.5.7.ebuild,v 1.1 2010/11/14 09:59:01 idl0r Exp $
+
+EAPI=3
+
+inherit eutils perl-module
+
+DESCRIPTION="Highly flexible server for git directory version tracker, Gentoo fork"
+HOMEPAGE="http://git.overlays.gentoo.org/gitweb/?p=proj/gitolite-gentoo.git;a=summary"
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="contrib vim-syntax"
+
+DEPEND="dev-lang/perl
+	>=dev-vcs/git-1.6.2"
+RDEPEND="${DEPEND}
+	!dev-vcs/gitolite
+	dev-perl/Net-SSH-AuthorizedKeysFile
+	vim-syntax? ( app-vim/gitolite-syntax )"
+
+pkg_setup() {
+	enewgroup git
+	enewuser git -1 /bin/bash /var/lib/gitolite git
+}
+
+src_prepare() {
+	rm -rf Makefile doc/COPYING contrib/{autotoc,gitweb,vim}
+
+	echo "${PF}-gentoo" > conf/VERSION
+}
+
+src_install() {
+	dodir /usr/share/gitolite/{conf,hooks} /usr/bin || die
+
+	./src/gl-system-install "${D}"/usr/bin \
+		"${D}"/usr/share/gitolite/conf "${D}"/usr/share/gitolite/hooks || die
+	dosed "s:${D}::g" usr/bin/gl-setup \
+		usr/share/gitolite/conf/example.gitolite.rc || die
+
+	rm "${D}/usr/bin/gitolite.pm"
+	insinto "${VENDOR_LIB}"
+	doins src/gitolite.pm || die
+
+	dodoc README.mkd doc/*
+
+	if use contrib; then
+		insinto /usr/share/doc/${PF}
+		doins -r contrib/ || die
+	fi
+
+	keepdir /var/lib/gitolite
+	fowners git:git /var/lib/gitolite
+	fperms 750 /var/lib/gitolite
+}