EAPI 5 bump.

Signed-off-by: Patrice Clement <monsieurp@gentoo.org>
(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 93491BB8)

2 files changed, 78 insertions, 1 deletions

diff --git a/net-misc/mosh/ChangeLog b/net-misc/mosh/ChangeLog
index b9b2f37dc40b..f83ad15a59bc 100644
--- a/net-misc/mosh/ChangeLog
+++ b/net-misc/mosh/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/mosh
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/mosh/ChangeLog,v 1.51 2015/07/26 18:16:50 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/mosh/ChangeLog,v 1.52 2015/07/31 07:59:15 monsieurp Exp $
+
+*mosh-1.2.5-r1 (31 Jul 2015)
+
+  31 Jul 2015; Patrice Clement <monsieurp@gentoo.org> +mosh-1.2.5-r1.ebuild:
+  EAPI 5 bump.
 
 *mosh-1.2.5 (26 Jul 2015)
 
diff --git a/net-misc/mosh/mosh-1.2.5-r1.ebuild b/net-misc/mosh/mosh-1.2.5-r1.ebuild
new file mode 100644
index 000000000000..fb99f6708686
--- /dev/null
+++ b/net-misc/mosh/mosh-1.2.5-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/mosh/mosh-1.2.5-r1.ebuild,v 1.1 2015/07/31 07:59:15 monsieurp Exp $
+
+EAPI=5
+
+inherit autotools bash-completion-r1 eutils vcs-snapshot
+
+DESCRIPTION="Mobile shell that supports roaming and intelligent local echo"
+HOMEPAGE="http://mosh.mit.edu"
+SRC_URI="http://mosh.mit.edu/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~mips ~ppc ~x86 ~amd64-linux ~arm-linux ~x86-linux ~x64-macos"
+IUSE="+client examples +mosh-hardening +server ufw +utempter"
+
+REQUIRED_USE="|| ( client server )
+	examples? ( client )"
+
+RDEPEND="dev-libs/protobuf
+	sys-libs/ncurses:5
+	virtual/ssh
+	client? (
+		dev-lang/perl
+		dev-perl/IO-Tty
+	)
+	utempter? (
+		sys-libs/libutempter
+	)"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+# [0] - avoid sandbox-violation calling git describe in Makefile
+PATCHES=(
+	"${FILESDIR}"/${P}-git-version.patch
+)
+
+src_prepare() {
+	# apply patches.
+	epatch ${PATCHES[@]}
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-completion \
+		$(use_enable client) \
+		$(use_enable server) \
+		$(use_enable examples) \
+		$(use_enable ufw) \
+		$(use_enable mosh-hardening hardening) \
+		$(use_with utempter)
+}
+
+src_compile() {
+	emake V=1
+}
+
+src_install() {
+	default
+
+	for myprog in $(find src/examples -type f -perm /0111) ; do
+		newbin ${myprog} ${PN}-$(basename ${myprog})
+		elog "${myprog} installed as ${PN}-$(basename ${myprog})"
+	done
+
+	# bug 477384
+	dobashcomp conf/bash-completion/completions/mosh
+}