Revision bump of 1.3.2 and 1.4.0_pre1 fix bug #380449 (duplicate bug #465092), meanwhile also added GPL-2 to LICENSE of all versions to fix bug #426122.

(Portage version: 2.1.11.60/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

7 files changed, 233 insertions, 9 deletions

diff --git a/net-proxy/dante/ChangeLog b/net-proxy/dante/ChangeLog
index 1c87fa270d15..02a152c4a666 100644
--- a/net-proxy/dante/ChangeLog
+++ b/net-proxy/dante/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for net-proxy/dante
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/dante/ChangeLog,v 1.66 2013/03/06 06:17:37 tomwij Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/dante/ChangeLog,v 1.67 2013/04/09 18:09:40 tomwij Exp $
+
+*dante-1.3.2-r1 (09 Apr 2013)
+*dante-1.4.0_pre1-r1 (09 Apr 2013)
+
+  09 Apr 2013; Tom Wijsman <TomWij@gentoo.org> +dante-1.3.2-r1.ebuild,
+  +dante-1.4.0_pre1-r1.ebuild, +files/dante-1.3.2-sockd-init,
+  dante-1.1.19-r4.ebuild, dante-1.3.2.ebuild, dante-1.4.0_pre1.ebuild:
+  Revision bump of 1.3.2 and 1.4.0_pre1 fix bug #380449 (duplicate bug #465092),
+  meanwhile also added GPL-2 to LICENSE of all versions to fix bug #426122.
 
   06 Mar 2013; Tom Wijsman <TomWij@gentoo.org>
   +files/dante-1.4.0-osdep-format-macro.patch, dante-1.4.0_pre1.ebuild:
diff --git a/net-proxy/dante/dante-1.1.19-r4.ebuild b/net-proxy/dante/dante-1.1.19-r4.ebuild
index e288d3c86a7e..ed50f8e45ce0 100644
--- a/net-proxy/dante/dante-1.1.19-r4.ebuild
+++ b/net-proxy/dante/dante-1.1.19-r4.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/dante/dante-1.1.19-r4.ebuild,v 1.9 2012/03/13 12:07:02 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/dante/dante-1.1.19-r4.ebuild,v 1.10 2013/04/09 18:09:40 tomwij Exp $
 
 inherit eutils autotools
 
@@ -8,7 +8,7 @@ DESCRIPTION="A free socks4,5 and msproxy implementation"
 HOMEPAGE="http://www.inet.no/dante/"
 SRC_URI="ftp://ftp.inet.no/pub/socks/${P}.tar.gz"
 
-LICENSE="BSD"
+LICENSE="BSD GPL-2"
 SLOT="0"
 KEYWORDS="alpha amd64 arm hppa ia64 ~m68k ~mips ppc ppc64 s390 sh sparc x86 ~x86-fbsd"
 IUSE="tcpd debug selinux pam"
diff --git a/net-proxy/dante/dante-1.3.2-r1.ebuild b/net-proxy/dante/dante-1.3.2-r1.ebuild
new file mode 100644
index 000000000000..9bdb31456ab6
--- /dev/null
+++ b/net-proxy/dante/dante-1.3.2-r1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/dante/dante-1.3.2-r1.ebuild,v 1.1 2013/04/09 18:09:40 tomwij Exp $
+
+EAPI="5"
+
+inherit autotools eutils
+
+DESCRIPTION="A free socks4,5 and msproxy implementation"
+HOMEPAGE="http://www.inet.no/dante/"
+SRC_URI="ftp://ftp.inet.no/pub/socks/${P}.tar.gz"
+
+LICENSE="BSD GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="debug kerberos pam selinux static-libs tcpd"
+
+RDEPEND="pam? ( virtual/pam )
+	kerberos? ( virtual/krb5 )
+	selinux? ( sec-policy/selinux-dante )
+	tcpd? ( sys-apps/tcp-wrappers )
+	userland_GNU? ( virtual/shadow )"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	sys-devel/bison"
+
+DOCS="BUGS CREDITS NEWS README SUPPORT doc/README* doc/*.txt doc/SOCKS4.protocol"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-1.3.0-socksify.patch \
+		"${FILESDIR}"/${PN}-1.3.1-flags.patch
+
+	sed -i \
+		-e 's:/etc/socks\.conf:"${EPREFIX}"/etc/socks/socks.conf:' \
+		-e 's:/etc/sockd\.conf:"${EPREFIX}"/etc/socks/sockd.conf:' \
+		doc/{socksify.1,socks.conf.5,sockd.conf.5,sockd.8} \
+		|| die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-socks-conf="${EPREFIX}"/etc/socks/socks.conf \
+		--with-sockd-conf="${EPREFIX}"/etc/socks/sockd.conf \
+		--without-upnp \
+		$(use_enable debug) \
+		$(use_with kerberos gssapi) \
+		$(use_with pam) \
+		$(use_enable static-libs static) \
+		$(use_enable tcpd libwrap)
+}
+
+src_install() {
+	default
+
+	# default configuration files
+	insinto /etc/socks
+	doins "${FILESDIR}"/sock?.conf
+	pushd "${ED}/etc/socks" > /dev/null
+	use pam && epatch "${FILESDIR}/sockd.conf-with-pam.patch"
+	use tcpd && epatch "${FILESDIR}/sockd.conf-with-libwrap.patch"
+	popd > /dev/null
+
+	# init script
+	newinitd "${FILESDIR}/${P}-sockd-init" dante-sockd
+	newconfd "${FILESDIR}/dante-sockd-conf" dante-sockd
+
+	# example configuration files
+	docinto examples
+	dodoc example/*.conf
+
+	use static-libs || find "${ED}" -name '*.la' -exec rm '{}' +
+}
+
+pkg_postinst() {
+	enewuser sockd -1 -1 /etc/socks daemon
+}
diff --git a/net-proxy/dante/dante-1.3.2.ebuild b/net-proxy/dante/dante-1.3.2.ebuild
index 994b1d59e725..d990a5a12910 100644
--- a/net-proxy/dante/dante-1.3.2.ebuild
+++ b/net-proxy/dante/dante-1.3.2.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/dante/dante-1.3.2.ebuild,v 1.4 2012/04/26 16:53:40 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/dante/dante-1.3.2.ebuild,v 1.5 2013/04/09 18:09:40 tomwij Exp $
 
 EAPI="4"
 
@@ -10,7 +10,7 @@ DESCRIPTION="A free socks4,5 and msproxy implementation"
 HOMEPAGE="http://www.inet.no/dante/"
 SRC_URI="ftp://ftp.inet.no/pub/socks/${P}.tar.gz"
 
-LICENSE="BSD"
+LICENSE="BSD GPL-2"
 SLOT="0"
 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
 IUSE="debug kerberos pam selinux static-libs tcpd"
diff --git a/net-proxy/dante/dante-1.4.0_pre1-r1.ebuild b/net-proxy/dante/dante-1.4.0_pre1-r1.ebuild
new file mode 100644
index 000000000000..4d3cac389847
--- /dev/null
+++ b/net-proxy/dante/dante-1.4.0_pre1-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/dante/dante-1.4.0_pre1-r1.ebuild,v 1.1 2013/04/09 18:09:40 tomwij Exp $
+
+EAPI="5"
+
+inherit autotools eutils
+
+DESCRIPTION="A free socks4,5 and msproxy implementation"
+HOMEPAGE="http://www.inet.no/dante/"
+MY_P="${P/_/-}"
+SRC_URI="ftp://ftp.inet.no/pub/socks/${MY_P}.tar.gz"
+
+LICENSE="BSD GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="debug kerberos pam selinux static-libs tcpd"
+
+RDEPEND="pam? ( virtual/pam )
+	kerberos? ( virtual/krb5 )
+	selinux? ( sec-policy/selinux-dante )
+	tcpd? ( sys-apps/tcp-wrappers )
+	userland_GNU? ( virtual/shadow )"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	sys-devel/bison"
+
+DOCS="BUGS CREDITS NEWS README SUPPORT doc/README* doc/*.txt doc/SOCKS4.protocol"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	epatch	"${FILESDIR}"/${PN}-1.3.0-socksify.patch \
+		"${FILESDIR}"/${PN}-1.4.0-osdep-format-macro.patch
+
+	sed -i \
+		-e 's:/etc/socks\.conf:"${EPREFIX}"/etc/socks/socks.conf:' \
+		-e 's:/etc/sockd\.conf:"${EPREFIX}"/etc/socks/sockd.conf:' \
+		doc/{socksify.1,socks.conf.5,sockd.conf.5,sockd.8} \
+		|| die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-socks-conf="${EPREFIX}"/etc/socks/socks.conf \
+		--with-sockd-conf="${EPREFIX}"/etc/socks/sockd.conf \
+		--without-upnp \
+		$(use_enable debug) \
+		$(use_with kerberos gssapi) \
+		$(use_with pam) \
+		$(use_enable static-libs static) \
+		$(use_enable tcpd libwrap)
+}
+
+src_install() {
+	default
+
+	# default configuration files
+	insinto /etc/socks
+	doins "${FILESDIR}"/sock?.conf
+	pushd "${ED}/etc/socks" > /dev/null
+	use pam && epatch "${FILESDIR}/sockd.conf-with-pam.patch"
+	use tcpd && epatch "${FILESDIR}/sockd.conf-with-libwrap.patch"
+	popd > /dev/null
+
+	# init script
+	newinitd "${FILESDIR}/${PN}-1.3.2-sockd-init" dante-sockd
+	newconfd "${FILESDIR}/dante-sockd-conf" dante-sockd
+
+	# example configuration files
+	docinto examples
+	dodoc example/*.conf
+
+	use static-libs || find "${ED}" -name '*.la' -exec rm '{}' +
+}
+
+pkg_postinst() {
+	enewuser sockd -1 -1 /etc/socks daemon
+}
diff --git a/net-proxy/dante/dante-1.4.0_pre1.ebuild b/net-proxy/dante/dante-1.4.0_pre1.ebuild
index f26a14682e3a..919078a93e64 100644
--- a/net-proxy/dante/dante-1.4.0_pre1.ebuild
+++ b/net-proxy/dante/dante-1.4.0_pre1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/dante/dante-1.4.0_pre1.ebuild,v 1.2 2013/03/06 06:17:37 tomwij Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/dante/dante-1.4.0_pre1.ebuild,v 1.3 2013/04/09 18:09:40 tomwij Exp $
 
 EAPI="5"
 
@@ -11,7 +11,7 @@ HOMEPAGE="http://www.inet.no/dante/"
 MY_P="${P/_/-}"
 SRC_URI="ftp://ftp.inet.no/pub/socks/${MY_P}.tar.gz"
 
-LICENSE="BSD"
+LICENSE="BSD GPL-2"
 SLOT="0"
 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
 IUSE="debug kerberos pam selinux static-libs tcpd"
diff --git a/net-proxy/dante/files/dante-1.3.2-sockd-init b/net-proxy/dante/files/dante-1.3.2-sockd-init
new file mode 100644
index 000000000000..7be9f3b265af
--- /dev/null
+++ b/net-proxy/dante/files/dante-1.3.2-sockd-init
@@ -0,0 +1,57 @@
+#!/sbin/runscript
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/dante/files/dante-1.3.2-sockd-init,v 1.1 2013/04/09 18:09:40 tomwij Exp $
+
+SOCKD_OPT=""
+[ "${SOCKD_FORKDEPTH:-1}" -gt 1 ] && SOCKD_OPT="${SOCKD_OPT} -N ${SOCKD_FORKDEPTH}"
+[ "${SOCKD_DEBUG:-0}" -eq 1 ] && SOCKD_OPT="${SOCKD_OPT} -d"
+[ "${SOCKD_DISABLE_KEEPALIVE:-0}" -eq 1 ] && SOCKD_OPT="${SOCKD_OPT} -n"
+PIDFILE=/var/run/sockd.pid
+SOCKDIR=/var/lock/dante-sockd/
+
+depend() {
+	need net
+}
+
+checkconfig() {
+	# first check that it exists
+	if [ ! -f /etc/socks/sockd.conf ] ; then
+		eerror "You need to setup /etc/socks/sockd.conf first"
+		eerror "Examples are in /usr/share/doc/dante[version]/example"
+		eerror "for more info, see: man sockd.conf"
+		return 1
+	fi
+
+	/usr/sbin/sockd -V >/tmp/dante-sockd.checkconf 2>&1
+	if [ $? -ne 0 ]; then
+		cat /tmp/dante-sockd.checkconf
+		eerror "Something is wrong with your configuration file"
+		eerror "for more info, see: man sockd.conf"
+		return 1
+	fi
+	rm /tmp/dante-sockd.checkconf
+
+	DAEMON_UID=`sed -e '/^[ \t]*user[.]notprivileged[ \t]*:/{s/.*:[ \t]*//;q};d' /etc/socks/sockd.conf`
+	if [ -n "$DAEMON_UID" ]; then
+		[ ! -d $SOCKDIR ] && mkdir $SOCKDIR && chown $DAEMON_UID $SOCKDIR
+		[ ! -f $SOCKDIR/.keep ] && touch $SOCKDIR/.keep 
+	fi
+
+	return 0
+}
+
+start() {
+	checkconfig || return 1
+	ebegin "Starting dante sockd"
+	start-stop-daemon --start --quiet \
+		--background --pidfile $PIDFILE --make-pidfile --env TMPDIR=$SOCKDIR \
+		--exec /usr/sbin/sockd -- ${SOCKD_OPT} >/dev/null 2>&1
+	eend $? "Failed to start sockd"
+}
+
+stop() {
+	ebegin "Stopping dante sockd"
+	start-stop-daemon --stop --quiet --pidfile $PIDFILE
+	eend $? "Failed to stop sockd"
+}