Add a live SVN version of Amarok. Although not supported and a bad idea in general, it would save me from supporting people with old and broken unofficial amarok-svn ebuilds that usually waste my time.

(Portage version: 2.1.2_rc4-r1)

3 files changed, 88 insertions, 1 deletions

diff --git a/media-sound/amarok/ChangeLog b/media-sound/amarok/ChangeLog
index f5b92f6da705..71c14620a521 100644
--- a/media-sound/amarok/ChangeLog
+++ b/media-sound/amarok/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/amarok
 # Copyright 2000-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.191 2006/12/26 19:35:00 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.192 2006/12/28 20:56:46 flameeyes Exp $
+
+*amarok-9999 (28 Dec 2006)
+
+  28 Dec 2006; Diego Pettenò <flameeyes@gentoo.org> +amarok-9999.ebuild:
+  Add a live SVN version of Amarok. Although not supported and a bad idea in
+  general, it would save me from supporting people with old and broken
+  unofficial amarok-svn ebuilds that usually waste my time.
 
   26 Dec 2006; Diego Pettenò <flameeyes@gentoo.org>
   files/digest-amarok-1.4.4-r3, Manifest:
diff --git a/media-sound/amarok/amarok-9999.ebuild b/media-sound/amarok/amarok-9999.ebuild
new file mode 100644
index 000000000000..ae204d630618
--- /dev/null
+++ b/media-sound/amarok/amarok-9999.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-9999.ebuild,v 1.1 2006/12/28 20:56:46 flameeyes Exp $
+
+inherit kde subversion
+
+ESVN_REPO_URI="svn://anonsvn.kde.org/home/kde/trunk/extragear/multimedia/amarok"
+ESVN_STORE_DIR="${PORTAGE_ACTUAL_DISTDIR-${DISTDIR}}/svn-src/"
+
+PKG_SUFFIX=""
+
+DESCRIPTION="Advanced audio player based on KDE framework."
+HOMEPAGE="http://amarok.kde.org/"
+
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="-*"
+IUSE="aac kde mysql noamazon opengl postgres
+visualization ipod ifp real njb mtp musicbrainz"
+# kde: enables compilation of the konqueror sidebar plugin
+
+RDEPEND="kde? ( || ( kde-base/konqueror kde-base/kdebase ) )
+	>=media-libs/xine-lib-1.1.2_pre20060328-r8
+	>=media-libs/taglib-1.4
+	mysql? ( >=virtual/mysql-4.0 )
+	postgres? ( dev-db/libpq )
+	opengl? ( virtual/opengl )
+	visualization? ( media-libs/libsdl
+					 =media-plugins/libvisual-plugins-0.4* )
+	ipod? ( >=media-libs/libgpod-0.3 )
+	aac? ( media-libs/libmp4v2 )
+	ifp? ( media-libs/libifp )
+	real? ( media-video/realplayer )
+	njb? ( >=media-libs/libnjb-2.2.4 )
+	mtp? ( media-libs/libmtp )
+	musicbrainz? ( media-libs/tunepimp )
+	=dev-lang/ruby-1.8*"
+
+DEPEND="${RDEPEND}"
+
+need-kde 3.3
+
+S="${WORKDIR}/${PN}"
+
+src_unpack() {
+	ESVN_UPDATE_CMD="svn update -N" \
+	ESVN_FETCH_CMD="svn checkout -N" \
+	ESVN_REPO_URI=`dirname ${ESVN_REPO_URI}` \
+		subversion_src_unpack
+
+	S="${WORKDIR}/${PN}/admin" \
+	ESVN_REPO_URI="svn://anonsvn.kde.org/home/kde/branches/KDE/3.5/kde-common/admin" \
+		subversion_src_unpack
+
+	ESVN_UPDATE_CMD="svn up" \
+	ESVN_FETCH_CMD="svn checkout" \
+	S="${WORKDIR}/${PN}/amarok" \
+		subversion_src_unpack
+}
+
+src_compile() {
+	# Extra, unsupported engines are forcefully disabled.
+	local myconf="$(use_enable mysql) $(use_enable postgres postgresql)
+				  $(use_with opengl) --without-xmms
+				  $(use_with visualization libvisual)
+				  $(use_enable !noamazon amazon)
+				  $(use_with ipod libgpod)
+				  $(use_with aac mp4v2)
+				  $(use_with ifp)
+				  $(use_with real helix)
+				  $(use_with njb libnjb)
+				  $(use_with mtp libmtp)
+				  $(use_with musicbrainz)
+				  --with-xine
+				  --without-mas
+				  --without-nmm"
+
+	kde_src_compile
+}
diff --git a/media-sound/amarok/files/digest-amarok-9999 b/media-sound/amarok/files/digest-amarok-9999
new file mode 100644
index 000000000000..e69de29bb2d1
--- /dev/null
+++ b/media-sound/amarok/files/digest-amarok-9999