Bump to 0.4, new use-flag 'policykit', remove static libs and .la files, fix deps, add elog about usb_modeswitch, add dist-version, add support for ppp-2.4.5 (if/when it's added), fixes bug 326605

(Portage version: 2.1.8.3/cvs/Linux i686)

2 files changed, 72 insertions, 1 deletions

diff --git a/net-misc/modemmanager/ChangeLog b/net-misc/modemmanager/ChangeLog
index 474a089763b2..0a86cd582f7c 100644
--- a/net-misc/modemmanager/ChangeLog
+++ b/net-misc/modemmanager/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for net-misc/modemmanager
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/modemmanager/ChangeLog,v 1.11 2010/07/07 16:55:56 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/modemmanager/ChangeLog,v 1.12 2010/07/08 01:05:27 nirbheek Exp $
+
+*modemmanager-0.4 (08 Jul 2010)
+
+  08 Jul 2010; Nirbheek Chauhan <nirbheek@gentoo.org>
+  +modemmanager-0.4.ebuild:
+  Bump to 0.4, new use-flag 'policykit', remove static libs and .la files,
+  fix deps, add elog about usb_modeswitch, add dist-version, add support for
+  ppp-2.4.5 (if/when it's added), fixes bug 326605
 
   07 Jul 2010; Samuli Suominen <ssuominen@gentoo.org>
   modemmanager-0.3_p20100401.ebuild:
diff --git a/net-misc/modemmanager/modemmanager-0.4.ebuild b/net-misc/modemmanager/modemmanager-0.4.ebuild
new file mode 100644
index 000000000000..7c01457cdda3
--- /dev/null
+++ b/net-misc/modemmanager/modemmanager-0.4.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/modemmanager/modemmanager-0.4.ebuild,v 1.1 2010/07/08 01:05:27 nirbheek Exp $
+
+EAPI="2"
+
+inherit gnome.org eutils
+
+# ModemManager likes itself with capital letters
+MY_PN="${PN/modemmanager/ModemManager}"
+
+DESCRIPTION="Modem and mobile broadband management libraries"
+HOMEPAGE="http://mail.gnome.org/archives/networkmanager-list/2008-July/msg00274.html"
+SRC_URI="${SRC_URI//${PN}/${MY_PN}}"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="doc policykit test"
+
+RDEPEND=">=dev-libs/glib-2.18
+	>=sys-fs/udev-145[extras]
+	>=dev-libs/dbus-glib-0.86
+	net-dialup/ppp
+	policykit? ( >=sys-auth/polkit-0.95 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35.0
+	sys-devel/gettext
+	dev-util/pkgconfig"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_configure() {
+	# ppp-2.4.5 will change the plugin directory (not added to portage yet)
+	if has_version '=net-dialup/ppp-2.4.4*'; then
+		pppd_plugin_dir="pppd/2.4.4"
+	elif has_version '=net-dialup/ppp-2.4.5*'; then
+		pppd_plugin_dir="pppd/2.4.5"
+	fi
+
+	econf \
+		--disable-more-warnings \
+		--with-udev-base-dir=/etc/udev/ \
+		--disable-static \
+		--with-dist-version=${PVR} \
+		--with-pppd-plugin-dir="/usr/$(get_libdir)/${pppd_plugin_dir}" \
+		$(use_with doc docs) \
+		$(use_with policykit polkit) \
+		$(use_with test tests)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog NEWS README
+	# Remove useless .la files
+	rm -vf "${D}"/usr/$(get_libdir)/{${MY_PN},${pppd_plugin_dir}}/*.la
+}
+
+pkg_postinst() {
+	elog "If your USB modem shows up as a Flash drive when you plug it in,"
+	elog "You should install sys-apps/usb_modeswitch which will automatically"
+	elog "switch it over to USB modem mode whenever you plug it in."
+}