Convert to distutils-r1.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 67 insertions, 3 deletions

diff --git a/media-video/gaupol/ChangeLog b/media-video/gaupol/ChangeLog
index ae601834b66f..91dabf483e2a 100644
--- a/media-video/gaupol/ChangeLog
+++ b/media-video/gaupol/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/gaupol
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/gaupol/ChangeLog,v 1.17 2012/04/23 04:31:10 patrick Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/gaupol/ChangeLog,v 1.18 2014/05/22 21:16:49 mgorny Exp $
+
+*gaupol-0.19.2-r1 (22 May 2014)
+
+  22 May 2014; Michał Górny <mgorny@gentoo.org> +gaupol-0.19.2-r1.ebuild:
+  Convert to distutils-r1.
 
 *gaupol-0.19.2 (23 Apr 2012)
 
@@ -72,4 +77,3 @@
 
   01 Dec 2006; Steve Dibb <beandog@gentoo.org> ChangeLog:
   Initial import, bug 118703, thanks to Ben de Groot for ebuild
-
diff --git a/media-video/gaupol/gaupol-0.19.2-r1.ebuild b/media-video/gaupol/gaupol-0.19.2-r1.ebuild
new file mode 100644
index 000000000000..c84e8305860b
--- /dev/null
+++ b/media-video/gaupol/gaupol-0.19.2-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/gaupol/gaupol-0.19.2-r1.ebuild,v 1.1 2014/05/22 21:16:49 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 fdo-mime gnome2-utils versionator
+
+MAJOR_MINOR_VERSION="$(get_version_component_range 1-2)"
+
+DESCRIPTION="Gaupol is a subtitle editor for text-based subtitles"
+HOMEPAGE="http://home.gna.org/gaupol"
+SRC_URI="http://download.gna.org/${PN}/${MAJOR_MINOR_VERSION}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="spell"
+
+RDEPEND="dev-python/chardet[${PYTHON_USEDEP}]
+	>=dev-python/pygtk-2.16[${PYTHON_USEDEP}]
+	spell? (
+		app-text/iso-codes
+		>=dev-python/pyenchant-1.4[${PYTHON_USEDEP}]
+	)"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext"
+
+DOCS=( AUTHORS ChangeLog CREDITS NEWS TODO README )
+
+src_compile() {
+	addpredict /root/.gconf
+	addpredict /root/.gconfd
+	distutils-r1_src_compile
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+	elog "Previewing support needs MPlayer or VLC."
+
+	if use spell; then
+		elog "Additionally, spell-checking requires a dictionary, any of"
+		elog "Aspell/Pspell, Ispell, MySpell, Uspell, Hspell or AppleSpell."
+	fi
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}