New upstream version (1.0.2).

(Portage version: 2.0.51.22-r2)

4 files changed, 255 insertions, 18 deletions

diff --git a/media-libs/xine-lib/ChangeLog b/media-libs/xine-lib/ChangeLog
index 8f8f3f49fb32..21cb95e18621 100644
--- a/media-libs/xine-lib/ChangeLog
+++ b/media-libs/xine-lib/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/xine-lib
 # Copyright 1999-2005 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/xine-lib/ChangeLog,v 1.231 2005/07/16 20:22:51 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/xine-lib/ChangeLog,v 1.232 2005/07/26 21:26:25 flameeyes Exp $
+
+*xine-lib-1.0.2 (26 Jul 2005)
+
+  26 Jul 2005; Diego Pettenò <flameeyes@gentoo.org> +xine-lib-1.0.2.ebuild:
+  New upstream version (1.0.2).
 
   16 Jul 2005; Joseph Jezak <josejx@gentoo.org> xine-lib-1.0.1-r3.ebuild:
   Marked ppc stable for bug #98805.
diff --git a/media-libs/xine-lib/Manifest b/media-libs/xine-lib/Manifest
index 499bde8904c0..f9e58c03a2be 100644
--- a/media-libs/xine-lib/Manifest
+++ b/media-libs/xine-lib/Manifest
@@ -1,28 +1,20 @@
------BEGIN PGP SIGNED MESSAGE-----
-Hash: SHA1
-
-MD5 26fcc8c7c4566812f911baef742cf191 xine-lib-1.0-r3.ebuild 7079
 MD5 85c8ecfc2f7acb495ab164a3e43d5d66 ChangeLog 9839
-MD5 05ac5f3e87594fa2a81a1a810983c9cf xine-lib-1_rc8-r1.ebuild 5240
-MD5 13d43d2a540653eeb091a62461004bff xine-lib-1.0.1-r1.ebuild 7276
 MD5 5529b17488d439ea93b380bacdb0a7a7 metadata.xml 239
+MD5 eeae60c214ca25ce0c9e4dbd37044004 xine-lib-1.0-r2.ebuild 7087
+MD5 26fcc8c7c4566812f911baef742cf191 xine-lib-1.0-r3.ebuild 7079
+MD5 13d43d2a540653eeb091a62461004bff xine-lib-1.0.1-r1.ebuild 7276
+MD5 6b5209f80c08295cc46aa8953f88945f xine-lib-1_rc6-r2.ebuild 5200
+MD5 05ac5f3e87594fa2a81a1a810983c9cf xine-lib-1_rc8-r1.ebuild 5240
 MD5 d369fe96b3307250f3d22c3b13785e35 xine-lib-1.0-r4.ebuild 7186
 MD5 c89993f4f2567fbcf104e0b7761fb06f xine-lib-1.0.1-r2.ebuild 7423
 MD5 301bdcd736db151e25aafb70a97d5290 xine-lib-1.0.1-r3.ebuild 7439
-MD5 eeae60c214ca25ce0c9e4dbd37044004 xine-lib-1.0-r2.ebuild 7087
-MD5 6b5209f80c08295cc46aa8953f88945f xine-lib-1_rc6-r2.ebuild 5200
+MD5 238022c4d7abb64eba6f330ff57464d4 xine-lib-1.0.2.ebuild 7439
 MD5 44995c2f2dc4faa99ed2795e5e401719 files/digest-xine-lib-1.0-r2 134
 MD5 44995c2f2dc4faa99ed2795e5e401719 files/digest-xine-lib-1.0-r3 134
 MD5 44995c2f2dc4faa99ed2795e5e401719 files/digest-xine-lib-1.0-r4 134
+MD5 bc7fc1f6b4a7e138d92e29e0231afd6f files/digest-xine-lib-1.0.1-r1 136
 MD5 57a9f924e9a78a68610f12a3f59435b3 files/digest-xine-lib-1_rc6-r2 139
 MD5 51e97df2f6ae538ab33a802eafb10457 files/digest-xine-lib-1_rc8-r1 138
