Version bump. Remove all libtool files since libltdl is not used for loading the plugins and USE="static-libs" wrt #381769 by Agostino Sarubbo. Solving issues with recent GTK+ API wrt #351854 by Ingo Krabbe.

(Portage version: 2.2.0_alpha96/cvs/Linux x86_64)

2 files changed, 110 insertions, 2 deletions

diff --git a/media-libs/libquicktime/ChangeLog b/media-libs/libquicktime/ChangeLog
index 385bdc9e69d2..ce886f879f9d 100644
--- a/media-libs/libquicktime/ChangeLog
+++ b/media-libs/libquicktime/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for media-libs/libquicktime
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libquicktime/ChangeLog,v 1.178 2011/12/29 21:49:28 halcy0n Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libquicktime/ChangeLog,v 1.179 2012/03/30 13:03:49 ssuominen Exp $
+
+*libquicktime-1.2.4 (30 Mar 2012)
+
+  30 Mar 2012; Samuli Suominen <ssuominen@gentoo.org>
+  +libquicktime-1.2.4.ebuild:
+  Version bump. Remove all libtool files since libltdl is not used for loading
+  the plugins and USE="static-libs" wrt #381769 by Agostino Sarubbo. Solving
+  issues with recent GTK+ API wrt #351854 by Ingo Krabbe.
 
   29 Dec 2011; Mark Loeser <halcy0n@gentoo.org> libquicktime-1.2.3.ebuild:
   Stable for ppc/ppc64; bug #380169
diff --git a/media-libs/libquicktime/libquicktime-1.2.4.ebuild b/media-libs/libquicktime/libquicktime-1.2.4.ebuild
new file mode 100644
index 000000000000..3c74b6b5d5b2
--- /dev/null
+++ b/media-libs/libquicktime/libquicktime-1.2.4.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libquicktime/libquicktime-1.2.4.ebuild,v 1.1 2012/03/30 13:03:49 ssuominen Exp $
+
+EAPI=4
+inherit libtool
+
+DESCRIPTION="An enchanced version of the quicktime4linux library"
+HOMEPAGE="http://libquicktime.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="aac alsa doc dv encode ffmpeg gtk jpeg lame mmx opengl png schroedinger static-libs vorbis X x264"
+
+RDEPEND="virtual/libintl
+	aac? (
+		media-libs/faad2
+		encode? ( media-libs/faac )
+		)
+	alsa? ( >=media-libs/alsa-lib-1.0.20 )
+	dv? ( media-libs/libdv )
+	ffmpeg? ( virtual/ffmpeg )
+	gtk? ( x11-libs/gtk+:2 )
+	jpeg? ( virtual/jpeg )
+	lame? ( media-sound/lame )
+	opengl? ( virtual/opengl )
+	png? ( media-libs/libpng:0 )
+	schroedinger? ( >=media-libs/schroedinger-1.0.10 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+		)
+	X? (
+		x11-libs/libX11
+		x11-libs/libXaw
+		x11-libs/libXext
+		x11-libs/libXt
+		x11-libs/libXv
+		)
+	x264? ( media-libs/x264 )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	sys-devel/gettext
+	doc? ( app-doc/doxygen )
+	X? ( x11-proto/videoproto )"
+
+REQUIRED_USE="opengl? ( X )"
+
+DOCS="ChangeLog README TODO"
+
+src_prepare() {
+	elibtoolize # Required for .so versioning on g/fbsd
+}
+
+src_configure() {
+	econf \
+		--enable-gpl \
+		$(use_enable static-libs static) \
+		$(use_enable mmx asm) \
+		$(use_with doc doxygen) \
+		$(use vorbis || echo --without-vorbis) \
+		$(use_with lame) \
+		$(use_with X x) \
+		$(use_with opengl) \
+		$(use_with alsa) \
+		$(use_with gtk) \
+		$(use_with dv libdv) \
+		$(use_with jpeg libjpeg) \
+		$(use_with ffmpeg) \
+		$(use_with png libpng) \
+		$(use_with schroedinger) \
+		$(use_with aac faac) \
+		$(use encode || echo --without-faac) \
+		$(use_with aac faad2) \
+		$(use_with x264) \
+		--without-cpuflags
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -exec rm -f {} +
+
+	# Compatibility with software that uses quicktime prefix, but
+	# don't do that when building for Darwin/MacOS
+	[[ ${CHOST} != *-darwin* ]] && dosym /usr/include/lqt /usr/include/quicktime
+}
+
+pkg_preinst() {
+	if [[ -d /usr/include/quicktime && ! -L /usr/include/quicktime ]]; then
+		elog "For compatibility with other quicktime libraries, ${PN} was"
+		elog "going to create a /usr/include/quicktime symlink, but for some"
+		elog "reason that is a directory on your system."
+
+		elog "Please check that is empty, and remove it, or submit a bug"
+		elog "telling us which package owns the directory."
+		die "/usr/include/quicktime is a directory."
+	fi
+}