sci-chemistry/relax: Version Bump

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

2 files changed, 74 insertions, 1 deletions

diff --git a/sci-chemistry/relax/ChangeLog b/sci-chemistry/relax/ChangeLog
index a7667b9b113a..1145d1d50969 100644
--- a/sci-chemistry/relax/ChangeLog
+++ b/sci-chemistry/relax/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sci-chemistry/relax
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/relax/ChangeLog,v 1.25 2014/06/06 08:10:14 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/relax/ChangeLog,v 1.26 2014/07/04 06:52:09 jlec Exp $
+
+*relax-3.2.3 (04 Jul 2014)
+
+  04 Jul 2014; Justin Lecher <jlec@gentoo.org> +relax-3.2.3.ebuild:
+  Version Bump
 
 *relax-3.2.2 (06 Jun 2014)
 
diff --git a/sci-chemistry/relax/relax-3.2.3.ebuild b/sci-chemistry/relax/relax-3.2.3.ebuild
new file mode 100644
index 000000000000..7aa1cfbb442c
--- /dev/null
+++ b/sci-chemistry/relax/relax-3.2.3.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/relax/relax-3.2.3.ebuild,v 1.1 2014/07/04 06:52:09 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+WX_GTK_VER="2.9"
+
+inherit eutils multiprocessing python-single-r1 scons-utils toolchain-funcs wxwidgets virtualx
+
+DESCRIPTION="Molecular dynamics by NMR data analysis"
+HOMEPAGE="http://www.nmr-relax.com/"
+SRC_URI="http://download.gna.org/relax/${P}.src.tar.bz2"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/wxpython:${WX_GTK_VER}[${PYTHON_USEDEP}]
+	sci-chemistry/molmol
+	sci-chemistry/pymol[${PYTHON_USEDEP}]
+	sci-chemistry/vmd
+	>=sci-libs/bmrblib-1.0.3[${PYTHON_USEDEP}]
+	>=sci-libs/minfx-1.0.5[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	sci-visualization/grace
+	sci-visualization/opendx
+	x11-libs/wxGTK:${WX_GTK_VER}[X]"
+DEPEND="${RDEPEND}
+	media-gfx/pngcrush"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	rm -rf minfx bmrblib || die
+	tc-export CC
+}
+
+src_compile() {
+	escons
+}
+
+src_test() {
+	VIRTUALX_COMMAND="${EPYTHON} ./${PN}.py -x --traceback"
+	virtualmake
+}
+
+src_install() {
+	dodoc README docs/{CHANGES,COMMITTERS,JOBS,relax.pdf,prompt_screenshot.txt}
+
+	python_moduleinto ${PN}
+	python_domodule *
+
+	rm ${PN} README || die
+
+	make_wrapper ${PN}-nmr "${EPYTHON} $(python_get_sitedir)/${PN}/${PN}.py $@"
+}