Version bump.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 95 insertions, 2 deletions

diff --git a/net-misc/rygel/ChangeLog b/net-misc/rygel/ChangeLog
index e3c66087358d..f3de8c5a7f19 100644
--- a/net-misc/rygel/ChangeLog
+++ b/net-misc/rygel/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/rygel
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/ChangeLog,v 1.44 2013/12/24 17:34:06 pacho Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/ChangeLog,v 1.45 2014/02/06 23:46:26 eva Exp $
+
+*rygel-0.20.3 (06 Feb 2014)
+
+  06 Feb 2014; Gilles Dartiguelongue <eva@gentoo.org> +rygel-0.20.3.ebuild:
+  Version bump.
 
 *rygel-0.20.0 (24 Dec 2013)
 
diff --git a/net-misc/rygel/rygel-0.20.3.ebuild b/net-misc/rygel/rygel-0.20.3.ebuild
new file mode 100644
index 000000000000..3cd81c3fbc43
--- /dev/null
+++ b/net-misc/rygel/rygel-0.20.3.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/rygel-0.20.3.ebuild,v 1.1 2014/02/06 23:46:26 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+
+inherit gnome2 virtualx
+
+DESCRIPTION="Rygel is an open source UPnP/DLNA MediaServer"
+HOMEPAGE="http://live.gnome.org/Rygel"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="X nls +sqlite tracker test transcode"
+
+# The deps for tracker? and transcode? are just the earliest available
+# version at the time of writing this ebuild
+RDEPEND="
+	>=dev-libs/glib-2.34:2
+	>=dev-libs/libgee-0.8:0.8
+	>=dev-libs/libxml2-2.7:2
+	>=media-libs/gupnp-dlna-0.9.4:2.0
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+	media-plugins/gst-plugins-soup:1.0
+	>=net-libs/gssdp-0.13
+	>=net-libs/gupnp-0.19
+	>=net-libs/gupnp-av-0.11.4
+	>=net-libs/libsoup-2.34:2.4
+	>=sys-apps/util-linux-2.20
+	x11-misc/shared-mime-info
+	sqlite? (
+		>=dev-db/sqlite-3.5:3
+		dev-libs/libunistring
+	)
+	tracker? ( >=app-misc/tracker-0.16:= )
+	transcode? (
+		media-libs/gst-plugins-bad:1.0
+		media-plugins/gst-plugins-twolame:1.0
+		media-plugins/gst-plugins-libav:1.0
+	)
+	X? ( >=x11-libs/gtk+-3:3 )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+# Maintainer only
+#	>=dev-lang/vala-0.20
+#   dev-libs/libxslt
+
+src_prepare() {
+	# runs gst-plugins-scanner on run with triggers sandbox violation
+	# trying to open dri
+	sed -e 's/rygel-media-engine-test$(EXEEXT)//' \
+		-e 's/rygel-playbin-renderer-test$(EXEEXT)//' \
+		-i tests/Makefile.in || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# We defined xsltproc because man pages are provided by upstream
+	# and we do not want to regenerate them automagically.
+	gnome2_src_configure \
+		XSLTPROC=$(type -P false) \
+		--disable-valadoc \
+		--enable-gst-launch-plugin \
+		--enable-mediathek-plugin \
+		--with-media-engine=gstreamer \
+		$(use_enable nls) \
+		$(use_enable sqlite media-export-plugin) \
+		$(use_enable test tests) \
+		$(use_enable tracker tracker-plugin) \
+		$(use_with X ui)
+}
+
+src_install() {
+	gnome2_src_install
+	# Autostart file is not placed correctly, bug #402745
+	insinto /etc/xdg/autostart
+	doins "${D}"/usr/share/applications/rygel.desktop
+	rm "${D}"/usr/share/applications/rygel.desktop
+}