Version bump.

(Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

2 files changed, 109 insertions, 1 deletions

diff --git a/net-nntp/nzbget/ChangeLog b/net-nntp/nzbget/ChangeLog
index fbed799db7c7..d62c390f39e2 100644
--- a/net-nntp/nzbget/ChangeLog
+++ b/net-nntp/nzbget/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-nntp/nzbget
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/ChangeLog,v 1.39 2012/05/03 04:32:50 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/ChangeLog,v 1.40 2012/05/07 17:52:41 radhermit Exp $
+
+*nzbget-0.8.0 (07 May 2012)
+
+  07 May 2012; Tim Harder <radhermit@gentoo.org> +nzbget-0.8.0.ebuild:
+  Version bump.
 
   03 May 2012; Jeff Horelick <jdhore@gentoo.org> nzbget-0.7.0.ebuild,
   nzbget-0.8.0_pre394.ebuild:
diff --git a/net-nntp/nzbget/nzbget-0.8.0.ebuild b/net-nntp/nzbget/nzbget-0.8.0.ebuild
new file mode 100644
index 000000000000..d023ad5cbca7
--- /dev/null
+++ b/net-nntp/nzbget/nzbget-0.8.0.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/nzbget-0.8.0.ebuild,v 1.1 2012/05/07 17:52:41 radhermit Exp $
+
+EAPI="4"
+
+inherit eutils autotools
+
+DESCRIPTION="A command-line based binary newsgrapper supporting .nzb files"
+HOMEPAGE="http://nzbget.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~x86"
+IUSE="debug gnutls ncurses parcheck ssl"
+
+RDEPEND="dev-libs/libxml2
+	ncurses? ( sys-libs/ncurses )
+	parcheck? (
+		app-arch/libpar2
+		dev-libs/libsigc++:2
+	)
+	ssl? (
+		gnutls? ( net-libs/gnutls )
+		!gnutls? ( dev-libs/openssl )
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog README nzbget.conf.example )
+
+src_prepare() {
+	sed \
+		-i \
+		-e 's:^PostProcess=.*:#PostProcess=/usr/share/nzbget/postprocess-example.sh:' \
+		nzbget.conf.example \
+		|| die
+
+	sed \
+		-e 's:^$MAINDIR=.*:$MAINDIR=/var/lib/nzbget:' \
+		-e 's:^LockFile=.*:LockFile=/var/run/nzbget/nzbget.pid:' \
+		-e 's:^LogFile=.*:LogFile=/var/log/nzbget/nzbget.log:' \
+		"${S}"/nzbget.conf.example > "${S}"/nzbgetd.conf.example \
+		|| die
+
+	epatch "${FILESDIR}"/${PN}-0.7.0-openssl-1.patch \
+		"${FILESDIR}"/${PN}-0.7.0-underlinking.patch
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		$(use_enable ncurses curses) \
+		$(use_enable parcheck) \
+		$(use_enable ssl tls) \
+		--with-tlslib=$(usex gnutls GnuTLS OpenSSL)
+}
+
+src_install() {
+	default
+
+	insinto /etc
+	newins nzbget.conf.example nzbget.conf
+	newins nzbgetd.conf.example nzbgetd.conf
+
+	keepdir /var/lib/nzbget/{dst,nzb,queue,tmp}
+	keepdir /var/{log,run}/nzbget
+
+	newinitd "${FILESDIR}"/nzbget.initd nzbget
+	newconfd "${FILESDIR}"/nzbget.confd nzbget
+
+	exeinto /usr/share/nzbget
+	doexe postprocess-example.sh
+
+	insinto /usr/share/nzbget
+	doins postprocess-example.conf
+}
+
+pkg_preinst() {
+	enewgroup nzbget
+	enewuser nzbget -1 -1 /var/lib/nzbget nzbget
+
+	fowners nzbget:nzbget /var/lib/nzbget/{dst,nzb,queue,tmp}
+	fperms 750 /var/lib/nzbget/{queue,tmp}
+	fperms 770 /var/lib/nzbget/{dst,nzb}
+
+	fowners nzbget:nzbget /var/{log,run}/nzbget
+	fperms 750 /var/{log,run}/nzbget
+
+	fowners root:nzbget /etc/nzbgetd.conf
+	fperms 640 /etc/nzbgetd.conf
+}
+
+pkg_postinst() {
+	elog
+	elog "Please add users that you want to be able to use the system-wide"
+	elog "nzbget daemon to the nzbget group. To access the daemon run nzbget"
+	elog "with the --configfile /etc/nzbgetd.conf option."
+	elog
+}