Re-add nsplugin support with dependency on firefox or seamonkey (use seamonkey useflag). Enable optimise for memory with optimisememory useflag.

(Portage version: 2.1.1_pre2-r2)

3 files changed, 263 insertions, 1 deletions

diff --git a/media-video/vlc/ChangeLog b/media-video/vlc/ChangeLog
index b5d3650adf18..fd317d755d9d 100644
--- a/media-video/vlc/ChangeLog
+++ b/media-video/vlc/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/vlc
 # Copyright 2002-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v 1.179 2006/07/04 14:02:00 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v 1.180 2006/07/04 23:00:25 flameeyes Exp $
+
+*vlc-0.8.5-r4 (04 Jul 2006)
+
+  04 Jul 2006; Diego Pettenò <flameeyes@gentoo.org> +vlc-0.8.5-r4.ebuild:
+  Re-add nsplugin support with dependency on firefox or seamonkey (use
+  seamonkey useflag). Enable optimise for memory with optimisememory useflag.
 
   04 Jul 2006; Diego Pettenò <flameeyes@gentoo.org> vlc-0.8.5-r3.ebuild:
   Bump patchset to fix the parallel install problem reported in bug #139176.
diff --git a/media-video/vlc/files/digest-vlc-0.8.5-r4 b/media-video/vlc/files/digest-vlc-0.8.5-r4
new file mode 100644
index 000000000000..f2363dfc5b13
--- /dev/null
+++ b/media-video/vlc/files/digest-vlc-0.8.5-r4
@@ -0,0 +1,6 @@
+MD5 16bb5bf87ed94879a8eb7b0ff9b4f16f vlc-0.8.5.tar.bz2 8562996
+RMD160 d24140a5b4bf771754028090e103bb5c171e4fd8 vlc-0.8.5.tar.bz2 8562996
+SHA256 48bc557bec16b48a304e5e760aef10e1c3cca2d74a011bc900bd1768d9ee79fa vlc-0.8.5.tar.bz2 8562996
+MD5 3bb5c88f50c5375dba2fdb00343bc445 vlc-patches-26.tar.bz2 11815
+RMD160 1db7b615899535dbd03f99028e053a5503901781 vlc-patches-26.tar.bz2 11815
+SHA256 b21b2f81840dc0270214de08fb7bf5185b9d8b8366e9628b1b97f74c89b571a9 vlc-patches-26.tar.bz2 11815
diff --git a/media-video/vlc/vlc-0.8.5-r4.ebuild b/media-video/vlc/vlc-0.8.5-r4.ebuild
new file mode 100644
index 000000000000..3b8e22c08727
--- /dev/null
+++ b/media-video/vlc/vlc-0.8.5-r4.ebuild
@@ -0,0 +1,250 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-0.8.5-r4.ebuild,v 1.1 2006/07/04 23:00:25 flameeyes Exp $
+
+inherit eutils wxwidgets multilib autotools toolchain-funcs gnome2
+
+RESTRICT="confcache"
+
+MY_P="${P/_beta/-test}"
+
+PATCHLEVEL="26"
+DESCRIPTION="VLC media player - Video player and streamer"
+HOMEPAGE="http://www.videolan.org/vlc/"
+
+[[ ${MY_P} != "${P}" ]] && \
+	SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2" \
+	|| SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
+
+SRC_URI="${SRC_URI}
+	mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="a52 3dfx nls debug altivec httpd vlm gnutls live v4l cdda ogg matroska
+dvb dvd vcd ffmpeg dts flac mpeg vorbis theora X opengl truetype svg fbcon svga
+oss aalib ggi libcaca esd arts alsa wxwindows ncurses xosd lirc stream
+mp3 xv bidi sdl png xml samba daap corba screen mod speex shout rtsp
+win32codecs skins hal avahi xinerama cddb directfb upnp nsplugin seamonkey
+optimisememory"
+
+RDEPEND="cdda? ( >=dev-libs/libcdio-0.71
+			cddb? ( >=media-libs/libcddb-1.2.0 ) )
+		live? ( >=media-plugins/live-2005.01.29 )
+		dvd? (	media-libs/libdvdread
+				media-libs/libdvdcss
+				>=media-libs/libdvdnav-0.1.9
+				media-libs/libdvdplay )
+		esd? ( media-sound/esound )
+		ogg? ( media-libs/libogg )
+		matroska? (
+			>=dev-libs/libebml-0.7.6
+			>=media-libs/libmatroska-0.7.5 )
+		mp3? ( media-libs/libmad )
+		ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20050226-r1 )
+		a52? ( >=media-libs/a52dec-0.7.4-r3 )
+		dts? ( >=media-libs/libdts-0.0.2-r3 )
+		flac? ( media-libs/flac )
+		mpeg? ( >=media-libs/libmpeg2-0.3.2 )
+		vorbis? ( media-libs/libvorbis )
+		theora? ( media-libs/libtheora )
+		truetype? ( media-libs/freetype
+			media-fonts/ttf-bitstream-vera )
+		svga? ( media-libs/svgalib )
+		ggi? ( media-libs/libggi )
+		aalib? ( media-libs/aalib )
+		libcaca? ( media-libs/libcaca )
+		arts? ( kde-base/arts )
+		alsa? ( media-libs/alsa-lib )
+		wxwindows? ( >=x11-libs/wxGTK-2.6.2-r1 )
+		ncurses? ( sys-libs/ncurses )
+		xosd? ( x11-libs/xosd )
+		lirc? ( app-misc/lirc )
+		3dfx? ( media-libs/glide-v3 )
+		bidi? ( >=dev-libs/fribidi-0.10.4 )
+		gnutls? ( >=net-libs/gnutls-1.0.17 )
+		sys-libs/zlib
+		png? ( media-libs/libpng )
+		media-libs/libdvbpsi
+		sdl? ( >=media-libs/libsdl-1.2.8 )
+		xml? ( dev-libs/libxml2 )
+		samba? ( net-fs/samba )
+		vcd? ( >=dev-libs/libcdio-0.72
+			>=media-video/vcdimager-0.7.21 )
+		daap? ( >=media-libs/libopendaap-0.3.0 )
+		corba? ( >=gnome-base/orbit-2.8.0
+			>=dev-libs/glib-2.3.2 )
+		v4l? ( sys-kernel/linux-headers )
+		dvb? ( sys-kernel/linux-headers )
+		mod? ( media-libs/libmodplug )
+		speex? ( media-libs/speex )
+		svg? ( >=gnome-base/librsvg-2.5.0 )
+		shout? ( media-libs/libshout )
+		win32codecs? ( media-libs/win32codecs )
+		hal? ( sys-apps/hal )
+		avahi? ( >=net-dns/avahi-0.6 )
+		X? ( || ( (
+				x11-libs/libX11
+				x11-libs/libXext
+				xv? ( x11-libs/libXv )
+				xinerama? ( x11-libs/libXinerama )
+			) virtual/x11 )
+			opengl? ( virtual/opengl )
+		)
+		directfb? ( dev-libs/DirectFB )
+		upnp? ( >=net-misc/upnp-1.2 )
+		nsplugin? (
+			!seamonkey? ( www-client/mozilla-firefox )
+			seamonkey? ( www-client/seamonkey )
+		)"
+
+DEPEND="${RDEPEND}
+	X? ( || ( (
+			x11-proto/xproto
+			x11-proto/xextproto
+			xinerama? ( x11-proto/xineramaproto )
+		) virtual/x11 )
+	)
+	dev-util/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	if use wxwindows; then
+		WX_GTK_VER="2.6"
+		need-wxwidgets unicode || die "You need to install wxGTK with unicode support."
+	fi
+
+	if use skins && ! use truetype; then
+		eerror "Trying to build with skins support but without truetype."
+		die "You have to use 'truetype' to use 'skins'"
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+
+	EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
+	AT_M4DIR="m4" eautoreconf
+}
+
+src_compile () {
+	use wxwindows && \
+		myconf="${myconf} --with-wx-config=$(basename ${WX_CONFIG}) --with-wx-config-path=$(dirname ${WX_CONFIG})"
+
+	use vlm && \
+		myconf="${myconf} --enable-vlm --enable-sout" || \
+		myconf="${myconf} --disable-vlm"
+
+	if use directfb; then
+		myconf="${myconf} --enable-directfb --with-directfb=/usr"
+		append-flags "-I /usr/include/directfb"
+	else
+		myconf="${myconf} --disable-directfb"
+	fi
+
+	if use nsplugin; then
+		use seamonkey && \
+			myconf="${myconf} --enable-mozilla=seamonkey" || \
+			myconf="${myconf} --enable-mozilla=firefox"
+	fi
+
+	econf \
+		$(use_enable altivec) \
+		$(use_enable stream sout) \
+		$(use_enable httpd) \
+		$(use_enable gnutls) \
+		$(use_enable v4l) \
+		$(use_enable cdda) $(use_enable cdda cddax)\
+		$(use_enable cddb libcddb) \
+		$(use_enable vcd) $(use_enable vcd vcdx) \
+		$(use_enable dvb) $(use_enable dvb pvr) \
+		$(use_enable ogg) \
+		$(use_enable matroska mkv) \
+		$(use_enable flac) \
+		$(use_enable vorbis) \
+		$(use_enable theora) \
+		$(use_enable X x11) \
+		$(use_enable xv xvideo) \
+		$(use_enable xinerama) \
+		$(use_enable opengl glx) $(use_enable opengl) \
+		$(use_enable truetype freetype) \
+		$(use_enable bidi fribidi) \
+		$(use_enable dvd dvdread) $(use_enable dvd dvdplay) $(use_enable dvd dvdnav) \
+		$(use_enable fbcon fb) \
+		$(use_enable svga svgalib) \
+		$(use_enable 3dfx glide) \
+		$(use_enable aalib aa) \
+		$(use_enable libcaca caca) \
+		$(use_enable oss) \
+		$(use_enable esd) \
+		$(use_enable arts) \
+		$(use_enable alsa) \
+		$(use_enable wxwindows wxwidgets) \
+		$(use_enable ncurses) \
+		$(use_enable xosd) \
+		$(use_enable lirc) \
+		$(use_enable live livedotcom) $(use_with live livedotcom-tree /usr/lib/live) \
+		$(use_enable mp3 mad) \
+		$(use_enable a52) \
+		$(use_enable dts) \
+		$(use_enable mpeg libmpeg2) \
+		$(use_enable ggi) \
+		$(use_enable 3dfx glide) \
+		$(use_enable sdl) \
+		$(use_enable png) \
+		$(use_enable xml libxml2) \
+		$(use_enable samba smb) \
+		$(use_enable daap) \
+		$(use_enable corba) \
+		$(use_enable mod) \
+		$(use_enable speex) \
+		$(use_enable shout) \
+		$(use_enable rtsp) $(use_enable rtsp realrtsp) \
+		$(use_enable win32codecs loader) \
+		$(use_enable skins skins2) \
+		$(use_enable hal) \
+		$(use_enable avahi bonjour) \
+		$(use_enable ffmpeg) \
+		$(use_enable upnp) \
+		$(use_enable optimisememory optimize-memory) \
+		--disable-faad \
+		--disable-jack \
+		--disable-dv \
+		--disable-libvc1 \
+		--disable-snapshot \
+		--disable-growl \
+		--disable-pth \
+		--disable-portaudio \
+		--disable-x264 \
+		--enable-utf8 \
+		${myconf} || die "configuration failed"
+
+	if [[ $(gcc-major-version) == 2 ]]; then
+		sed -i -e s:"-fomit-frame-pointer":: vlc-config || die "-fomit-frame-pointer patching failed"
+	fi
+
+	emake || die "make of VLC failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "Installation failed!"
+
+	dodoc AUTHORS MAINTAINERS HACKING THANKS TODO NEWS README \
+		doc/fortunes.txt doc/intf-cdda.txt doc/intf-vcd.txt
+
+	rm -rf ${D}/usr/share/doc/vlc \
+		${D}/usr/share/vlc/vlc{16x16,32x32,48x48,128x128}.{png,xpm,ico}
+
+	use skins || rm -rf ${D}/usr/share/vlc/skins2
+
+	for res in 16 32 48; do
+		insinto /usr/share/icons/hicolor/${res}x${res}/apps/
+		newins ${S}/share/vlc${res}x${res}.png vlc.png
+	done
+
+	use wxwindows && domenu "${S}/debian/vlc.desktop"
+}