Add support for small-scale filesystem scale

(Portage version: 2.1.10.10/cvs/Linux x86_64)

3 files changed, 234 insertions, 3 deletions

diff --git a/mail-filter/dspam/ChangeLog b/mail-filter/dspam/ChangeLog
index fde1bec0fe58..3e2794094a07 100644
--- a/mail-filter/dspam/ChangeLog
+++ b/mail-filter/dspam/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for mail-filter/dspam
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/dspam/ChangeLog,v 1.133 2011/08/06 03:45:01 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/dspam/ChangeLog,v 1.134 2011/08/06 10:16:52 eras Exp $
+
+*dspam-3.10.0-r1 (06 Aug 2011)
+
+  06 Aug 2011; Eray Aslan <eras@gentoo.org> +dspam-3.10.0-r1.ebuild,
+  metadata.xml:
+  Add support for small-scale filesystem scale
 
   06 Aug 2011; Tim Harder <radhermit@gentoo.org> dspam-3.10.0.ebuild:
   Enable hash storage driver by default.
diff --git a/mail-filter/dspam/dspam-3.10.0-r1.ebuild b/mail-filter/dspam/dspam-3.10.0-r1.ebuild
new file mode 100644
index 000000000000..6f8f14e1196a
--- /dev/null
+++ b/mail-filter/dspam/dspam-3.10.0-r1.ebuild
@@ -0,0 +1,222 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/dspam/dspam-3.10.0-r1.ebuild,v 1.1 2011/08/06 10:16:52 eras Exp $
+
+EAPI=4
+
+inherit eutils
+
+DESCRIPTION="A statistical-algorithmic hybrid anti-spam filter"
+HOMEPAGE="http://dspam.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
+DRIVERS_IUSE="+hash mysql postgres sqlite"
+SCALES_IUSE="+small-scale domain-scale large-scale"
+IUSE="clamav daemon debug ldap static-libs syslog virtual-users user-homedirs ${DRIVERS_IUSE} ${SCALES_IUSE}"
+
+DEPEND="
+	ldap? ( net-nds/openldap )
+	mysql? ( >=virtual/mysql-5.0 )
+	postgres? ( dev-db/postgresql-base )
+	sqlite? ( dev-db/sqlite:3 )
+"
+
+RDEPEND="
+	${DEPEND}
+	clamav? ( app-antivirus/clamav )
+	syslog?	( virtual/logger )
+"
+
+# Demands on sane USE flags:
+# - find out what driver to use: select at least one
+# - if static-libs is set, only one driver may be selected
+# - find out what scale to use: choose at most one
+# - user-homedirs does not work with virtual-users
+# - virtual-users does not work with hash or sqlite
+REQUIRED_USE="
+	|| ( ${DRIVERS_IUSE//+} )
+	static-libs? ( ^^ ( ${DRIVERS_IUSE//+} ) )
+	^^ ( ${SCALES_IUSE//+} )
+	virtual-users? ( !user-homedirs )
+	hash? ( !virtual-users )
+	sqlite? ( !virtual-users )
+"
+
+# dspam setup defaults
+DSPAM_HOME=/var/spool/dspam
+DSPAM_CONF=/etc/dspam
+DSPAM_LOG=/var/log/dspam
+DSPAM_MODE=2510
+DSPAM_DRIVERS=
+DSPAM_DRIVERS_EXTRAS=
+
+pkg_setup() {
+	# setup storage, this sets DSPAM_DRIVERS
+	dspam_setup_storage_drivers
+
+	# create dspam user and group
+	dspam_setup_user
+}
+
+src_configure() {
+	local myconf=""
+	if ! use large-scale && ! use domain-scale ; then
+		# default to domain-scale
+		myconf="--disable-large-scale --enable-domain-scale"
+	fi
+
+	econf \
+	--sysconfdir=${DSPAM_CONF} \
+	--with-dspam-home=${DSPAM_HOME} \
+	--with-dspam-home-group=dspam \
+	--with-dspam-mode=${DSPAM_MODE} \
+	--with-dspam-group=dspam \
+	--with-logdir=${DSPAM_LOG} \
+	--enable-external-lookup \
+	--enable-long-usernames \
+	--enable-split-configuration \
+	$(use_enable clamav) \
+	$(use_enable daemon) \
+	$(use_enable debug) \
+	$(use_enable debug bnr-debug) \
+	$(use_enable debug verbose-debug) \
+	$(use_enable domain-scale) \
+	$(use_enable large-scale) \
+	$(use_enable static-libs static) \
+	$(use_enable syslog) \
+	$(use_enable user-homedirs homedir) \
+	$(use_enable virtual-users) \
+	--with-storage-driver=${DSPAM_DRIVERS} ${DSPAM_DRIVERS_EXTRAS} \
+	$(use mysql || use postgres && echo "--enable-preferences-extension") \
+	$(use syslog || echo "--with-logfile=${DSPAM_LOG}/dspam.log") \
+	${myconf}
+}
+
+dspam_setup_user() {
+	# DSPAM CGI web gui (www-apps/dspam-web) needs to run as a regular user
+	# under suexec in apache, so DSPAM user/group need to be regular users too
+
+	local euid egid
+	for euid in {1000..5000} ; do
+		[ -z "$(egetent passwd ${euid})" ] && break
+	done
+	for egid in {1000..5000} ; do
+		[ -z "$(egetent group ${egid})" ] && break
+	done
+	enewgroup dspam ${egid}
+	enewuser dspam ${euid} -1 "${DSPAM_HOMEDIR}" dspam,mail
+}
+
+dspam_setup_storage_drivers() {
+	# Find out which storage drivers need to be enabled, and set some
+	# variables so that src_configure can pick them up
+
+	if use hash; then
+		DSPAM_DRIVERS+=",hash_drv"
+	fi
+
+	if use mysql; then
+		DSPAM_DRIVERS+=",mysql_drv"
+		DSPAM_DRIVERS_EXTRAS+="--with-mysql-includes=/usr/include/mysql "
+	fi
+
+	if use postgres; then
+		DSPAM_DRIVERS+=",pgsql_drv"
+	fi
+
+	if use sqlite; then
+		DSPAM_DRIVERS+=",sqlite3_drv"
+	fi
+
+	if ! use static-libs; then
+		# set the driver name twice to avoid a static build
+		DSPAM_DRIVERS+=${DSPAM_DRIVERS}
+	fi
+
+	# remove first comma separator
+	DSPAM_DRIVERS=${DSPAM_DRIVERS:1}
+	einfo "Building with drivers: ${DSPAM_DRIVERS}"
+	#echo DSPAM_DRIVERS_EXTRAS=$DSPAM_DRIVERS_EXTRAS
+}
+
+src_install() {
+	default
+
+	if use daemon; then
+		newinitd "${FILESDIR}/dspam.initd" dspam
+		newconfd "${FILESDIR}/dspam.confd" dspam
+	fi
+
+	if use mysql; then
+		insinto "/usr/share/${PN}/mysql"
+
+		local files="mysql_objects-4.1.sql mysql_objects-space.sql mysql_objects-speed.sql purge-4.1.sql purge.sql"
+		if use virtual-users; then
+			files+=" virtual_user_aliases.sql virtual_users.sql"
+		fi
+
+		for file in $files; do
+			doins src/tools.mysql_drv/${file}
+		done
+	fi
+
+	if use postgres; then
+		insinto "/usr/share/${PN}/pgsql"
+
+		local files="pgsql_objects.sql purge-pe.sql purge.sql"
+		if use virtual-users; then
+			files+=" virtual_users.sql"
+		fi
+
+		for file in $files; do
+			doins src/tools.pgsql_drv/${file}
+		done
+	fi
+
+	if use sqlite; then
+		insinto "/usr/share/${PN}/sqlite"
+		newins src/tools.sqlite_drv/purge-3.sql purge.sql
+	fi
+
+	insinto "${DSPAM_HOME}/txt"
+	doins txt/*.txt
+	for i in spam nonspam; do
+		echo "Scanned and tagged with DSPAM ${PV} on Gentoo Linux as ${i} by ISP" > "${T}/msgtag.${i}"
+		doins "${T}/msgtag.${i}"
+	done
+
+	exeinto /usr/bin
+	newexe contrib/dspam_maintenance/dspam_maintenance.sh dspam_maintenance
+	exeinto /etc/cron.daily
+	newexe "${FILESDIR}/dspam.cron-r4" dspam
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/dspam.logrotate" dspam
+
+	dodoc CHANGELOG README* RELEASE.NOTES UPGRADING doc/*.txt
+}
+
+pkg_preinst() {
+	# dspam-3.10.0: config dir change, should be removed at some later point
+	ewarn "The configuration directory of DSPAM has been relocated from /etc/mail/dspam to ${DSPAM_CONF}."
+	if [ -d "${ROOT}/etc/mail/dspam" ]; then
+		if [ -h "${ROOT}${DSPAM_CONF}" ]; then
+			# symlink, this is the setup in older ebuilds
+			ewarn "Moving contents of /etc/mail/dspam to ${DSPAM_CONF} ..."
+			rm "${ROOT}${DSPAM_CONF}" && mv "${ROOT}/etc/mail/dspam" "${DSPAM_CONF}"
+			eend $?
+
+		elif [ -d "${ROOT}${DSPAM_CONF}" ]; then
+			# directory and no symlink, do it manually since we cannot decide.
+			ewarn "You have both /etc/mail/dspam and ${DSPAM_CONF} directories, please delete the former."
+
+		else
+			# nothing interesting in /etc/dspam
+			ewarn "Moving contents of /etc/mail/dspam to ${DSPAM_CONF} ..."
+			mv "${ROOT}/etc/mail/dspam" "${DSPAM_CONF}"
+			eend $?
+		fi
+	fi
+}
diff --git a/mail-filter/dspam/metadata.xml b/mail-filter/dspam/metadata.xml
index 28c56e67dbe2..28501bf25eb0 100644
--- a/mail-filter/dspam/metadata.xml
+++ b/mail-filter/dspam/metadata.xml
@@ -30,11 +30,14 @@
 	<flag name='virtual-users'>
 		Build with virtual-users support
 	</flag>
+	<flag name='small-scale'>
+		Build for small scale setups - puts data to $HOME/data/user
+	</flag>
 	<flag name='domain-scale'>
-		Build with domain scale setups
+		Build for domain scale setups - puts data to $HOME/data/domain.com/user
 	</flag>
 	<flag name='large-scale'>
-		Build with large scale setups
+		Build for large scale setups - puts data to $HOME/data/u/s/user
 	</flag>
 	<flag name='hash'>
 		Enable support for the file-orientated hash driver