Version bump, see bug #146482. Some cleanups.

(Portage version: 2.1.2_pre1)

3 files changed, 70 insertions, 1 deletions

diff --git a/media-video/kino/ChangeLog b/media-video/kino/ChangeLog
index 411531b51e26..d561593c47f6 100644
--- a/media-video/kino/ChangeLog
+++ b/media-video/kino/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/kino
 # Copyright 2002-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/kino/ChangeLog,v 1.47 2006/08/11 02:24:10 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/kino/ChangeLog,v 1.48 2006/09/16 16:43:20 calchan Exp $
+
+*kino-0.9.2 (16 Sep 2006)
+
+  16 Sep 2006; Denis Dupeyron <calchan@gentoo.org> +kino-0.9.2.ebuild:
+  Version bump, see bug #146482. Some cleanups.
 
   11 Aug 2006; Joseph Jezak <josejx@gentoo.org>
   +files/kino-0.9.0-compile-fix.patch, kino-0.9.0.ebuild:
diff --git a/media-video/kino/files/digest-kino-0.9.2 b/media-video/kino/files/digest-kino-0.9.2
new file mode 100644
index 000000000000..3fcdc96e8a37
--- /dev/null
+++ b/media-video/kino/files/digest-kino-0.9.2
@@ -0,0 +1,3 @@
+MD5 9c0d5a4d2fb04896c719e44df44a2622 kino-0.9.2.tar.gz 1580036
+RMD160 5c16318f061d83bab8051da3d23917da7a8c1ca2 kino-0.9.2.tar.gz 1580036
+SHA256 2df8937eff8ac2848bf5d5d533bb2b322fbd17d455b5a7d56794026008074ce1 kino-0.9.2.tar.gz 1580036
diff --git a/media-video/kino/kino-0.9.2.ebuild b/media-video/kino/kino-0.9.2.ebuild
new file mode 100644
index 000000000000..bba15dc6e8ac
--- /dev/null
+++ b/media-video/kino/kino-0.9.2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/kino/kino-0.9.2.ebuild,v 1.1 2006/09/16 16:43:20 calchan Exp $
+
+DESCRIPTION="Kino is a non-linear DV editor for GNU/Linux"
+HOMEPAGE="http://kino.schirmacher.de/"
+SRC_URI="mirror://sourceforge/kino/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="alsa dvdr ffmpeg quicktime sox vorbis"
+
+DEPEND=">=x11-libs/gtk+-2.6.0
+	>=gnome-base/libglade-2.5.0
+	>=dev-libs/glib-2
+	dev-libs/libxml2
+	media-libs/audiofile
+	>=sys-libs/libraw1394-1.0.0
+	>=sys-libs/libavc1394-0.4.1
+	>=media-libs/libdv-0.103
+	media-libs/libsamplerate
+	!sparc? ( media-libs/libiec61883 )
+	alsa? ( >=media-libs/alsa-lib-1.0.9 )
+	ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20051216 )
+	quicktime? ( || ( >=media-libs/libquicktime-0.9.5 media-video/cinelerra-cvs ) )"
+RDEPEND="${DEPEND}
+	media-video/mjpegtools
+	media-sound/rawrec
+	dvdr? ( media-video/dvdauthor )
+	sox? ( media-sound/sox )
+	vorbis? ( media-sound/vorbis-tools )"
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+
+	# Fix to link with --as-needed
+	sed -i -e 's:LIBS="-lXext:LIBS="-lXext -lX11:' configure || die "sed failed!"
+
+	# Deactivating automagic alsa configuration, bug #134725
+	if ! use alsa ; then
+		sed -i -e "s:HAVE_ALSA 1:HAVE_ALSA 0:" configure || die "sed failed!"
+	fi
+}
+
+src_compile() {
+	econf \
+		--disable-dependency-tracking \
+		--disable-debug \
+		$(use_enable quicktime) \
+		$(use_with ffmpeg avcodec) \
+		$(use_with sparc dv1394) \
+		|| die "Configuration failed"
+	emake || die "Compilation failed"
+}
+
+src_install() {
+	emake DESTDIR=${D} install || die "Installation failed"
+	dodoc AUTHORS BUGS ChangeLog NEWS README* TODO
+}