Version bump wrt #357699 by Rafael.

(Portage version: 2.2.0_alpha29/cvs/Linux x86_64)

2 files changed, 79 insertions, 1 deletions

diff --git a/media-sound/exaile/ChangeLog b/media-sound/exaile/ChangeLog
index 623278d787c8..70604a69c061 100644
--- a/media-sound/exaile/ChangeLog
+++ b/media-sound/exaile/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/exaile
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/exaile/ChangeLog,v 1.75 2011/01/14 21:26:28 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/exaile/ChangeLog,v 1.76 2011/03/28 13:23:18 ssuominen Exp $
+
+*exaile-0.3.2.1 (28 Mar 2011)
+
+  28 Mar 2011; Samuli Suominen <ssuominen@gentoo.org> +exaile-0.3.2.1.ebuild:
+  Version bump wrt #357699 by Rafael.
 
   14 Jan 2011; Brent Baude <ranger@gentoo.org> exaile-0.3.2.0.ebuild:
   stable ppc, bug 343163
diff --git a/media-sound/exaile/exaile-0.3.2.1.ebuild b/media-sound/exaile/exaile-0.3.2.1.ebuild
new file mode 100644
index 000000000000..cd7c14105c72
--- /dev/null
+++ b/media-sound/exaile/exaile-0.3.2.1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/exaile/exaile-0.3.2.1.ebuild,v 1.1 2011/03/28 13:23:18 ssuominen Exp $
+
+EAPI=2
+
+PYTHON_DEPEND="2:2.6"
+PYTHON_USE_WITH="sqlite"
+
+inherit fdo-mime multilib python
+
+DESCRIPTION="a media player aiming to be similar to AmaroK, but for GTK+"
+HOMEPAGE="http://www.exaile.org/"
+SRC_URI="http://launchpad.net/${PN}/0.3.2/${PV}/+download/${P}.tar.gz"
+
+LICENSE="GPL-2 GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="cddb libnotify nls"
+
+RDEPEND="dev-python/dbus-python
+	>=media-libs/mutagen-1.10
+	>=dev-python/pygtk-2.17
+	>=dev-python/pygobject-2.18
+	dev-python/gst-python:0.10
+	media-libs/gst-plugins-good:0.10
+	media-plugins/gst-plugins-meta:0.10
+	libnotify? ( dev-python/notify-python )
+	cddb? ( dev-python/cddb-py )"
+DEPEND="nls? ( dev-util/intltool
+	sys-devel/gettext )"
+
+RESTRICT="test" #315589
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	sed -i \
+		-e "s:exec python:exec $(PYTHON):" \
+		exaile tools/generate-launcher || die
+}
+
+src_compile() {
+	if use nls; then
+		emake locale || die
+	fi
+}
+
+src_install() {
+	emake \
+		PREFIX=/usr \
+		LIBINSTALLDIR=/$(get_libdir) \
+		DESTDIR="${D}" \
+		install$(use nls || echo _no_locale) || die
+
+	dodoc FUTURE || die
+}
+
+pkg_postinst() {
+	python_need_rebuild
+	python_mod_optimize /usr/$(get_libdir)/${PN}
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}
+
+pkg_postrm() {
+	python_mod_cleanup /usr/$(get_libdir)/${PN}
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}