Version bump for Gnome 3.16.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 74 insertions, 1 deletions

diff --git a/net-libs/glib-networking/ChangeLog b/net-libs/glib-networking/ChangeLog
index c53df73a9aac..c2c8c53b3804 100644
--- a/net-libs/glib-networking/ChangeLog
+++ b/net-libs/glib-networking/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/glib-networking
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/glib-networking/ChangeLog,v 1.102 2015/06/07 10:43:21 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/glib-networking/ChangeLog,v 1.103 2015/06/09 09:50:11 eva Exp $
+
+*glib-networking-2.44.0 (09 Jun 2015)
+
+  09 Jun 2015; Gilles Dartiguelongue <eva@gentoo.org>
+  +glib-networking-2.44.0.ebuild:
+  Version bump for Gnome 3.16.
 
   07 Jun 2015; Markus Meier <maekke@gentoo.org> glib-networking-2.42.1.ebuild:
   arm stable, bug #534012
diff --git a/net-libs/glib-networking/glib-networking-2.44.0.ebuild b/net-libs/glib-networking/glib-networking-2.44.0.ebuild
new file mode 100644
index 000000000000..3f40aa555210
--- /dev/null
+++ b/net-libs/glib-networking/glib-networking-2.44.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/glib-networking/glib-networking-2.44.0.ebuild,v 1.1 2015/06/09 09:50:11 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit autotools eutils gnome2 multilib-minimal virtualx
+
+DESCRIPTION="Network-related giomodules for glib"
+HOMEPAGE="http://git.gnome.org/browse/glib-networking/"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+IUSE="+gnome +libproxy smartcard +ssl test"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+
+RDEPEND="
+	>=dev-libs/glib-2.39.1:2[${MULTILIB_USEDEP}]
+	gnome? ( gnome-base/gsettings-desktop-schemas )
+	libproxy? ( >=net-libs/libproxy-0.4.11-r1:=[${MULTILIB_USEDEP}] )
+	smartcard? (
+		>=app-crypt/p11-kit-0.18.4[${MULTILIB_USEDEP}]
+		>=net-libs/gnutls-3:=[pkcs11,${MULTILIB_USEDEP}] )
+	ssl? (
+		app-misc/ca-certificates
+		>=net-libs/gnutls-3:=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35.0
+	sys-devel/gettext
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	test? ( sys-apps/dbus[X] )
+"
+# eautoreconf needs >=sys-devel/autoconf-2.65:2.5
+
+src_prepare() {
+	# Fix test build failure with USE=-smartcard
+	epatch "${FILESDIR}"/${PN}-2.40.1-unittests.patch
+
+	eautoreconf
+	gnome2_src_prepare
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		--disable-static \
+		--with-ca-certificates="${EPREFIX}"/etc/ssl/certs/ca-certificates.crt \
+		$(use_with gnome gnome-proxy) \
+		$(use_with libproxy) \
+		$(use_with smartcard pkcs11) \
+		$(use_with ssl gnutls)
+}
+
+multilib_src_test() {
+	# non-native tests fail if glib-networking is already installed.
+	# have no idea what's wrong. would appreciate some help.
+	multilib_is_native_abi || return 0
+
+	Xemake check
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}