Version bump: EAPI 5, migrate to distutils-r1, optional dependencies for IRC backend. Drop old versions

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

6 files changed, 99 insertions, 186 deletions

diff --git a/net-im/err/ChangeLog b/net-im/err/ChangeLog
index 0ff03c815b66..99c2276f5377 100644
--- a/net-im/err/ChangeLog
+++ b/net-im/err/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-im/err
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/err/ChangeLog,v 1.13 2013/04/17 07:24:39 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/err/ChangeLog,v 1.14 2013/10/05 16:24:15 pinkbyte Exp $
+
+*err-1.7.1 (05 Oct 2013)
+
+  05 Oct 2013; Sergey Popov <pinkbyte@gentoo.org> -err-1.3.1-r1.ebuild,
+  -err-1.5.1-r1.ebuild, -err-1.6.1.ebuild, +err-1.7.1.ebuild, metadata.xml:
+  Version bump: EAPI 5, migrate to distutils-r1, optional dependencies for IRC
+  backend. Drop old versions
 
   17 Apr 2013; Sergey Popov <pinkbyte@gentoo.org> err-1.3.1-r1.ebuild,
   err-1.5.1-r1.ebuild, err-1.6.1.ebuild:
diff --git a/net-im/err/err-1.3.1-r1.ebuild b/net-im/err/err-1.3.1-r1.ebuild
deleted file mode 100644
index 822e0833f926..000000000000
--- a/net-im/err/err-1.3.1-r1.ebuild
+++ /dev/null
@@ -1,52 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/err/err-1.3.1-r1.ebuild,v 1.2 2013/04/17 07:24:39 pinkbyte Exp $
-
-EAPI=4
-
-DISTUTILS_SRC_TEST="setup.py"
-
-SUPPORT_PYTHON_ABIS="1"
-PYTHON_DEPEND="2:2.7"
-RESTRICT_PYTHON_ABIS="3.*"
-
-inherit distutils eutils user
-
-DESCRIPTION="Plugin based XMPP chatbot designed to be easily deployable, extensible and maintainable"
-HOMEPAGE="http://gbin.github.com/err/"
-
-SRC_URI="mirror://pypi/e/${PN}/${P}.tar.gz"
-KEYWORDS="~amd64 ~x86"
-LICENSE="GPL-3"
-SLOT="0"
-IUSE="+plugins"
-
-DEPEND="dev-python/setuptools"
-RDEPEND="dev-python/xmpppy
-	dev-python/python-daemon
-	<dev-python/yapsy-1.10
-	plugins? ( dev-vcs/git )"
-
-pkg_setup() {
-	python_pkg_setup
-	ebegin "Creating err group and user"
-	enewgroup 'err'
-	enewuser 'err' -1 -1 -1 'err'
-	eend ${?}
-}
-
-src_install() {
-	distutils_src_install
-	newinitd "${FILESDIR}"/errd.initd errd
-	newconfd "${FILESDIR}"/errd.confd errd
-	dodir /etc/${PN}
-	dodir /var/lib/${PN}
-	# Create plugins directory here because of err creates it itself with 0777 rights
-	dodir /var/lib/${PN}/plugins
-
-	keepdir /var/log/${PN}
-	fowners -R err:err /var/lib/${PN}
-	fowners -R err:err /var/log/${PN}
-	insinto /etc/${PN}
-	newins errbot/config-template.py config.py
-}
diff --git a/net-im/err/err-1.5.1-r1.ebuild b/net-im/err/err-1.5.1-r1.ebuild
deleted file mode 100644
index df40a5c9e3e1..000000000000
--- a/net-im/err/err-1.5.1-r1.ebuild
+++ /dev/null
@@ -1,59 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/err/err-1.5.1-r1.ebuild,v 1.2 2013/04/17 07:24:39 pinkbyte Exp $
-
-EAPI=4
-
-DISTUTILS_SRC_TEST="setup.py"
-
-SUPPORT_PYTHON_ABIS="1"
-PYTHON_DEPEND="2:2.7"
-RESTRICT_PYTHON_ABIS="3.*"
-
-inherit distutils eutils user
-
-DESCRIPTION="Plugin based XMPP chatbot designed to be easily deployable, extensible and maintainable"
-HOMEPAGE="http://gbin.github.com/err/"
-
-SRC_URI="mirror://pypi/e/${PN}/${P}.tar.gz"
-KEYWORDS="~amd64 ~x86"
-LICENSE="GPL-3"
-SLOT="0"
-IUSE="qt4 +plugins"
-
-DEPEND="dev-python/setuptools"
-RDEPEND="dev-python/dnspython
-	dev-python/jinja
-	dev-python/python-daemon
-	dev-python/xmpppy
-	<dev-python/yapsy-1.10
-	qt4? ( dev-python/pyside[X,webkit] )
-	plugins? ( dev-vcs/git )"
-
-pkg_setup() {
-	python_pkg_setup
-	ebegin "Creating err group and user"
-	enewgroup 'err'
-	enewuser 'err' -1 -1 -1 'err'
-	eend ${?}
-}
-
-src_install() {
-	# Upstream requires images to be in site-packages directory,
-	# butdoes not install them at all!
-	install_svgs() {
-		insinto "$(python_get_sitedir)"/errbot
-		doins errbot/*.svg
-	}
-	distutils_src_install
-	newinitd "${FILESDIR}"/errd.initd errd
-	newconfd "${FILESDIR}"/errd.confd errd
-	dodir /etc/${PN}
-	dodir /var/lib/${PN}
-	keepdir /var/log/${PN}
-	fowners -R err:err /var/lib/${PN}
-	fowners -R err:err /var/log/${PN}
-	insinto /etc/${PN}
-	newins errbot/config-template.py config.py
-	use qt4 && python_execute_function install_svgs
-}
diff --git a/net-im/err/err-1.6.1.ebuild b/net-im/err/err-1.6.1.ebuild
deleted file mode 100644
index 6b6b2a31a3ff..000000000000
--- a/net-im/err/err-1.6.1.ebuild
+++ /dev/null
@@ -1,74 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/err/err-1.6.1.ebuild,v 1.2 2013/04/17 07:24:39 pinkbyte Exp $
-
-EAPI=5
-
-DISTUTILS_SRC_TEST="setup.py"
-
-SUPPORT_PYTHON_ABIS="1"
-PYTHON_DEPEND="2:2.7"
-RESTRICT_PYTHON_ABIS="3.*"
-
-inherit distutils eutils user
-
-DESCRIPTION="Plugin based XMPP chatbot designed to be easily deployable, extensible and maintainable"
-HOMEPAGE="http://gbin.github.com/err/"
-
-SRC_URI="mirror://pypi/e/${PN}/${P}.tar.gz"
-KEYWORDS="~amd64 ~x86"
-LICENSE="GPL-3"
-SLOT="0"
-IUSE="qt4 +plugins"
-
-DEPEND="dev-python/setuptools"
-# NOTES:
-# 1. It has bundled libs - for example exrex(see 'errbot/bundled' subfolder)
-RDEPEND="dev-python/dnspython
-	dev-python/flask
-	dev-python/jinja
-	dev-python/pyfire
-	dev-python/python-daemon
-	dev-python/simplejson
-	dev-python/xmpppy
-	<dev-python/yapsy-1.10
-	qt4? ( dev-python/pyside[X,webkit] )
-	plugins? ( dev-vcs/git )"
-
-pkg_setup() {
-	python_pkg_setup
-	ebegin "Creating err group and user"
-	enewgroup 'err'
-	enewuser 'err' -1 -1 -1 'err'
-	eend ${?}
-}
-
-src_prepare() {
-	# Remove configparser from requirements
-	sed -i "s/'configparser', //" setup.py || die "remove configparser from setup.py failed"
-	distutils_src_prepare
-}
-
-src_install() {
-	# Upstream requires images to be in site-packages directory,
-	# butdoes not install them at all!
-	install_svgs() {
-		insinto "$(python_get_sitedir)"/errbot
-		doins errbot/*.svg
-	}
-	distutils_src_install
-
-	newinitd "${FILESDIR}"/errd.initd errd
-	newconfd "${FILESDIR}"/errd.confd errd
-
-	dodir /etc/${PN}
-	dodir /var/lib/${PN}
-	keepdir /var/log/${PN}
-	fowners -R err:err /var/lib/${PN}
-	fowners -R err:err /var/log/${PN}
-
-	insinto /etc/${PN}
-	newins errbot/config-template.py config.py
-
-	use qt4 && python_execute_function install_svgs
-}
diff --git a/net-im/err/err-1.7.1.ebuild b/net-im/err/err-1.7.1.ebuild
new file mode 100644
index 000000000000..db969b2ba50f
--- /dev/null
+++ b/net-im/err/err-1.7.1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/err/err-1.7.1.ebuild,v 1.1 2013/10/05 16:24:15 pinkbyte Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+inherit distutils-r1 eutils user
+
+DESCRIPTION="Plugin based XMPP chatbot designed to be easily deployable, extensible and maintainable"
+HOMEPAGE="http://gbin.github.com/err/"
+
+SRC_URI="mirror://pypi/e/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="irc qt4 +plugins"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+RDEPEND="dev-python/dnspython[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/pyfire[${PYTHON_USEDEP}]
+	dev-python/python-daemon[${PYTHON_USEDEP}]
+	dev-python/xmpppy
+	dev-python/yapsy[${PYTHON_USEDEP}]
+	irc? (
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/twisted-core[${PYTHON_USEDEP}]
+		dev-python/twisted-words[${PYTHON_USEDEP}]
+	)
+	qt4? ( dev-python/pyside[${PYTHON_USEDEP},X,webkit] )
+	plugins? ( dev-vcs/git )"
+
+# Testsuite is broken since 1.6.3
+RESTRICT="test"
+
+# NOTES:
+# 1. It has bundled libs - for example exrex(see 'errbot/bundled' subfolder)
+# 2. Need to add PYTHON_USEDEP to remaining dev-python/ deps
+# 3. Support for BOT_SENTRY option is missing, cause
+#    we do not have apropriate packages in portage yet
+# 4. Internal web server is broken(dunno why :-()
+
+pkg_setup() {
+	ebegin "Creating err group and user"
+	enewgroup 'err'
+	enewuser 'err' -1 -1 -1 'err'
+	eend ${?}
+}
+
+python_prepare_all() {
+	# Remove configparser and config from requirements as they are NOT needed
+	sed -i \
+		-e "/install_requires/s/'configparser', //" \
+		-e "/install_requires/s/, 'config'//" \
+		setup.py || die
+
+	# Tests are broken and should not be installed
+	rm -r tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newinitd "${FILESDIR}"/errd.initd errd
+	newconfd "${FILESDIR}"/errd.confd errd
+
+	dodir /etc/${PN}
+	dodir /var/lib/${PN}
+	keepdir /var/log/${PN}
+	fowners -R err:err /var/lib/${PN}
+	fowners -R err:err /var/log/${PN}
+
+	insinto /etc/${PN}
+	newins errbot/config-template.py config.py
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Upstream requires images to be in site-packages directory,
+	# but does not install them at all!
+	if use qt4; then
+		local python_moduleroot=errbot
+		python_domodule errbot/*.svg
+	fi
+}
diff --git a/net-im/err/metadata.xml b/net-im/err/metadata.xml
index a1091ccecb0f..d7e1264c8006 100644
--- a/net-im/err/metadata.xml
+++ b/net-im/err/metadata.xml
@@ -6,6 +6,7 @@
 		<name>Sergey Popov</name>
 	</maintainer>
 	<use>
+		<flag name="irc">Pull optional dependencies, needed for IRC backend</flag>
 		<flag name="plugins">Enable support for installing plugins with <pkg>dev-vcs/git</pkg></flag>
 	</use>
 	<upstream>