Add multilib support

(Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

2 files changed, 59 insertions, 1 deletions

diff --git a/media-sound/gsm/ChangeLog b/media-sound/gsm/ChangeLog
index 105912464ed0..4e420949d6d9 100644
--- a/media-sound/gsm/ChangeLog
+++ b/media-sound/gsm/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/gsm
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/gsm/ChangeLog,v 1.44 2013/03/03 09:00:01 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/gsm/ChangeLog,v 1.45 2013/05/08 10:53:42 aballier Exp $
+
+*gsm-1.0.13-r1 (08 May 2013)
+
+  08 May 2013; Alexis Ballier <aballier@gentoo.org> +gsm-1.0.13-r1.ebuild:
+  Add multilib support
 
   03 Mar 2013; Mike Frysinger <vapier@gentoo.org> gsm-1.0.13.ebuild:
   Add s390 love.
diff --git a/media-sound/gsm/gsm-1.0.13-r1.ebuild b/media-sound/gsm/gsm-1.0.13-r1.ebuild
new file mode 100644
index 000000000000..5793df28e159
--- /dev/null
+++ b/media-sound/gsm/gsm-1.0.13-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/gsm/gsm-1.0.13-r1.ebuild,v 1.1 2013/05/08 10:53:42 aballier Exp $
+
+EAPI=5
+inherit eutils flag-o-matic multilib multilib-minimal toolchain-funcs versionator
+
+DESCRIPTION="Lossy speech compression library and tool."
+HOMEPAGE="http://packages.qa.debian.org/libg/libgsm.html"
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+
+LICENSE="gsm"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE=""
+RDEPEND="abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20130224 )"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${PN}-"$(replace_version_separator 2 '-pl' )"
+
+DOCS=( ChangeLog MACHINES MANIFEST README )
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-shared.patch \
+		"${FILESDIR}"/${PN}-1.0.12-memcpy.patch \
+		"${FILESDIR}"/${PN}-1.0.12-64bit.patch
+	multilib_copy_sources
+}
+
+multilib_src_compile() {
+	# From upstream Makefile. Define this if your host multiplies
+	# floats faster than integers, e.g. on a SPARCstation.
+	use sparc && append-flags -DUSE_FLOAT_MUL -DFAST
+
+	emake -j1 CCFLAGS="${CFLAGS} -c -DNeedFunctionPrototypes=1" \
+		LD="$(tc-getCC)" AR="$(tc-getAR)" CC="$(tc-getCC)"
+}
+
+multilib_src_install() {
+	dodir /usr/bin /usr/$(get_libdir) /usr/include/gsm /usr/share/man/man{1,3}
+
+	emake -j1 INSTALL_ROOT="${D}"/usr \
+		LD="$(tc-getCC)" AR="$(tc-getAR)" CC="$(tc-getCC)" \
+		GSM_INSTALL_LIB="${D}"/usr/$(get_libdir) \
+		GSM_INSTALL_INC="${D}"/usr/include/gsm \
+		GSM_INSTALL_MAN="${D}"/usr/share/man/man3 \
+		TOAST_INSTALL_MAN="${D}"/usr/share/man/man1 \
+		install
+
+	dolib lib/libgsm.so*
+
+	dosym ../gsm/gsm.h /usr/include/libgsm/gsm.h
+}