media-gfx/gimp: Add linguas_* use flags to latest 2.8.x ebuild (bug #416597)

(Portage version: 2.1.10.56/cvs/Linux x86_64)

2 files changed, 167 insertions, 1 deletions

diff --git a/media-gfx/gimp/ChangeLog b/media-gfx/gimp/ChangeLog
index 42a65589759b..1b568a30c629 100644
--- a/media-gfx/gimp/ChangeLog
+++ b/media-gfx/gimp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/gimp
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.367 2012/05/28 14:17:33 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.368 2012/05/28 21:01:14 sping Exp $
+
+*gimp-2.8.0-r1 (28 May 2012)
+
+  28 May 2012; Sebastian Pipping <sping@gentoo.org> +gimp-2.8.0-r1.ebuild:
+  Add linguas_* use flags to latest 2.8.x ebuild (bug #416597)
 
   28 May 2012; Raúl Porcel <armin76@gentoo.org> gimp-2.6.12.ebuild:
   alpha/ia64/sparc stable wrt #410403
diff --git a/media-gfx/gimp/gimp-2.8.0-r1.ebuild b/media-gfx/gimp/gimp-2.8.0-r1.ebuild
new file mode 100644
index 000000000000..e28ba6b8c51d
--- /dev/null
+++ b/media-gfx/gimp/gimp-2.8.0-r1.ebuild
@@ -0,0 +1,161 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/gimp-2.8.0-r1.ebuild,v 1.1 2012/05/28 21:01:14 sping Exp $
+
+EAPI="3"
+PYTHON_DEPEND="python? 2:2.5"
+
+inherit versionator autotools eutils gnome2 fdo-mime multilib python
+
+DESCRIPTION="GNU Image Manipulation Program"
+HOMEPAGE="http://www.gimp.org/"
+SRC_URI="mirror://gimp/v$(get_version_component_range 1-2)/${P}.tar.bz2"
+LICENSE="GPL-3 LGPL-3"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+LANGS="am ar ast az be bg br ca ca@valencia cs csb da de dz el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu id is it ja ka kk km kn ko lt lv mk ml ms my nb nds ne nl nn oc pa pl pt pt_BR ro ru rw si sk sl sr sr@latin sv ta te th tr tt uk vi xh zh_CN zh_HK zh_TW"  # for yi see bug #418053
+IUSE="alsa aalib altivec bzip2 curl dbus debug doc exif gnome gs jpeg jpeg2k lcms mmx mng pdf png python smp sse svg tiff udev webkit wmf xpm"
+
+for lang in ${LANGS}; do
+	IUSE+=" linguas_${lang}"
+done
+
+RDEPEND=">=dev-libs/glib-2.30.2:2
+	>=dev-libs/atk-2.2.0
+	>=x11-libs/gtk+-2.24.10:2
+	>=x11-libs/gdk-pixbuf-2.24.1:2
+	>=x11-libs/cairo-1.10.2
+	>=x11-libs/pango-1.29.4
+	xpm? ( x11-libs/libXpm )
+	>=media-libs/freetype-2.1.7
+	>=media-libs/fontconfig-2.2.0
+	sys-libs/zlib
+	dev-libs/libxml2
+	dev-libs/libxslt
+	x11-themes/hicolor-icon-theme
+	>=media-libs/babl-0.1.10
+	>=media-libs/gegl-0.2.0
+	aalib? ( media-libs/aalib )
+	alsa? ( media-libs/alsa-lib )
+	curl? ( net-misc/curl )
+	dbus? ( dev-libs/dbus-glib )
+	gnome? ( gnome-base/gvfs )
+	webkit? ( >=net-libs/webkit-gtk-1.6.1:2 )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( media-libs/jasper )
+	exif? ( >=media-libs/libexif-0.6.15 )
+	lcms? ( >=media-libs/lcms-1.16:0 )
+	mng? ( media-libs/libmng )
+	pdf? ( >=app-text/poppler-0.12.4[cairo] )
+	png? ( >=media-libs/libpng-1.2.37:0 )
+	python?	( >=dev-python/pygtk-2.10.4:2 )
+	tiff? ( >=media-libs/tiff-3.5.7:0 )
+	svg? ( >=gnome-base/librsvg-2.34.2:2 )
+	wmf? ( >=media-libs/libwmf-0.2.8 )
+	x11-libs/libXcursor
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )
+	gs? ( app-text/ghostscript-gpl )
+	udev? ( sys-fs/udev[gudev] )"
+DEPEND="${RDEPEND}
+	sys-apps/findutils
+	virtual/pkgconfig
+	>=dev-util/intltool-0.40.1
+	>=sys-devel/gettext-0.17
+	doc? ( >=dev-util/gtk-doc-1 )
+	>=sys-devel/libtool-2.2
+	>=sys-devel/automake-1.11
+	dev-util/gtk-doc-am"  # due to our call to eautoreconf below (bug #386453)
+
+DOCS="AUTHORS ChangeLog* HACKING NEWS README*"
+
+S="${WORKDIR}"/${P}
+
+pkg_setup() {
+	G2CONF="--enable-default-binary \
+		--with-x \
+		$(use_with aalib aa) \
+		$(use_with alsa) \
+		$(use_enable altivec) \
+		$(use_with bzip2) \
+		$(use_with curl libcurl) \
+		$(use_with dbus) \
+		$(use_with gnome gvfs) \
+		$(use_with webkit) \
+		$(use_with jpeg libjpeg) \
+		$(use_with jpeg2k libjasper) \
+		$(use_with exif libexif) \
+		$(use_with lcms) \
+		$(use_with gs) \
+		$(use_enable mmx) \
+		$(use_with mng libmng) \
+		$(use_with pdf poppler) \
+		$(use_with png libpng) \
+		$(use_enable python) \
+		$(use_enable smp mp) \
+		$(use_enable sse) \
+		$(use_with svg librsvg) \
+		$(use_with tiff libtiff) \
+		$(use_with udev gudev) \
+		$(use_with wmf) \
+		--with-xmc \
+		$(use_with xpm libxpm) \
+		--without-xvfb-run"
+
+	if use python; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.7.4-no-deprecation.patch  # bug 395695, comment 9 and 16
+	epatch "${FILESDIR}"/${PN}-2.8.0-bzip2.patch  # bug 414525
+	eautoreconf  # If you remove this: remove dev-util/gtk-doc-am from DEPEND, too
+
+	echo '#!/bin/sh' > py-compile
+	gnome2_src_prepare
+}
+
+_clean_up_locales() {
+	elog "Cleaning up locales..."
+	for lang in ${LANGS} yi; do  # for yi see bug #418053
+		use "linguas_${lang}" && {
+			elog "- keeping ${lang}"
+			continue
+		}
+		rm -Rf "${D}"/usr/share/locale/"${lang}" || die
+	done
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use python; then
+		python_convert_shebangs -r $(python_get_version) "${ED}"
+		python_need_rebuild
+	fi
+
+	# Workaround for bug #321111 to give GIMP the least
+	# precedence on PDF documents by default
+	mv "${D}"/usr/share/applications/{,zzz-}gimp.desktop || die
+
+	find "${D}" -name '*.la' -delete || die
+
+	_clean_up_locales
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	use python && python_mod_optimize /usr/$(get_libdir)/gimp/2.0/python \
+		/usr/$(get_libdir)/gimp/2.0/plug-ins
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+
+	use python && python_mod_cleanup /usr/$(get_libdir)/gimp/2.0/python \
+		/usr/$(get_libdir)/gimp/2.0/plug-ins
+}