Version bump

(Portage version: 2.1.10.57/cvs/Linux x86_64)

2 files changed, 89 insertions, 1 deletions

diff --git a/media-sound/xwax/ChangeLog b/media-sound/xwax/ChangeLog
index fc56b65a37d8..5dea53e3cee9 100644
--- a/media-sound/xwax/ChangeLog
+++ b/media-sound/xwax/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/xwax
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/xwax/ChangeLog,v 1.39 2012/02/25 15:10:13 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/xwax/ChangeLog,v 1.40 2012/05/13 19:22:14 nixphoeni Exp $
+
+*xwax-1.2 (13 May 2012)
+
+  13 May 2012; Joe Sapp <nixphoeni@gentoo.org> +xwax-1.2.ebuild:
+  Version bump
 
   25 Feb 2012; Samuli Suominen <ssuominen@gentoo.org> xwax-1.0.ebuild:
   ppc/ppc64 stable wrt #400415
diff --git a/media-sound/xwax/xwax-1.2.ebuild b/media-sound/xwax/xwax-1.2.ebuild
new file mode 100644
index 000000000000..6b8b990d2616
--- /dev/null
+++ b/media-sound/xwax/xwax-1.2.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/xwax/xwax-1.2.ebuild,v 1.1 2012/05/13 19:22:14 nixphoeni Exp $
+
+EAPI=4
+inherit toolchain-funcs
+
+DESCRIPTION="Digital vinyl emulation software"
+HOMEPAGE="http://www.xwax.co.uk/"
+SRC_URI="http://www.xwax.co.uk/releases/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="alsa jack oss cdda mp3 +fallback"
+REQUIRED_USE="|| ( cdda mp3 fallback )
+	|| ( alsa jack oss )"
+
+RDEPEND="sys-libs/glibc
+	media-libs/libsdl
+	media-libs/sdl-ttf
+	media-fonts/dejavu
+	alsa? ( media-libs/alsa-lib )
+	jack? ( media-sound/jack-audio-connection-kit )
+	cdda? ( media-sound/cdparanoia )
+	mp3? ( || ( media-sound/mpg123 media-sound/mpg321 ) )
+	fallback? ( virtual/ffmpeg )"
+DEPEND="${RDEPEND}"
+
+DOCS="README CHANGES"
+
+src_prepare() {
+	# Remove the forced optimization from 'CFLAGS' and 'LDFLAGS' in
+	# the Makefile
+	# Also remove the dependency on the .version target so we don't need
+	# git just to build
+	sed -i -e 's/\(^\(LD\|C\)FLAGS.*\)-O[0-9]\(.*\)/\1\3/g' \
+		-e 's/^xwax\.o:.*\.version//' \
+		Makefile || die "sed failed"
+
+	# Replace any decoder commands in the import script, if necessary
+	if [[ `use mp3` ]]; then
+		# mpg123 is upstream's default
+		if has_version media-sound/mpg123; then
+			TO="mpg123"
+			FROM="mpg321"
+		# Otherwise, use mpg321
+		else
+			TO="mpg321"
+			FROM="mpg123"
+		fi
+		debug-print "found ${TO}"
+		sed -i -e "s:${FROM}:${TO}:g" import || \
+			die "problem converting xwax-import to use ${TO}"
+	fi
+}
+
+src_configure() {
+	tc-export CC
+	econf \
+		--prefix "${EROOT}usr" \
+		$(use_enable alsa) \
+		$(use_enable jack) \
+		$(use_enable oss)
+}
+
+src_compile() {
+	# EXECDIR is the default directory in which xwax will look for
+	# the 'xwax-import' and 'xwax-scan' scripts
+	emake EXECDIR="\$(BINDIR)" VERSION="${PV}"
+}
+
+src_install() {
+	# This is easier than setting all the environment variables
+	# needed, running the sed script required to get the man directory
+	# correct, and removing the GPL-2 after a 'make install' run
+	dobin xwax || die "failed to install xwax"
+	newbin import xwax-import || die "failed to install xwax-import"
+	newbin scan xwax-scan || die "failed to install xwax-scan"
+	doman xwax.1 || die "failed to install man page"
+
+	dodoc ${DOCS} || die "failed to install docs"
+}