Version bump.

(Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

2 files changed, 66 insertions, 1 deletions

diff --git a/media-sound/lame/ChangeLog b/media-sound/lame/ChangeLog
index eb54e54fb8f5..a4f25312f2d1 100644
--- a/media-sound/lame/ChangeLog
+++ b/media-sound/lame/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/lame
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/ChangeLog,v 1.144 2012/01/22 15:33:40 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/ChangeLog,v 1.145 2012/02/04 16:52:02 ssuominen Exp $
+
+*lame-3.99.4 (04 Feb 2012)
+
+  04 Feb 2012; Samuli Suominen <ssuominen@gentoo.org> +lame-3.99.4.ebuild:
+  Version bump.
 
   22 Jan 2012; Raúl Porcel <armin76@gentoo.org> lame-3.99.3.ebuild:
   alpha/ia64/sh/sparc stable wrt #398353
diff --git a/media-sound/lame/lame-3.99.4.ebuild b/media-sound/lame/lame-3.99.4.ebuild
new file mode 100644
index 000000000000..1f1668a3d694
--- /dev/null
+++ b/media-sound/lame/lame-3.99.4.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/lame-3.99.4.ebuild,v 1.1 2012/02/04 16:52:02 ssuominen Exp $
+
+EAPI=4
+inherit autotools eutils
+
+DESCRIPTION="LAME Ain't an MP3 Encoder"
+HOMEPAGE="http://lame.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="debug mmx mp3rtp sndfile static-libs"
+
+RDEPEND=">=sys-libs/ncurses-5.7-r7
+	sndfile? ( >=media-libs/libsndfile-1.0.2 )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	mmx? ( dev-lang/nasm )"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-3.96-ccc.patch \
+		"${FILESDIR}"/${PN}-3.98-gtk-path.patch
+
+	mkdir libmp3lame/i386/.libs || die #workaround parallel build with nasm
+
+	sed -i -e '/define sp/s/+/ + /g' libmp3lame/i386/nasm.h || die
+
+	use mmx || sed -i -e '/AC_PATH_PROG/s:nasm:dIsAbLe&:' configure.in #361879
+
+	AT_M4DIR=${S} eautoreconf
+	epunt_cxx #74498
+}
+
+src_configure() {
+	local myconf
+	use mmx && myconf+="--enable-nasm" #361879
+	use sndfile && myconf+=" --with-fileio=sndfile"
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable debug debug norm) \
+		--disable-mp3x \
+		$(use_enable mp3rtp) \
+		--enable-dynamic-frontends \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkghtmldir="${EPREFIX}/usr/share/doc/${PF}/html" install
+	dobin misc/mlame
+
+	dodoc API ChangeLog HACKING README STYLEGUIDE TODO USAGE
+	dohtml misc/lameGUI.html Dll/LameDLLInterface.htm
+
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}