Bump to new snapshot (fixes bug #484048).

(Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 86 insertions, 1 deletions

diff --git a/media-sound/moc/ChangeLog b/media-sound/moc/ChangeLog
index 350fdc897f96..20679afcc2c3 100644
--- a/media-sound/moc/ChangeLog
+++ b/media-sound/moc/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/moc
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/moc/ChangeLog,v 1.112 2013/04/13 07:36:15 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/moc/ChangeLog,v 1.113 2013/09/07 10:15:18 radhermit Exp $
+
+*moc-2.5.0_beta1_p20130907 (07 Sep 2013)
+
+  07 Sep 2013; Tim Harder <radhermit@gentoo.org>
+  +moc-2.5.0_beta1_p20130907.ebuild:
+  Bump to new snapshot (fixes bug #484048).
 
   13 Apr 2013; Agostino Sarubbo <ago@gentoo.org> moc-2.5.0_beta1-r1.ebuild:
   Stable for sparc, wrt bug #464548
diff --git a/media-sound/moc/moc-2.5.0_beta1_p20130907.ebuild b/media-sound/moc/moc-2.5.0_beta1_p20130907.ebuild
new file mode 100644
index 000000000000..2be423c39e01
--- /dev/null
+++ b/media-sound/moc/moc-2.5.0_beta1_p20130907.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/moc/moc-2.5.0_beta1_p20130907.ebuild,v 1.1 2013/09/07 10:15:18 radhermit Exp $
+
+EAPI=5
+
+DESCRIPTION="Music On Console - ncurses interface for playing audio files"
+HOMEPAGE="http://moc.daper.net"
+SRC_URI="http://dev.gentoo.org/~radhermit/dist/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="aac alsa +cache curl debug ffmpeg flac jack libsamplerate mad +magic modplug musepack
+oss sid sndfile speex timidity tremor +unicode vorbis wavpack"
+
+# libltdl from libtool is used at runtime
+RDEPEND=">=sys-devel/libtool-2.2.6b
+	sys-libs/ncurses[unicode?]
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	cache? ( >=sys-libs/db-4 )
+	curl? ( net-misc/curl )
+	ffmpeg? ( virtual/ffmpeg )
+	flac? ( media-libs/flac )
+	jack? ( media-sound/jack-audio-connection-kit )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad sys-libs/zlib media-libs/libid3tag )
+	magic? ( sys-apps/file )
+	modplug? ( media-libs/libmodplug )
+	musepack? ( media-sound/musepack-tools media-libs/taglib )
+	sid? ( >=media-libs/libsidplay-2 )
+	sndfile? ( media-libs/libsndfile )
+	speex? ( media-libs/speex )
+	timidity? ( media-libs/libtimidity media-sound/timidity++ )
+	vorbis? (
+		media-libs/libogg
+		tremor? ( media-libs/tremor )
+		!tremor? ( media-libs/libvorbis )
+	)
+	wavpack? ( media-sound/wavpack )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable debug)
+		$(use_enable cache)
+		$(use_with oss)
+		$(use_with alsa)
+		$(use_with jack)
+		$(use_with magic)
+		$(use_with unicode ncursesw)
+		$(use_with libsamplerate samplerate)
+		$(use_with aac)
+		$(use_with ffmpeg)
+		$(use_with flac)
+		$(use_with modplug)
+		$(use_with mad mp3)
+		--without-rcc
+		$(use_with musepack)
+		$(use_with sid sidplay2)
+		$(use_with sndfile)
+		$(use_with speex)
+		$(use_with timidity)
+		$(use_with vorbis vorbis $(usex tremor tremor ""))
+		$(use_with wavpack)
+		$(use_with curl)
+		)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+}