Version bump KDE SC 4.9.0

(Portage version: 2.2.0_alpha120/cvs/Linux x86_64)

2 files changed, 84 insertions, 1 deletions

diff --git a/kde-base/korundum/ChangeLog b/kde-base/korundum/ChangeLog
index c7828bea5105..2459af47bc68 100644
--- a/kde-base/korundum/ChangeLog
+++ b/kde-base/korundum/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/korundum
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/ChangeLog,v 1.116 2012/06/21 21:54:58 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/ChangeLog,v 1.117 2012/08/01 22:17:21 johu Exp $
+
+*korundum-4.9.0 (01 Aug 2012)
+
+  01 Aug 2012; Johannes Huber <johu@gentoo.org> +korundum-4.9.0.ebuild:
+  Version bump KDE SC 4.9.0
 
 *korundum-4.8.4 (21 Jun 2012)
 
diff --git a/kde-base/korundum/korundum-4.9.0.ebuild b/kde-base/korundum/korundum-4.9.0.ebuild
new file mode 100644
index 000000000000..6c38d9e37b3e
--- /dev/null
+++ b/kde-base/korundum/korundum-4.9.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/korundum-4.9.0.ebuild,v 1.1 2012/08/01 22:17:21 johu Exp $
+
+EAPI=4
+
+OPENGL_REQUIRED="always"
+KDE_SCM="git"
+
+USE_RUBY="ruby18"
+# No ruby19 for three reasons:
+# 1) it does not build (yet) - will likely be solved soon
+# 2) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
+# 3) the ebuild can only be installed for one ruby variant, otherwise the compiled
+#    files with identical path+name will overwrite each other - difficult :(
+
+inherit kde4-base ruby-ng
+
+DESCRIPTION="KDE Ruby bindings"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="akonadi debug kate okular"
+
+# unfortunately single modules cannot be disabled with cmake defines
+# possible more useflags have no effect... does anyone actually build this stuff?
+# may need some hacking, for now semantic-desktop just becomes a hard dependency
+
+DEPEND="
+	$(add_kdebase_dep qtruby)
+	$(add_kdebase_dep smokekde 'kate?,okular?,semantic-desktop')
+	$(add_kdebase_dep smokeqt)
+"
+RDEPEND="${DEPEND}
+"
+
+# Split from kdebindings-ruby in 4.7
+add_blocker kdebindings-ruby
+
+pkg_setup() {
+	ruby-ng_pkg_setup
+	kde4-base_pkg_setup
+}
+
+src_unpack() {
+	local S="${WORKDIR}/${P}"
+	kde4-base_src_unpack
+
+	cd "${WORKDIR}"
+	mkdir all
+	mv ${P} all/ || die "Could not move sources"
+}
+
+all_ruby_prepare() {
+	kde4-base_src_prepare
+}
+
+each_ruby_configure() {
+	CMAKE_USE_DIR=${S}
+	mycmakeargs=(
+		-DRUBY_LIBRARY=$(ruby_get_libruby)
+		-DRUBY_INCLUDE_PATH=$(ruby_get_hdrdir)
+		-DRUBY_EXECUTABLE=${RUBY}
+		$(cmake-utils_use_with akonadi)
+		$(cmake-utils_use_with akonadi KdepimLibs)
+		$(cmake-utils_use_disable kate)
+		$(cmake-utils_use_with okular)
+	)
+	kde4-base_src_configure
+}
+
+each_ruby_compile() {
+	CMAKE_USE_DIR=${S}
+	kde4-base_src_compile
+}
+
+each_ruby_install() {
+	CMAKE_USE_DIR=${S}
+	kde4-base_src_install
+}