Version bump, drop old.

(Portage version: 2.2.0_alpha12_p8/cvs/Linux x86_64)

5 files changed, 122 insertions, 296 deletions

diff --git a/net-im/ekg2/ChangeLog b/net-im/ekg2/ChangeLog
index ce0fab7a5397..05d05fadb6be 100644
--- a/net-im/ekg2/ChangeLog
+++ b/net-im/ekg2/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-im/ekg2
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/ekg2/ChangeLog,v 1.37 2010/12/18 12:51:47 mgorny Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/ekg2/ChangeLog,v 1.38 2011/01/05 15:06:46 mgorny Exp $
+
+*ekg2-0.3.0_rc5 (05 Jan 2011)
+
+  05 Jan 2011; Michał Górny <mgorny@gentoo.org>
+  -files/0001-Drop-duplicate-config_audio_device-declaration-it-wa.patch,
+  -ekg2-0.3_pre20101008.ebuild, +ekg2-0.3.0_rc5.ebuild, metadata.xml:
+  Version bump, drop old.
 
 *ekg2-0.3.0_rc4 (18 Dec 2010)
 
diff --git a/net-im/ekg2/ekg2-0.3.0_rc5.ebuild b/net-im/ekg2/ekg2-0.3.0_rc5.ebuild
new file mode 100644
index 000000000000..90cab7948afd
--- /dev/null
+++ b/net-im/ekg2/ekg2-0.3.0_rc5.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/ekg2/ekg2-0.3.0_rc5.ebuild,v 1.1 2011/01/05 15:06:46 mgorny Exp $
+
+EAPI=2
+
+inherit autotools-utils versionator
+
+DESCRIPTION="Text-based, multi-protocol instant messenger"
+HOMEPAGE="http://www.ekg2.org"
+SRC_URI="http://pl.ekg2.org/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="expat gadu gif gnutls gpg gpm gsm gtk idn inotify jpeg ncurses nls
+	oracle perl python readline spell sqlite sqlite3 ssl threads unicode
+	xosd zlib"
+
+RDEPEND="
+	gpg? ( app-crypt/gpgme )
+	gsm? ( media-sound/gsm )
+	gtk? ( x11-libs/gtk+:2 )
+	idn? ( net-dns/libidn )
+	nls? ( virtual/libintl )
+	oracle?	( dev-db/oracle-instantclient-basic )
+	perl? ( dev-lang/perl )
+	python?	( dev-lang/python )
+	readline? ( sys-libs/readline )
+	ssl? ( dev-libs/openssl )
+	xosd? ( x11-libs/xosd )
+	zlib? ( sys-libs/zlib )
+
+	gadu? ( net-libs/libgadu
+		gif? ( media-libs/giflib )
+		jpeg? ( media-libs/jpeg ) )
+	expat? ( dev-libs/expat
+		gnutls? ( net-libs/gnutls ) )
+	ncurses? ( sys-libs/ncurses[unicode?]
+		gpm? ( sys-libs/gpm )
+		spell? ( app-text/aspell ) )
+	sqlite3? ( dev-db/sqlite:3 )
+	!sqlite3? ( sqlite? ( dev-db/sqlite:0 ) )"
+
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+DOCS=(
+	AUTHORS docs/README docs/TODO
+	docs/events.txt docs/mouse.txt docs/sim.txt docs/voip.txt
+	docs/themes.txt docs/themes-en.txt
+	docs/ui-ncurses.txt docs/ui-ncurses-en.txt
+)
+
+AUTOTOOLS_IN_SOURCE_BUILD=1
+
+pkg_setup() {
+	if ! use gtk && ! use ncurses && ! use readline; then
+		ewarn 'ekg2 is being compiled without any frontend, you should consider'
+		ewarn 'enabling at least one of following USEflags:'
+		ewarn '  gtk, ncurses, readline.'
+	fi
+
+	if use gnutls && ! use ssl; then
+		ewarn 'You have enabled USE=gnutls without USE=ssl. The SSL support'
+		ewarn 'in ekg2 will be limited to the plugins supporting GnuTLS.'
+	fi
+}
+
+src_configure() {
+	myeconfargs=(
+		$(use_with expat)
+		$(use_with gadu libgadu)
+		$(use_with gif)
+		$(use_with gnutls libgnutls)
+		$(use_with gpg)
+		$(use_with gpm gpm-mouse)
+		$(use_with gsm libgsm)
+		$(use_with gtk)
+		$(use_with idn libidn)
+		$(use_with inotify)
+		$(use_with jpeg libjpeg)
+		$(use_with ncurses)
+		$(use_with oracle logsoracle)
+		$(use_with perl)
+		$(use_with python)
+		$(use_with readline)
+		$(use_with spell aspell)
+		$(use_with sqlite)
+		$(use_with sqlite3)
+		$(use_with ssl openssl)
+		$(use_with threads pthread)
+		$(use_with xosd libxosd)
+		$(use_with zlib)
+		$(use_enable nls)
+		$(use_enable unicode)
+		--without-ioctld
+		--disable-remote
+		--enable-skip-relative-plugins-dir
+	)
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+	remove_libtool_files all
+}
diff --git a/net-im/ekg2/ekg2-0.3_pre20101008.ebuild b/net-im/ekg2/ekg2-0.3_pre20101008.ebuild
deleted file mode 100644
index 8efa5c7d76e0..000000000000
--- a/net-im/ekg2/ekg2-0.3_pre20101008.ebuild
+++ /dev/null
@@ -1,223 +0,0 @@
-# Copyright 1999-2010 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/ekg2/ekg2-0.3_pre20101008.ebuild,v 1.4 2010/10/25 00:24:12 fauli Exp $
-
-EAPI=2
-
-inherit base multilib perl-module scons-utils toolchain-funcs
-
-DESCRIPTION="Text-based, multi-protocol instant messenger"
-HOMEPAGE="http://www.ekg2.org"
-SRC_URI="http://github.com/downloads/mgorny/${PN}-scons/${P}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="dbus extra gadu gif gnutls gpg gpm gsm icq idn inotify irc
-	jabber jogger jpeg mail minimal ncurses nls nntp oracle oss pcap
-	perl python readline remote rss ruby sim sms spell
-	sqlite sqlite3 srv ssl static unicode web xosd zlib"
-
-# -- non-obvious plugin mappings --
-# extra	    -> autoresponder, polchat, rivchat, rot13, xmsg
-# !minimal  -> ioctld, logs, rc
-# any sound -> pcm
-# web	    -> httprc_xajax
-
-RDEPEND="
-	dbus? ( sys-apps/dbus )
-	gpg? ( app-crypt/gpgme )
-	gsm? ( media-sound/gsm )
-	idn? ( net-dns/libidn )
-	nls? ( virtual/libintl )
-	oracle?	( dev-db/oracle-instantclient-basic )
-	pcap? ( net-libs/libpcap )
-	perl? ( dev-lang/perl )
-	python?	( dev-lang/python )
-	readline? ( sys-libs/readline )
-	rss? ( dev-libs/expat )
-	ruby? ( dev-lang/ruby )
-	sim? ( dev-libs/openssl )
-	xosd? ( x11-libs/xosd )
-	gadu? ( net-libs/libgadu
-		gif? ( media-libs/giflib )
-		jpeg? ( media-libs/jpeg ) )
-	irc? ( ssl? ( dev-libs/openssl ) )
-	jabber? ( dev-libs/expat
-		gnutls? ( net-libs/gnutls )
-		!gnutls? ( ssl? ( dev-libs/openssl ) )
-		zlib? ( sys-libs/zlib ) )
-	!minimal? (
-		zlib? ( sys-libs/zlib ) )
-	ncurses? ( sys-libs/ncurses[unicode?]
-		gpm? ( sys-libs/gpm )
-		spell? ( app-text/aspell ) )
-	sqlite3? ( dev-db/sqlite:3 )
-	!sqlite3? ( sqlite? ( dev-db/sqlite:0 ) )"
-
-DEPEND="${RDEPEND}
-	nls? ( sys-devel/gettext )"
-
-PATCHES=(
-	"${FILESDIR}"/0001-Drop-duplicate-config_audio_device-declaration-it-wa.patch
-)
-
-pkg_setup() {
-	if ! use ncurses && ! use readline && ! use remote && ! use web; then
-		ewarn 'ekg2 is being compiled without any frontend, you should consider'
-		ewarn 'enabling at least one of following USEflags:'
-		ewarn '  ncurses, readline, remote, web.'
-	fi
-}
-
-use_plug() {
-	use ${1} && echo -n ,${2:-${1}}
-}
-
-# Build comma-separated plugin list based on USE
-# We can put the same plugin few times if it's referenced by more than one flag
-
-build_plugin_list() {
-	echo '@none' \
-	$(use_plug dbus) \
-	$(use_plug extra autoresponder,polchat,rivchat,rot13,xmsg) \
-	$(use_plug gadu gg) \
-	$(use_plug gpg) \
-	$(use_plug gsm) \
-	$(use_plug icq) \
-	$(use_plug irc) \
-	$(use_plug jabber jabber) \
-	$(use_plug jogger jogger) \
-	$(use_plug mail) \
-	$(use_plug !minimal ioctld,logs,rc) \
-	$(use_plug ncurses) \
-	$(use_plug nntp feed) \
-	$(use_plug oracle logsoracle) \
-	$(use_plug oss oss,pcm) \
-	$(use_plug pcap sniff) \
-	$(use_plug perl) \
-	$(use_plug python) \
-	$(use_plug readline) \
-	$(use_plug remote) \
-	$(use_plug rss feed) \
-	$(use_plug ruby) \
-	$(use_plug sim) \
-	$(use_plug sms) \
-	$(use_plug sqlite logsqlite) \
-	$(use_plug sqlite3 logsqlite) \
-	$(use_plug web httprc_xajax) \
-	$(use_plug xosd) \
-		| tr -d '[[:space:]]'
-}
-
-# create DEPS list for plugin
-# + means dep forced (fail if unavailable, prioritize over other one-of)
-# - means dep disabled (don't even check for it)
-# use:opt maps USEflag to specified opt
-# usea|useb|usec makes one-of opt
-
-make_deps() {
-	local spls spll flag fopt out
-
-	echo -n " ${1}_DEPS="
-	shift
-
-	# loop over different opts
-	while [[ -n ${1} ]]; do
-		spls=${1}
-		out=
-		# loop over one-of opts
-		while true; do
-			# get next one-of, make sure spls gets empty if last
-			spll=${spls%%|*}
-			spls=${spls:$(( ${#spll} + 1 ))}
-			# parse use:opt, if no :opt specified fopt=flag
-			flag=${spll%:*}
-			fopt=${spll#*:}
-
-			# if one of one-of opt matches, we output only it
-			# else we need to output all of them disabled
-			use ${flag} && out=+ || out=${out}-
-			out=${out}${fopt}
-
-			# got more one-of opts? parse them only if this didn't match
-			if [[ -n ${spls} ]] && ! use ${flag}; then
-				out=${out},
-				continue
-			fi
-
-			echo -n ${out}
-			shift
-			[[ -n ${1} ]] && echo -n ,
-			break
-		done
-	done
-}
-
-# create all DEPS lists
-
-build_addopts_list() {
-	use extra && make_deps XMSG inotify
-	use gadu && make_deps GG gif jpeg
-	use irc && make_deps IRC 'ssl:openssl'
-	use jabber && make_deps JABBER zlib 'gnutls|ssl:openssl'
-	use mail && make_deps MAIL inotify
-	use !minimal && make_deps LOGS zlib
-	use ncurses && make_deps NCURSES gpm spell:aspell
-	use rss || use nntp && make_deps FEED rss:expat
-	use sqlite3 || use sqlite && make_deps LOGSQLITE 'sqlite3|sqlite'
-}
-
-# SCons doesn't build perl modules, perl-module.eclass does it better
-
-foreach_perl_module() {
-	if use perl; then
-		local d
-		for d in "${S}"/plugins/perl/*/; do
-			cd "${d}" || die
-			${1}
-
-			# workaround perl-module.eclass
-			unset SRC_PREP
-		done
-	fi
-}
-
-src_configure() {
-	# HARDDEPS -> build should fail if some dep is unsatisfied
-	# DISTNOTES -> are displayed with /version, helpful for upstream bug reports
-
-	tc-export CC
-	escons PLUGINS=$(build_plugin_list) $(build_addopts_list) \
-		HARDDEPS=1 SKIPCHECKS=1 RELPLUGINS=0 \
-		$(use_scons unicode UNICODE) $(use_scons nls NLS) \
-		$(use_scons static STATIC) $(use_scons idn IDN) \
-		$(use_scons srv RESOLV) \
-		PREFIX=/usr LIBDIR="\$EPREFIX/$(get_libdir)" \
-		DOCDIR="\$DATAROOTDIR/doc/${PF}" \
-		DISTNOTES="Gentoo ebuild ${PVR}, USE='${USE}'" \
-		${MAKEOPTS} conf || die "escons conf failed"
-
-	foreach_perl_module perl-module_src_configure
-}
-
-src_compile() {
-	# SKIPCONF -> no need to reconfigure
-
-	escons SKIPCONF=1 ${MAKEOPTS} || die
-
-	foreach_perl_module perl-module_src_compile
-}
-
-src_test() {
-	foreach_perl_module perl-module_src_test
-}
-
-src_install() {
-	escons DESTDIR="${D}" ${MAKEOPTS} install || die
-
-	foreach_perl_module perl-module_src_install
-
-	# XXX: replace it when an alternative is available
-	prepalldocs
-}
diff --git a/net-im/ekg2/files/0001-Drop-duplicate-config_audio_device-declaration-it-wa.patch b/net-im/ekg2/files/0001-Drop-duplicate-config_audio_device-declaration-it-wa.patch
deleted file mode 100644
index d2183ea3b0cd..000000000000
--- a/net-im/ekg2/files/0001-Drop-duplicate-config_audio_device-declaration-it-wa.patch
+++ /dev/null
@@ -1,37 +0,0 @@
-From e748db6357c9d6730a4a20c6783d3d0fe19ef133 Mon Sep 17 00:00:00 2001
-From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
-Date: Fri, 22 Oct 2010 19:08:06 +0200
-Subject: [PATCH] Drop duplicate config_audio_device declaration, it was moved to the OSS plugin.
-
----
- trunk/ekg/stuff.c |    1 -
- trunk/ekg/stuff.h |    1 -
- 2 files changed, 0 insertions(+), 2 deletions(-)
-
-diff --git a/trunk/ekg/stuff.c b/trunk/ekg/stuff.c
-index f4be1bd..12f3490 100644
---- a/trunk/ekg/stuff.c
-+++ b/trunk/ekg/stuff.c
-@@ -170,7 +170,6 @@ int config_display_sent = 1;
- int config_send_white_lines = 0;
- int config_sort_windows = 1;
- int config_keep_reason = 1;
--char *config_audio_device = NULL;
- char *config_speech_app = NULL;
- int config_time_deviation = 300;
- int config_mesg = MESG_DEFAULT;
-diff --git a/trunk/ekg/stuff.h b/trunk/ekg/stuff.h
-index 08680a9..45683a4 100644
---- a/trunk/ekg/stuff.h
-+++ b/trunk/ekg/stuff.h
-@@ -169,7 +169,6 @@ extern int no_mouse;
- extern int old_stderr;
- extern int mesg_startup;
- 
--extern char *config_audio_device;
- extern char *config_away_reason;
- extern int config_auto_save;
- extern int config_auto_user_add;
--- 
-1.7.3.2
-
diff --git a/net-im/ekg2/metadata.xml b/net-im/ekg2/metadata.xml
index 30e137880b50..516fe4808955 100644
--- a/net-im/ekg2/metadata.xml
+++ b/net-im/ekg2/metadata.xml
@@ -10,52 +10,24 @@
 	<use>
 		<flag name='expat'>Enable plugins relying on <pkg>dev-libs/expat</pkg>
 			(jabber &amp; feed plugins).</flag>
-		<flag name='extra'>Enable following plugins: autoresponder,
-			polchat, rivchat, rot13, xmsg.</flag>
 		<flag name='gadu'>Enable Gadu-Gadu protocol support (requires
 			<pkg>net-libs/libgadu</pkg>).</flag>
 		<flag name='gif'>GIF token support for Gadu-Gadu protocol.</flag>
-		<flag name='gnutls' restrict='&lt;net-im/ekg2-0.3.0_rc'>Enable SSL/TLS
-			support through GnuTLS for the plugins supporting it. If 'ssl'
-			is enabled too, GnuTLS will be preferred where possible (and
-			OpenSSL will be used elsewhere).</flag>
-		<flag name='gnutls' restrict='&gt;=net-im/ekg2-0.3.0_rc'>Enable SSL/TLS
-			support through GnuTLS (for jabber plugin). If 'ssl' is set too,
-			GnuTLS will be used.</flag>
+		<flag name='gnutls'>Enable SSL/TLS support through GnuTLS
+			for the plugins supporting it. If 'ssl' is enabled too, GnuTLS will
+			be preferred where possible (and OpenSSL will be used
+			elsewhere).</flag>
 		<flag name='gpg'>Enable jabber message encryption through
 			<pkg>app-crypt/gpgme</pkg>.</flag>
 		<flag name='inotify'>Enable inotify-based filesystem moniotoring support
 			for xmsg&amp;mail plugins.</flag>
-		<flag name='irc'>Enable IRC protocol support.</flag>
-		<flag name='jogger'>Enable support for Jogger.pl jabber bot message
-			parsing plugin.</flag>
 		<flag name='jpeg'>JPEG token support for Gadu-Gadu protocol.</flag>
-		<flag name='mail'>Enable mailbox/maildir monitoring plugin.</flag>
-		<flag name='minimal'>Don't build following plugins: ioctld, logs,
-			rc.</flag>
+		<flag name='ssl'>Enable the complete SSL/TLS support through OpenSSL.
+			This also enables the 'sim' plugin which relies on OpenSSL.</flag>
 		<flag name='oracle'>Support logging messages into Oracle database.</flag>
-		<flag name='pcap'>Enable Gadu-Gadu protocol sniffer plugin (requires
-			<pkg>net-libs/libpcap</pkg>).</flag>
-		<flag name='remote'>Enable remote UI plugin allowing to connect to
-			running EKG2 using <pkg>net-im/ekg2-remote</pkg>.</flag>
-		<flag name='sim'>Enable 'sim' plugin which provides asymmetric
-			encryption of messages used by few unofficial Gadu-Gadu clients
-			(requires <pkg>dev-libs/openssl</pkg>).</flag>
-		<flag name='sms'>Enable SMS sending plugin.</flag>
 		<flag name='sqlite3'>Support logging messages into SQLite3 database.
 			If 'sqlite' is set too, SQLite3 will be used.</flag>
 		<flag name='sqlite'>Support logging messages into SQLite2 database.
 			If 'sqlite3' is set too, it will be used instead.</flag>
-		<flag name='srv'>Use SRV-capable resolver through libresolv.</flag>
-		<flag name='ssl' restrict='&lt;net-im/ekg2-0.3.0_rc'>Enable SSL/TLS support
-			through OpenSSL (for jabber plugin). If 'gnutls' is set too, it
-			will be used instead.</flag>
-		<flag name='ssl' restrict='&gt;=net-im/ekg2-0.3.0_rc'>Enable the complete
-			SSL/TLS support through OpenSSL. This also enables the 'sim' plugin
-			which relies on OpenSSL.</flag>
-		<flag name='static'>Link statically with plugins instead of installing
-			them as shared libraries (external libraries can still be linked
-			dynamically).</flag>
-		<flag name='web'>Enable httprc_xajax WebUI plugin.</flag>
 	</use>
 </pkgmetadata>