Version bump. Use system's qtsingleapplication. Bug #496638

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key C2BA7F3C!)

2 files changed, 61 insertions, 2 deletions

diff --git a/net-p2p/qbittorrent/ChangeLog b/net-p2p/qbittorrent/ChangeLog
index 857e34d90be6..ed35888ecc6b 100644
--- a/net-p2p/qbittorrent/ChangeLog
+++ b/net-p2p/qbittorrent/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-p2p/qbittorrent
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/ChangeLog,v 1.222 2013/12/30 12:55:47 hwoarang Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/ChangeLog,v 1.223 2014/01/01 11:44:16 hwoarang Exp $
+
+*qbittorrent-3.1.4 (01 Jan 2014)
+
+  01 Jan 2014; Markos Chandras <hwoarang@gentoo.org> +qbittorrent-3.1.4.ebuild:
+  Version bump. Use system's qtsingleapplication. Bug #496638
 
   30 Dec 2013; Markos Chandras <hwoarang@gentoo.org> qbittorrent-9999.ebuild:
   Use system's qtsingleapplication (>=2.6.1_p20130904) to take advantage of the
diff --git a/net-p2p/qbittorrent/qbittorrent-3.1.4.ebuild b/net-p2p/qbittorrent/qbittorrent-3.1.4.ebuild
new file mode 100644
index 000000000000..18a498a69b78
--- /dev/null
+++ b/net-p2p/qbittorrent/qbittorrent-3.1.4.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/qbittorrent-3.1.4.ebuild,v 1.1 2014/01/01 11:44:16 hwoarang Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit python-r1 qt4-r2
+
+MY_P="${P/_/}"
+DESCRIPTION="BitTorrent client in C++ and Qt"
+HOMEPAGE="http://www.qbittorrent.org/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="dbus +X geoip"
+
+# python-2 is a runtime dep only, for the search engine (see INSTALL file)
+CDEPEND="dev-libs/boost
+	dev-qt/qtcore:4
+	>=net-libs/rb_libtorrent-0.16.3
+	>=dev-qt/qtsingleapplication-2.6.1_p20130904
+	X? ( dev-qt/qtgui:4 )
+	dbus? ( dev-qt/qtdbus:4 )"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	${PYTHON_DEPS}
+	geoip? ( dev-libs/geoip )"
+
+DOCS="AUTHORS Changelog NEWS README TODO"
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	# Respect LDFLAGS
+	sed -i -e 's/-Wl,--as-needed/$(LDFLAGS)/g' src/src.pro
+	qt4-r2_src_prepare
+}
+
+src_configure() {
+	local myconf
+	use geoip     || myconf+=" --disable-geoip-database"
+	use dbus 	  || myconf+=" --disable-qt-dbus"
+	use X         || myconf+=" --disable-gui"
+
+	# econf fails, since this uses qconf
+	./configure --prefix=/usr --qtdir=/usr \
+		--with-qtsingleapplication=system \
+		--with-libboost-inc=/usr/include/boost \
+		${myconf} || die "configure failed"
+	eqmake4
+}