Enable multilib support, bug #493176.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

3 files changed, 204 insertions, 1 deletions

diff --git a/media-libs/gstreamer/ChangeLog b/media-libs/gstreamer/ChangeLog
index c2576db897d1..7b369b20e801 100644
--- a/media-libs/gstreamer/ChangeLog
+++ b/media-libs/gstreamer/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/gstreamer
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.367 2014/05/31 14:05:50 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.368 2014/06/10 18:32:44 mgorny Exp $
+
+*gstreamer-1.2.4-r1 (10 Jun 2014)
+*gstreamer-0.10.36-r1 (10 Jun 2014)
+
+  10 Jun 2014; Michał Górny <mgorny@gentoo.org> +gstreamer-0.10.36-r1.ebuild,
+  +gstreamer-1.2.4-r1.ebuild:
+  Enable multilib support, bug #493176.
 
 *gstreamer-1.2.4 (31 May 2014)
 
diff --git a/media-libs/gstreamer/gstreamer-0.10.36-r1.ebuild b/media-libs/gstreamer/gstreamer-0.10.36-r1.ebuild
new file mode 100644
index 000000000000..e9b3fbd91a12
--- /dev/null
+++ b/media-libs/gstreamer/gstreamer-0.10.36-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/gstreamer-0.10.36-r1.ebuild,v 1.1 2014/06/10 18:32:44 mgorny Exp $
+
+EAPI=5
+
+inherit eutils multilib multilib-minimal pax-utils
+
+DESCRIPTION="Streaming media framework"
+HOMEPAGE="http://gstreamer.freedesktop.org/"
+SRC_URI="http://${PN}.freedesktop.org/src/${PN}/${P}.tar.xz"
+
+LICENSE="LGPL-2+"
+SLOT="0.10"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="+introspection nls +orc test"
+
+RDEPEND=">=dev-libs/glib-2.24:2[${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.4.9[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-0.6.8 )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	>=dev-util/gtk-doc-am-1.3
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+	nls? ( sys-devel/gettext )"
+# gtk-doc-am to install API docs
+RDEPEND="${RDEPEND}
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-medialibs-20140508-r5
+		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)]
+	)
+	!<media-libs/gst-plugins-base-0.10.26"
+	# ^^ queue2 move, mustn't have both libgstcoreleements.so and libgstqueue2.so at runtime providing the element at once
+
+src_prepare() {
+	# Disable silly test that's not guaranteed to pass on an arbitrary machine
+	epatch "${FILESDIR}/${PN}-0.10.36-disable-test_fail_abstract_new.patch"
+
+	# Fix compilation with >=sys-devel/bison-3.0 (#478676)
+	epatch "${FILESDIR}/${PN}-make-grammar.y-work-with-bison-3.patch"
+
+	# Disable windows-portability tests that are relevant only on x86 and amd64
+	# and can fail on other arches (bug #455038)
+	if [[ ${ABI} != x86 && ${ABI} != amd64 ]]; then
+		sed -e 's#check:\(.*\)$(CHECK_EXPORTS)#check:\1#' -i Makefile.{am,in} || die
+	fi
+}
+
+src_configure() {
+	if [[ ${CHOST} == *-interix* ]] ; then
+		export ac_cv_lib_dl_dladdr=no
+		export ac_cv_func_poll=no
+	fi
+	if [[ ${CHOST} == powerpc-apple-darwin* ]] ; then
+		# GCC groks this, but then refers to an implementation (___multi3,
+		# ___udivti3) that don't exist (at least I can't find it), so force
+		# this one to be off, such that we use 2x64bit emulation code.
+		export gst_cv_uint128_t=no
+	fi
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	# Set 'libexecdir' to ABI-specific location for the library spawns
+	# helpers from there.
+	# Disable static archives, dependency tracking and examples
+	# to speed up build time
+	# Disable debug, as it only affects -g passing (debugging symbols), this must done through make.conf in gentoo
+	ECONF_SOURCE=${S} \
+	econf \
+		--libexecdir=/usr/$(get_libdir) \
+		--disable-static \
+		$(use_enable nls) \
+		--disable-valgrind \
+		--disable-examples \
+		--disable-debug \
+		--enable-check \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable test tests) \
+		--with-package-name="GStreamer ebuild for Gentoo" \
+		--with-package-origin="http://packages.gentoo.org/package/media-libs/gstreamer"
+
+	if multilib_is_native_abi; then
+		local x
+		for x in gst libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS ChangeLog NEWS MAINTAINERS README RELEASE"
+	einstalldocs
+
+	# Remove unversioned binaries to allow SLOT installations in future
+	cd "${ED%/}"/usr/bin || die
+	local gst_bins
+	for gst_bins in *-${SLOT} ; do
+		[[ -e ${gst_bins} ]] || continue
+		rm ${gst_bins/-${SLOT}/}
+		elog "Removed ${gst_bins/-${SLOT}/}"
+	done
+
+	# Punt useless .la files
+	prune_libtool_files --modules
+
+	# Needed for orc-using gst plugins on hardened/PaX systems, bug #421579
+	use orc && pax-mark -m "${ED}usr/bin/gst-launch-${SLOT}" \
+		"${ED}usr/libexec/gstreamer-${SLOT}/gst-plugin-scanner"
+}
diff --git a/media-libs/gstreamer/gstreamer-1.2.4-r1.ebuild b/media-libs/gstreamer/gstreamer-1.2.4-r1.ebuild
new file mode 100644
index 000000000000..27f10af3a5cc
--- /dev/null
+++ b/media-libs/gstreamer/gstreamer-1.2.4-r1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/gstreamer-1.2.4-r1.ebuild,v 1.1 2014/06/10 18:32:44 mgorny Exp $
+
+EAPI="5"
+
+inherit eutils multilib multilib-minimal pax-utils
+
+DESCRIPTION="Streaming media framework"
+HOMEPAGE="http://gstreamer.freedesktop.org/"
+SRC_URI="http://${PN}.freedesktop.org/src/${PN}/${P}.tar.xz"
+
+LICENSE="LGPL-2+"
+SLOT="1.0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="+introspection nls +orc test"
+
+RDEPEND="
+	>=dev-libs/glib-2.32:2[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1 )
+"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	>=dev-util/gtk-doc-am-1.12
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+	nls? ( sys-devel/gettext )
+"
+# gtk-doc-am to install API docs
+
+src_configure() {
+	if [[ ${CHOST} == *-interix* ]] ; then
+		export ac_cv_lib_dl_dladdr=no
+		export ac_cv_func_poll=no
+	fi
+	if [[ ${CHOST} == powerpc-apple-darwin* ]] ; then
+		# GCC groks this, but then refers to an implementation (___multi3,
+		# ___udivti3) that don't exist (at least I can't find it), so force
+		# this one to be off, such that we use 2x64bit emulation code.
+		export gst_cv_uint128_t=no
+	fi
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	# Set 'libexecdir' to ABI-specific location for the library spawns
+	# helpers from there.
+	# Disable static archives, dependency tracking and examples
+	# to speed up build time
+	# Disable debug, as it only affects -g passing (debugging symbols), this must done through make.conf in gentoo
+	ECONF_SOURCE=${S} \
+	econf \
+		--libexecdir=/usr/$(get_libdir) \
+		--disable-debug \
+		--disable-examples \
+		--disable-static \
+		--disable-valgrind \
+		--enable-check \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable nls) \
+		$(use_enable test tests) \
+		--with-package-name="GStreamer ebuild for Gentoo" \
+		--with-package-origin="http://packages.gentoo.org/package/media-libs/gstreamer"
+
+	if multilib_is_native_abi; then
+		local x
+		for x in gst libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS ChangeLog NEWS MAINTAINERS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+
+	# Needed for orc-using gst plugins on hardened/PaX systems, bug #421579
+	use orc && pax-mark -m "${ED}usr/bin/gst-launch-${SLOT}" \
+		"${ED}usr/libexec/gstreamer-${SLOT}/gst-plugin-scanner"
+}