Bump bino to 1.4.4 thanks to PhobosK, see bug #501374, #499772 and #482938

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x2EDD52403B68AF47)

2 files changed, 77 insertions, 2 deletions

diff --git a/media-video/bino/ChangeLog b/media-video/bino/ChangeLog
index fe6171b677e5..379d579c39b0 100644
--- a/media-video/bino/ChangeLog
+++ b/media-video/bino/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/bino
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/bino/ChangeLog,v 1.4 2013/05/12 17:25:00 hwoarang Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/bino/ChangeLog,v 1.5 2014/05/02 20:13:59 swift Exp $
+
+*bino-1.4.4 (02 May 2014)
+
+  02 May 2014; Sven Vermeulen <swift@gentoo.org> +bino-1.4.4.ebuild:
+  Bump bino to 1.4.4 thanks to PhobosK, see bug #501374, #499772 and #482938
 
 *bino-1.4.2-r1 (12 May 2013)
 
diff --git a/media-video/bino/bino-1.4.4.ebuild b/media-video/bino/bino-1.4.4.ebuild
new file mode 100644
index 000000000000..38ff0907f914
--- /dev/null
+++ b/media-video/bino/bino-1.4.4.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/bino/bino-1.4.4.ebuild,v 1.1 2014/05/02 20:13:59 swift Exp $
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF="1"
+
+inherit autotools-utils flag-o-matic
+
+DESCRIPTION="Stereoscopic and multi-display media player"
+HOMEPAGE="http://bino3d.org/"
+SRC_URI="http://download.savannah.gnu.org/releases/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc lirc"
+
+IUSE_VIDEO_CARDS="
+	video_cards_nvidia"
+IUSE+="${IUSE_VIDEO_CARDS}"
+
+LANGS="en bg de fr ru zh_CN"
+for X in ${LANGS} ; do
+	IUSE+=" linguas_${X}"
+done
+
+RDEPEND=">=media-libs/glew-1.6.0
+	>=media-libs/openal-1.15.1
+	dev-qt/qtgui:4
+	dev-qt/qtcore:4
+	dev-qt/qtopengl:4
+	>=media-libs/libass-0.9.9
+	>=virtual/ffmpeg-0.6.90
+	lirc? ( app-misc/lirc )
+	video_cards_nvidia? ( media-video/nvidia-settings )
+	virtual/libintl"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog NEWS README README.Linux )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.4.2-lirc-detect.patch" # detect lirc
+)
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with video_cards_nvidia xnvctrl)
+		$(use_with lirc liblircclient)
+		--without-equalizer
+		--htmldir=/usr/share/doc/${PF}/html
+	)
+	use video_cards_nvidia && append-cppflags "-I/usr/include/NVCtrl" && append-ldflags "-I/usr/$(get_libdir)" && append-libs "Xext"
+	use lirc && append-cppflags "-I/usr/include/lirc"  && append-libs "lirc_client"
+
+	# Fix a compilation error because of a multiple definitions in glew
+	append-ldflags "-zmuldefs"
+
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+
+	use doc || ( rm -rf "${D}"/usr/share/doc/${PF}/html && dohtml "${FILESDIR}/${PN}.html" )
+}