Add 0.9.9-r55 without bluetooth support for quick stabilization. Bluetooth didn't really work with this version, and this is blocking bluez-4 stabilization -- bug 284661 . If you want bluetooth, you should use the -r54 version or keyword a newer version.

(Portage version: 2.2_rc40/cvs/Linux i686)

2 files changed, 173 insertions, 1 deletions

diff --git a/media-sound/pulseaudio/ChangeLog b/media-sound/pulseaudio/ChangeLog
index 66f2a0230df5..edf441bec245 100644
--- a/media-sound/pulseaudio/ChangeLog
+++ b/media-sound/pulseaudio/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for media-sound/pulseaudio
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.149 2009/09/10 19:17:17 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.150 2009/09/12 13:46:18 nirbheek Exp $
+
+*pulseaudio-0.9.9-r55 (12 Sep 2009)
+
+  12 Sep 2009; Nirbheek Chauhan <nirbheek@gentoo.org>
+  +pulseaudio-0.9.9-r55.ebuild:
+  Add 0.9.9-r55 without bluetooth support for quick stabilization. Bluetooth
+  didn't really work with this version, and this is blocking bluez-4
+  stabilization -- bug 284661 . If you want bluetooth, you should use the
+  -r54 version or keyword a newer version.
 
   10 Sep 2009; Diego E. Pettenò <flameeyes@gentoo.org>
   -pulseaudio-0.9.15-r51.ebuild:
