rev bump to get upstream hot fix

(Portage version: 2.1.9.24/cvs/Linux i686)

2 files changed, 120 insertions, 1 deletions

diff --git a/games-strategy/ufo-ai/ChangeLog b/games-strategy/ufo-ai/ChangeLog
index 0b866707c06a..a6d3445b3dc2 100644
--- a/games-strategy/ufo-ai/ChangeLog
+++ b/games-strategy/ufo-ai/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for games-strategy/ufo-ai
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/ufo-ai/ChangeLog,v 1.29 2010/11/30 21:14:55 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/ufo-ai/ChangeLog,v 1.30 2010/12/20 05:09:05 mr_bones_ Exp $
+
+*ufo-ai-2.3.1-r1 (20 Dec 2010)
+
+  20 Dec 2010; Michael Sterrett <mr_bones_@gentoo.org>
+  +ufo-ai-2.3.1-r1.ebuild:
+  rev bump to get upstream hot fix
 
 *ufo-ai-2.3.1 (30 Nov 2010)
 
diff --git a/games-strategy/ufo-ai/ufo-ai-2.3.1-r1.ebuild b/games-strategy/ufo-ai/ufo-ai-2.3.1-r1.ebuild
new file mode 100644
index 000000000000..3c8da5141a0a
--- /dev/null
+++ b/games-strategy/ufo-ai/ufo-ai-2.3.1-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/ufo-ai/ufo-ai-2.3.1-r1.ebuild,v 1.1 2010/12/20 05:09:05 mr_bones_ Exp $
+
+EAPI=2
+inherit eutils flag-o-matic games
+
+MY_P="${P/o-a/oa}"
+
+DESCRIPTION="UFO: Alien Invasion - X-COM inspired strategy game"
+HOMEPAGE="http://ufoai.sourceforge.net/"
+SRC_URI="mirror://sourceforge/ufoai/${MY_P}-source.tar.bz2
+	mirror://sourceforge/ufoai/${MY_P}-data.tar
+	http://mattn.ninex.info/1maps.pk3"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug dedicated doc editor"
+
+# Dependencies and more instructions can be found here:
+# http://ufoai.ninex.info/wiki/index.php/Compile_for_Linux
+RDEPEND="!dedicated? (
+		virtual/opengl
+		virtual/glu
+		media-libs/libsdl
+		media-libs/sdl-image[jpeg,png]
+		media-libs/sdl-ttf
+		media-libs/sdl-mixer
+		media-libs/jpeg
+		media-libs/libpng
+		media-libs/libogg
+		media-libs/libvorbis
+		x11-proto/xf86vidmodeproto
+	)
+	net-misc/curl
+	sys-devel/gettext
+	sys-libs/zlib
+	editor? (
+		dev-libs/libxml2
+		media-libs/jpeg
+		media-libs/openal
+		x11-libs/gtkglext
+		x11-libs/gtksourceview
+	)"
+
+DEPEND="${RDEPEND}
+	doc? (
+		virtual/latex-base
+		dev-tex/pdftex
+		dev-texlive/texlive-latexextra
+	)"
+
+S=${WORKDIR}/${MY_P}-source
+
+src_prepare() {
+	cp "${DISTDIR}"/1maps.pk3 "${WORKDIR}"/base/ || die
+	mv "${WORKDIR}"/base/ "${S}"/ || die "Moving data failed"
+}
+
+src_configure() {
+	strip-flags # bug #330381
+	egamesconf \
+		$(use_enable !debug release) \
+		$(use_enable editor ufo2map) \
+		$(use_enable editor uforadiant) \
+		--enable-dedicated \
+		$(use_enable !dedicated client) \
+		--bindir="${GAMES_BINDIR}" \
+		--datarootdir="${GAMES_DATADIR_BASE}" \
+		--datadir="${GAMES_DATADIR}" \
+		--localedir="${GAMES_DATADIR}/${PN/-}/base/i18n/"
+}
+
+src_compile() {
+	if use doc ; then
+		emake pdf-manual || die "emake pdf-manual failed"
+	fi
+
+	emake || die "emake failed"
+	emake lang || die "emake lang failed"
+
+	if use editor; then
+		emake uforadiant || die "emake uforadiant failed"
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install_exec || die
+
+	newicon src/ports/linux/ufo.png ${PN}.png || die
+	make_desktop_entry ufoded "UFO: Alien Invasion Server" ${PN}
+	if ! use dedicated ; then
+		make_desktop_entry ufo "UFO: Alien Invasion" ${PN}
+	fi
+
+	# install data
+	insinto "${GAMES_DATADIR}"/${PN/-}/base/
+	doins base/*.pk3 || die
+
+	if use doc ; then
+		dodoc src/docs/tex/ufo-manual_EN.pdf || die
+	fi
+
+	# move translations where they belong
+	dodir "${GAMES_DATADIR_BASE}/locale" || die
+	mv "${D}/${GAMES_DATADIR}/${PN/-}/base/i18n/"* \
+		"${D}/${GAMES_DATADIR_BASE}/locale/" || die
+	rm -rf "${D}/${GAMES_DATADIR}/${PN/-}/base/i18n/" || die
+	dosym "${GAMES_DATADIR_BASE}/locale/" "${GAMES_DATADIR}/${PN/-}/base/i18n" || die
+
+	prepgamesdirs
+}