-MD5 bc7fc1f6b4a7e138d92e29e0231afd6f files/digest-xine-lib-1.0.1-r1 136
-MD5 9678227c043f04d5e8561cb6ba80d3e6 files/digest-xine-lib-1.0.1-r3 137
 MD5 5f84d7a1d762461967b5a9d45da70e9b files/digest-xine-lib-1.0.1-r2 137
------BEGIN PGP SIGNATURE-----
-Version: GnuPG v1.4.1 (GNU/Linux)
-
-iD8DBQFC2WyqcsIHjyDViGQRAjLfAJwPcrdFmbmsQa/AfrwCR5OnKHJKGwCfYujs
-mP6bUXTiXrddScHB74eVrEE=
-=5ons
------END PGP SIGNATURE-----
+MD5 9678227c043f04d5e8561cb6ba80d3e6 files/digest-xine-lib-1.0.1-r3 137
+MD5 b5cff6ac57a1f66ac90f95608a138717 files/digest-xine-lib-1.0.2 137
diff --git a/media-libs/xine-lib/files/digest-xine-lib-1.0.2 b/media-libs/xine-lib/files/digest-xine-lib-1.0.2
new file mode 100644
index 000000000000..41d3c1094116
--- /dev/null
+++ b/media-libs/xine-lib/files/digest-xine-lib-1.0.2
@@ -0,0 +1,2 @@
+MD5 f193aa14017ef104b797ccde9d82edc9 xine-lib-1.0.2.tar.gz 7774805
+MD5 d5fd94c89eb0630e78dfecfdb6db4573 xine-lib-patches-6.tar.bz2 15344
diff --git a/media-libs/xine-lib/xine-lib-1.0.2.ebuild b/media-libs/xine-lib/xine-lib-1.0.2.ebuild
new file mode 100644
index 000000000000..1bae5a36cbf1
--- /dev/null
+++ b/media-libs/xine-lib/xine-lib-1.0.2.ebuild
@@ -0,0 +1,238 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/xine-lib/xine-lib-1.0.2.ebuild,v 1.1 2005/07/26 21:26:25 flameeyes Exp $
+
+inherit eutils flag-o-matic toolchain-funcs libtool
+
+# This should normally be empty string, unless a release has a suffix.
+MY_PKG_SUFFIX=""
+MY_P=${PN}-${PV/_/-}${MY_PKG_SUFFIX}
+
+PATCHLEVEL="6"
+
+DESCRIPTION="Core libraries for Xine movie player"
+HOMEPAGE="http://xine.sourceforge.net/"
+SRC_URI="mirror://sourceforge/xine/${MY_P}.tar.gz
+	http://digilander.libero.it/dgp85/gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="1"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="aalib libcaca arts cle266 esd win32codecs nls dvd X directfb vorbis alsa
+gnome sdl speex theora ipv6 altivec opengl aac fbcon ffmpeg xv xvmc nvidia i8x0
+samba dxr3 vidix png mng flac oss v4l xinerama vcd a52 mad"
+RESTRICT="nostrip"
+
+RDEPEND="vorbis? ( media-libs/libvorbis )
+	X? ( virtual/x11 )
+	win32codecs? ( >=media-libs/win32codecs-0.50 )
+	esd? ( media-sound/esound )
+	dvd? ( >=media-libs/libdvdcss-1.2.7 )
+	arts? ( kde-base/arts )
+	alsa? ( media-libs/alsa-lib )
+	aalib? ( media-libs/aalib )
+	directfb? ( >=dev-libs/DirectFB-0.9.9 )
+	gnome? ( >=gnome-base/gnome-vfs-2.0 )
+	flac? ( >=media-libs/flac-1.0.4 )
+	sdl? ( >=media-libs/libsdl-1.1.5 )
+	dxr3? ( >=media-libs/libfame-0.9.0 )
+	theora? ( media-libs/libtheora )
+	speex? ( media-libs/speex )
+	libcaca? ( media-libs/libcaca )
+	samba? ( net-fs/samba )
+	png? ( media-libs/libpng )
+	mng? ( media-libs/libmng )
+	vcd? ( media-video/vcdimager )
+	ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20050226-r1 )
+	a52? ( >=media-libs/a52dec-0.7.4-r5 )
+	mad? ( media-libs/libmad )
+	!=media-libs/xine-lib-0.9.13*"
+
+DEPEND="${RDEPEND}
+	v4l? ( sys-kernel/linux-headers )
+	>=sys-devel/automake-1.7
+	>=sys-devel/autoconf-2.59
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+S=${WORKDIR}/${MY_P}
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+
+	# That patch is highly experimental!
+	EPATCH_EXCLUDE="07_all_vidix64.patch 03_all_kernel26.patch"
+	EPATCH_SUFFIX="patch" epatch ${WORKDIR}/${PV}/
+
+	elibtoolize
+
+	# Makefile.ams and configure.ac get patched, so we need to rerun
+	# autotools
+	export WANT_AUTOCONF=2.5
+	export WANT_AUTOMAKE=1.7
+	aclocal -I m4 || die "aclocal failed"
+	autoheader || die "autoheader failed"
+	automake -afc || die "automake failed"
+	autoconf || die "autoconf failed"
+
+	libtoolize --copy --force || die "libtoolize failed"
+}
+
+src_compile() {
+	#filter dangerous compile CFLAGS
+	strip-flags
+
+	#prevent quicktime crashing
+	append-flags -frename-registers
+
+	use x86 && has_pic && append-flags -UHAVE_MMX
+
+	if [ "$(gcc-major-version)" -eq "3" -a "$(gcc-minor-version)" -ge "4" ] || \
+	[ "$(gcc-major-version)" -ge "4" ]; then
+		# bugs 49509 and 55202
+		append-flags -fno-web -funit-at-a-time
+		filter-flags -fno-unit-at-a-time #55202
+	fi
+
+	is-flag -O? || append-flags -O1 #31243
+
+	# fix build errors with sse2 #49482
+	if use x86 && [ $(gcc-major-version) -ge 3 ]; then
+		append-flags -mno-sse2 $(test_flag -mno-sse3)
+		filter-mfpmath sse
+	fi
+
+	local myconf
+
+	# the win32 codec path should ignore $(get_libdir) and always use lib
+	use win32codecs \
+		&& myconf="${myconf} --with-w32-path=/usr/$(get_libdir)/win32" \
+		|| myconf="${myconf} --disable-asf"
+
+	# enable/disable appropiate optimizations on sparc
+	[ "${PROFILE_ARCH}" == "sparc64" ] \
+		&& myconf="${myconf} --enable-vis"
+	[ "${PROFILE_ARCH}" == "sparc" ] \
+		&& myconf="${myconf} --disable-vis"
+
+	# Fix compilation-errors on PowerPC #45393 & #55460 & #68251
+	if use ppc || use ppc64 ; then
+		append-flags -U__ALTIVEC__
+		myconf="${myconf} $(use_enable altivec)"
+	fi
+
+	# The default CFLAGS (-O) is the only thing working on hppa.
+	if use hppa; then
+		unset CFLAGS
+	else
+		append-flags -ffunction-sections
+	fi
+
+	if use xvmc; then
+		count="0"
+		use nvidia && count="`expr ${count} + 1`"
+		use i8x0 && count="`expr ${count} + 1`"
+		use cle266 && count="`expr ${count} + 1`"
+		if [ "${count}" -gt "1" ]; then
+			eerror "Invalid combination of USE flags"
+			eerror "When building support for xvmc, you may only"
+			eerror "include support for one video card:"
+			eerror "   nvidia, i8x0, cle266"
+			eerror ""
+			die "emerge again with different USE flags"
+		fi
+
+		use nvidia && xvmclib="XvMCNVIDIA"
+		use i8x0 && xvmclib="I810XvmC"
+		use cle266 && xvmclib="viaXvMC"
+
+		if [ -n "${xvmclib}" ]; then
+			if [ -f "${ROOT}/usr/$(get_libdir)/libXvMC.so" -o -f "${ROOT}/usr/$(get_libdir)/libXvMC.a" ]; then
+				myconf="${myconf} --with-xvmc-path=${ROOT}/usr/$(get_libdir) --with-xxmc-path=${ROOT}/usr/$(get_libdir) --with-xvmc-lib=${xvmclib} --with-xxmc-lib=${xvmclib}"
+			elif [ -f "${ROOT}/usr/X11R6/$(get_libdir)/libXvMC.so" -o -f "${ROOT}/usr/X11R6/$(get_libdir)/libXvMC.a" ]; then
+				myconf="${myconf} --with-xvmc-path=${ROOT}/usr/X11R6/$(get_libdir) --with-xxmc-path=${ROOT}/usr/X11R6/$(get_libdir) --with-xvmc-lib=${xvmclib} --with-xxmc-lib=${xvmclib}"
+			else
+				ewarn "Couldn't find libXvMC.  Disabling xvmc support."
+			fi
+		fi
+	fi
+
+	if use xv; then
+		if [ -f "${ROOT}/usr/$(get_libdir)/libXv.so" ]; then
+			myconf="${myconf} --with-xv-path=${ROOT}/usr/$(get_libdir)"
+		elif [ -f "${ROOT}/usr/$(get_libdir)/libXv.a" ]; then
+			myconf="${myconf} --enable-static-xv --with-xv-path=${ROOT}/usr/$(get_libdir)"
+		elif [ -f "${ROOT}/usr/X11R6/$(get_libdir)/libXv.so" ]; then
+			myconf="${myconf} --with-xv-path=${ROOT}/usr/X11R6/$(get_libdir)"
+		elif [ -f "${ROOT}/usr/X11R6/$(get_libdir)/libXv.a" ]; then
+			myconf="${myconf} --enable-static-xv --with-xv-path=${ROOT}/usr/X11R6/$(get_libdir)"
+		else
+			eerror "Couldn't find your libXv.  Did you set USE=\"xv\" when you emerged xorg-x11?"
+			die "Couldn't find libXv."
+		fi
+	fi
+
+	use ffmpeg && myconf="${myconf} --with-external-ffmpeg=/usr"
+
+	econf \
+		$(use_enable nls) \
+		$(use_enable ipv6) \
+		$(use_enable samba) \
+		\
+		$(use_enable mng) \
+		$(use_enable png) \
+		\
+		$(use_enable aac faad) \
+		$(use_enable flac) \
+		$(use_with vorbis ogg) $(use_with vorbis) \
+		$(use_enable speex) \
+		\
+		$(use_with X x) \
+		$(use_enable xinerama) \
+		$(use_enable vidix) \
+		$(use_enable dxr3) \
+		$(use_enable directfb) \
+		$(use_enable fbcon fb) \
+		$(use_enable opengl) \
+		$(use_enable aalib) \
+		$(use_enable libcaca caca) \
+		$(use_enable sdl) \
+		\
+		$(use_enable oss) \
+		$(use_enable alsa) \
+		$(use_enable arts) \
+		$(use_enable esd) \
+		$(use_enable vcd) --without-internal-vcdlibs \
+		$(use_with a52 external-a52dec) \
+		$(use_with mad external-libmad) \
+		--disable-polypaudio \
+		${myconf} \
+		--disable-dependency-tracking || die "Configure failed"
+
+		#$(use_with dvdnav external-dvdnav) \
+		#$(use_enable macos macosx-video) $(use_enable macos coreaudio) \
+		# This will be added when polypaudio will be added to portage.
+		# $(use_enable polypaudio)
+
+	emake -j1 || die "Parallel make failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die "Install failed"
+
+	# Xine's makefiles install some file incorrectly. (Gentoo bug #8583, #16112).
+	dodir /usr/share/xine/libxine1/fonts
+	mv ${D}/usr/share/*.xinefont.gz ${D}/usr/share/xine/libxine1/fonts/
+
+	dodoc AUTHORS ChangeLog README TODO dataflow.dia doc/README* doc/faq/faq.txt
+	dohtml doc/faq/faq.html doc/hackersguide/*.html doc/hackersguide/*.png
+
+	rm -rf ${D}/usr/share/doc/xine
+}
+
+pkg_postinst() {
+	einfo
+	einfo "Make sure to remove your ~/.xine if upgrading from a pre-1.0 version."
+	einfo
+}