diff --git a/media-sound/pulseaudio/pulseaudio-0.9.9-r55.ebuild b/media-sound/pulseaudio/pulseaudio-0.9.9-r55.ebuild
new file mode 100644
index 000000000000..ed7456902d36
--- /dev/null
+++ b/media-sound/pulseaudio/pulseaudio-0.9.9-r55.ebuild
@@ -0,0 +1,163 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.9-r55.ebuild,v 1.1 2009/09/12 13:46:18 nirbheek Exp $
+
+inherit eutils libtool autotools flag-o-matic
+
+DESCRIPTION="A networked sound server with an advanced plugin system"
+HOMEPAGE="http://www.pulseaudio.org"
+SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2 GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
+IUSE="alsa avahi caps jack lirc oss tcpd X hal dbus libsamplerate gnome policykit asyncns"
+
+# XXX: bluetooth support has been disabled because it doesn't work, and it
+# blocks bluez-4 stabilization -- bug 284661
+RDEPEND="X? ( x11-libs/libX11 )
+	caps? ( sys-libs/libcap )
+	>=media-libs/audiofile-0.2.6-r1
+	libsamplerate? ( >=media-libs/libsamplerate-0.1.1-r1 )
+	>=media-libs/libsndfile-1.0.10
+	>=dev-libs/liboil-0.3.6
+	alsa? ( >=media-libs/alsa-lib-1.0.10 )
+	>=dev-libs/glib-2.4.0
+	avahi? ( >=net-dns/avahi-0.6.12 )
+	>=dev-libs/liboil-0.3.0
+	jack? ( >=media-sound/jack-audio-connection-kit-0.100 )
+	tcpd? ( sys-apps/tcp-wrappers )
+	lirc? ( app-misc/lirc )
+	dbus? ( >=sys-apps/dbus-1.0.0 )
+	gnome? ( >=gnome-base/gconf-2.4.0 )
+	hal? (
+		>=sys-apps/hal-0.5.7
+		>=sys-apps/dbus-1.0.0
+	)
+	app-admin/eselect-esd
+	policykit? ( sys-auth/policykit )
+	asyncns? ( net-libs/libasyncns )
+	=sys-devel/libtool-1.5*" # it's a valid RDEPEND, libltdl.so is used
+DEPEND="${RDEPEND}
+	dev-libs/libatomic_ops
+	dev-util/pkgconfig"
+
+# alsa-utils dep is for the alsasound init.d script (see bug #155707)
+RDEPEND="${RDEPEND}
+	gnome-extra/gnome-audio
+	alsa? ( media-sound/alsa-utils )"
+
+pkg_setup() {
+	if use avahi && ! built_with_use net-dns/avahi dbus ; then
+		echo
+		eerror "In order to compile pulseaudio with avahi support, you need to have"
+		eerror "net-dns/avahi emerged with 'dbus' in your USE flag. Please add that"
+		eerror "flag, re-emerge avahi, and then emerge pulseaudio again."
+		die "net-dns/avahi is missing the D-Bus bindings."
+	fi
+
+	enewgroup audio 18 # Just make sure it exists
+	enewgroup realtime
+	enewgroup pulse-access
+	enewgroup pulse
+	enewuser pulse -1 -1 /var/run/pulse pulse,audio
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/${PN}-0.9.8-svn2074.patch"
+	epatch "${FILESDIR}/${PN}-0.9.8-polkit.patch"
+	epatch "${FILESDIR}/${PN}-0.9.8-bt-nohal.patch"
+	epatch "${FILESDIR}/${PN}-0.9.8-esoundpath.patch"
+	epatch "${FILESDIR}/${PN}-0.9.8-create-directory.patch"
+	epatch "${FILESDIR}/${P}-CVE-2009-1894.patch"
+
+	eautoreconf
+	elibtoolize
+}
+
+src_compile() {
+	# To properly fix CVE-2008-0008
+	append-flags -UNDEBUG
+
+	econf \
+		--enable-largefile \
+		--enable-glib2 \
+		--disable-solaris \
+		--disable-bluez \
+		$(use_enable asyncns) \
+		$(use_enable oss) \
+		$(use_enable alsa) \
+		$(use_enable lirc) \
+		$(use_enable tcpd tcpwrap) \
+		$(use_enable jack) \
+		$(use_enable lirc) \
+		$(use_enable avahi) \
+		$(use_enable hal) \
+		$(use_enable dbus) \
+		$(use_enable gnome gconf) \
+		$(use_enable libsamplerate samplerate) \
+		$(use_enable policykit polkit) \
+		$(use_with caps) \
+		$(use_with X x) \
+		--disable-ltdl-install \
+		--localstatedir=/var \
+		--with-realtime-group=realtime \
+		|| die "econf failed"
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install || die "make install failed"
+
+	newconfd "${FILESDIR}/pulseaudio.conf.d" pulseaudio
+
+	local neededservices
+	use alsa && neededservices="$neededservices alsasound"
+	use avahi && neededservices="$neededservices avahi-daemon"
+	use hal && neededservices="$neededservices hald"
+	if [[ -n ${neededservices} ]]; then
+		sed -e "s/@neededservices@/need $neededservices/" "${FILESDIR}/pulseaudio.init.d-2" > "${T}/pulseaudio"
+	else
+		sed -e "/@neededservices@/d" "${FILESDIR}/pulseaudio.init.d-2" > "${T}/pulseaudio"
+	fi
+	doinitd "${T}/pulseaudio"
+
+	use avahi && sed -i -e '/module-zeroconf-publish/s:^#::' "${D}/etc/pulse/default.pa"
+
+	dohtml -r doc
+	dodoc README
+
+	# Create the state directory
+	diropts -o pulse -g pulse -m0755
+	keepdir /var/run/pulse
+}
+
+pkg_postinst() {
+	elog "PulseAudio in Gentoo can use a system-wide pulseaudio daemon."
+	elog "This support is enabled by starting the pulseaudio init.d ."
+	elog "To be able to access that you need to be in the group pulse-access."
+	elog "For more information about system-wide support, please refer to"
+	elog "	 http://pulseaudio.org/wiki/SystemWideInstance"
+	if use gnome; then
+		elog
+		elog "By enabling gnome USE flag, you enabled gconf support. Please note"
+		elog "that you might need to remove the gnome USE flag or disable the"
+		elog "gconf module on /etc/pulse/default.pa to be able to use PulseAudio"
+		elog "with a system-wide instance."
+	fi
+	elog
+	elog "To use the ESounD wrapper while using a system-wide daemon, you also"
+	elog "need to enable auth-anonymous for the esound-unix module, or to copy"
+	elog "/var/run/pulse/.esd_auth into each home directory."
+	elog
+	elog "If you want to make use of realtime capabilities of PulseAudio"
+	elog "you should follow the realtime guide to create and set up a realtime"
+	elog "user group: http://www.gentoo.org/proj/en/desktop/sound/realtime.xml"
+	elog "Make sure you also have baselayout installed with pam USE flag"
+	elog "enabled, if you're using the rlimit method."
+
+	eselect esd update --if-unset
+}