Version bump, bug #301173, thank Justin Lecher (jlec) for report.

(Portage version: 2.1.7.16/cvs/Linux x86_64)

2 files changed, 96 insertions, 1 deletions

diff --git a/net-im/gajim/ChangeLog b/net-im/gajim/ChangeLog
index abfefcd47f5d..6f79c760db9d 100644
--- a/net-im/gajim/ChangeLog
+++ b/net-im/gajim/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-im/gajim
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/ChangeLog,v 1.84 2010/01/05 07:22:35 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/ChangeLog,v 1.85 2010/01/16 13:42:46 pva Exp $
+
+*gajim-0.13.2 (16 Jan 2010)
+
+  16 Jan 2010; Peter Volkov <pva@gentoo.org> +gajim-0.13.2.ebuild:
+  Version bump, bug #301173, thank Justin Lecher (jlec) for report.
 
   05 Jan 2010; Peter Volkov <pva@gentoo.org> gajim-0.13.1.ebuild:
   Up gettext version as it's required for tests to pass.
diff --git a/net-im/gajim/gajim-0.13.2.ebuild b/net-im/gajim/gajim-0.13.2.ebuild
new file mode 100644
index 000000000000..c1530de36c2a
--- /dev/null
+++ b/net-im/gajim/gajim-0.13.2.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/gajim-0.13.2.ebuild,v 1.1 2010/01/16 13:42:46 pva Exp $
+
+EAPI="2"
+
+NEED_PYTHON="2.5"
+inherit python eutils autotools versionator
+
+DESCRIPTION="Jabber client written in PyGTK"
+HOMEPAGE="http://www.gajim.org/"
+SRC_URI="http://www.gajim.org/downloads/$(get_version_component_range 1-2)/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="avahi crypt dbus gnome idle libnotify nls spell srv trayicon X xhtml"
+
+COMMON_DEPEND=">=dev-python/pygtk-2.12.0"
+
+DEPEND="${COMMON_DEPEND}
+	>=sys-devel/gettext-0.17-r1
+	>=dev-util/intltool-0.40.1
+	dev-util/pkgconfig"
+
+RDEPEND="${COMMON_DEPEND}
+	>=dev-lang/python-2.5[sqlite,xml]
+	dev-python/pyopenssl
+	dev-python/sexy-python
+	gnome? (
+		dev-python/libgnome-python
+		dev-python/gnome-keyring-python
+		trayicon? ( dev-python/egg-python ) )
+	dbus? (
+		dev-python/dbus-python
+		dev-libs/dbus-glib
+		libnotify? ( dev-python/notify-python )
+		avahi? ( net-dns/avahi[dbus,gtk,python] ) )
+	xhtml? ( dev-python/docutils )
+	srv? ( || (
+			dev-python/libasyncns-python
+			net-dns/bind-tools ) )
+	idle? ( x11-libs/libXScrnSaver )
+	spell? ( app-text/gtkspell )
+	crypt? (
+		app-crypt/gnupg
+		dev-python/pycrypto )"
+
+pkg_setup() {
+	if ! use dbus; then
+		if use libnotify; then
+			eerror "The dbus USE flag is required for libnotify support"
+			die "USE=\"dbus\" needed for libnotify support"
+		fi
+		if use avahi; then
+			eerror "The dbus USE flag is required for avahi support"
+			die "USE=\"dbus\" needed for avahi support"
+		fi
+	fi
+}
+
+src_prepare() {
+	# install pyfiles in /usr/lib/python2.x/site-packages/gajim
+	# upstream: http://trac.gajim.org/ticket/5460
+	epatch "${FILESDIR}/${PN}-0.13-autotools--enable-site-packages_option.patch"
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	if ! use gnome; then
+		myconf+=" $(use_enable trayicon)"
+	fi
+
+	econf \
+		$(use_enable nls) \
+		$(use_with X x) \
+		--docdir="/usr/share/doc/${PF}" \
+		--libdir="$(python_get_sitedir)" \
+		--enable-site-packages \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	rm "${D}/usr/share/doc/${PF}/{README.html,COPYING}"
+	dohtml README.html
+}