Version bump.

(Portage version: 2.2.0_alpha116/cvs/Linux x86_64)

2 files changed, 78 insertions, 1 deletions

diff --git a/media-gfx/luminance-hdr/ChangeLog b/media-gfx/luminance-hdr/ChangeLog
index eceef0ad6e90..68e895296dc6 100644
--- a/media-gfx/luminance-hdr/ChangeLog
+++ b/media-gfx/luminance-hdr/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/luminance-hdr
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/luminance-hdr/ChangeLog,v 1.18 2012/06/30 16:48:49 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/luminance-hdr/ChangeLog,v 1.19 2012/07/09 09:51:30 radhermit Exp $
+
+*luminance-hdr-2.3.0 (09 Jul 2012)
+
+  09 Jul 2012; Tim Harder <radhermit@gentoo.org> +luminance-hdr-2.3.0.ebuild:
+  Version bump.
 
   30 Jun 2012; Tim Harder <radhermit@gentoo.org> -luminance-hdr-2.1.0.ebuild,
   -files/luminance-hdr-2.1.0-libraw.patch, -luminance-hdr-2.2.0.ebuild,
diff --git a/media-gfx/luminance-hdr/luminance-hdr-2.3.0.ebuild b/media-gfx/luminance-hdr/luminance-hdr-2.3.0.ebuild
new file mode 100644
index 000000000000..1aa5c8abce80
--- /dev/null
+++ b/media-gfx/luminance-hdr/luminance-hdr-2.3.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/luminance-hdr/luminance-hdr-2.3.0.ebuild,v 1.1 2012/07/09 09:51:30 radhermit Exp $
+
+EAPI="4"
+
+inherit cmake-utils toolchain-funcs eutils
+
+MY_P=${P/_/.}
+DESCRIPTION="Luminance HDR is a graphical user interface that provides a workflow for HDR imaging."
+HOMEPAGE="http://qtpfsgui.sourceforge.net"
+SRC_URI="mirror://sourceforge/qtpfsgui/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+LANGS=" cs de es fi fr hi hu id it pl ro ru sk tr zh"
+IUSE="${LANGS// / linguas_} openmp"
+
+DEPEND="
+	>=media-gfx/exiv2-0.14
+	media-libs/lcms:2
+	media-libs/libpng
+	>=media-libs/libraw-0.13.4
+	>=media-libs/openexr-1.2.2-r2
+	>=media-libs/tiff-3.8.2-r2
+	sci-libs/fftw:3.0
+	sci-libs/gsl
+	virtual/jpeg
+	x11-libs/qt-core:4
+	x11-libs/qt-gui:4
+	x11-libs/qt-sql:4
+	x11-libs/qt-webkit:4"
+RDEPEND="${DEPEND}"
+
+DOCS=( AUTHORS BUGS Changelog README TODO )
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	if use openmp ; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+}
+
+src_prepare() {
+	# Don't try to define the git version of the release
+	epatch "${FILESDIR}"/${PN}-2.3.0_beta1-no-git.patch
+
+	# Don't install extra docs and fix install dir
+	epatch "${FILESDIR}"/${PN}-2.2.1-docs.patch
+
+	# Fix openmp automagic support
+	epatch "${FILESDIR}"/${PN}-2.2.1-openmp-automagic.patch
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_use openmp OPENMP)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	for lang in ${LANGS} ; do
+		if ! use linguas_${lang} ; then
+			rm -f "${D}"/usr/share/${PN}/i18n/{lang,qt}_${lang}.qm || die
+		fi
+	done
+}